C_OrgDivisionValueHelp

DDL: C_ORGDIVISIONVALUEHELP Type: view CONSUMPTION Package: ODATA_SD_S4H_COMMON

Division by Distribution Chain

C_OrgDivisionValueHelp is a Consumption CDS View that provides data about "Division by Distribution Chain" in SAP S/4HANA. It reads from 1 data source (I_SalesArea) and exposes 7 fields with key fields SalesOrganization, DistributionChannel, Division. It has 1 association to related views. It is exposed through 2 OData services (UI_SALESDOCUMENTMANAGE, UI_TRDGCONTR_MANAGEV4). Part of development package ODATA_SD_S4H_COMMON.

1 data source(s) Exposed by 2 service(s) 7 fields

Data Sources (1)

SourceAliasJoin Type
I_SalesArea SalesArea from

Associations (1)

CardinalityTargetAliasCondition
[0..*] I_DivisionText _Text $projection.Division = _Text.Division

Annotations (14)

NameValueLevelField
AbapCatalog.sqlViewName CSORGDIVISIONVH view
AbapCatalog.compiler.compareFilter true view
ClientDependent true view
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label Division by Distribution Chain view
VDM.viewType #CONSUMPTION view
UI.headerInfo.typeName Division view
UI.headerInfo.typeNamePlural Divisions view
ObjectModel.usageType.dataClass #CUSTOMIZING view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #S view
Search.searchable true view
Consumption.ranked true view
Consumption.valueHelpDefault.fetchValues #AUTOMATICALLY_WHEN_DISPLAYED view

OData Services (2)

ServiceBindingVersionContractRelease
UI_SALESDOCUMENTMANAGE UI_SALESDOCUMENTMANAGE V4 C1 NOT_RELEASED
UI_TRDGCONTR_MANAGEV4 UI_TRDGCONTR_MANAGEV4 V4 C1 NOT_RELEASED

Fields (7)

KeyFieldSource TableSource FieldDescription
KEY SalesOrganization I_SalesArea SalesOrganization
KEY DistributionChannel I_SalesArea DistributionChannel
KEY Division I_SalesArea Division
DivisionName
_SalesOrganization I_SalesArea _SalesOrganization
_DistributionChannel I_SalesArea _DistributionChannel
_Division I_SalesArea _Division 
@AbapCatalog: {
   sqlViewName: 'CSORGDIVISIONVH',
   compiler.compareFilter: true
}

@ClientDependent: true 
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Division by Distribution Chain' 

@VDM: {
  viewType: #CONSUMPTION
}

@UI.headerInfo:{ 
  typeName:       'Division',
  typeNamePlural: 'Divisions'
}

@ObjectModel:{
  usageType:{
    dataClass: #CUSTOMIZING,
    serviceQuality: #A,
    sizeCategory: #S
  }
}

@Search.searchable: true

@Consumption: {
  ranked: true,
  valueHelpDefault.fetchValues:#AUTOMATICALLY_WHEN_DISPLAYED
}

define view C_OrgDivisionValueHelp 
  as select from I_SalesArea as SalesArea

  association [0..*] to I_DivisionText as _Text on $projection.Division = _Text.Division

{   
    @Search: {
      defaultSearchElement: true,
      ranking: #LOW }
    @ObjectModel.foreignKey.association: '_SalesOrganization'
    @UI: {
      selectionField: [{ position: 30 }],
      lineItem:[ {position:30, importance: #HIGH} ],
      textArrangement: #TEXT_FIRST
    }
    key SalesArea.SalesOrganization,
    
    @Search: {
       defaultSearchElement: true,
       ranking: #LOW }
    @ObjectModel.foreignKey.association: '_DistributionChannel'
    @UI: {
      selectionField: [{ position: 40 }],
      lineItem:[ {position:40, importance: #HIGH} ],
      textArrangement: #TEXT_FIRST
    }
    key SalesArea.DistributionChannel,
    
    @ObjectModel.foreignKey.association: '_Division'
    @ObjectModel.text.element: ['DivisionName']
    @UI: {
      selectionField: [{ position: 10 }],
      lineItem:[ {position:10, importance: #HIGH } ]
    } 
    @Search: {
       defaultSearchElement: true,
       ranking: #HIGH,
       fuzzinessThreshold: 0.9 
    }
    key SalesArea.Division,
    
    @Semantics.text :true
    @UI: {
      selectionField: [{ position: 20 }],
      lineItem:[ {position:20, importance: #HIGH } ]
    }
    @Search: {
       defaultSearchElement: true,
       ranking: #LOW,
       fuzzinessThreshold: 0.8 
    }
    _Text[1:Language=$session.system_language].DivisionName,
    
    @Search.defaultSearchElement: false
    SalesArea._SalesOrganization,
    @Search.defaultSearchElement: false
    SalesArea._DistributionChannel,
    @Search.defaultSearchElement: false
    SalesArea._Division 
}

Learn More