C_SalesOfficeValueHelp

DDL: C_SALESOFFICEVALUEHELP Type: view CONSUMPTION Package: ODATA_SD_S4H_COMMON

Sales Office

C_SalesOfficeValueHelp is a Consumption CDS View that provides data about "Sales Office" in SAP S/4HANA. It reads from 1 data source (I_SalesAreaSalesOffice) and exposes 6 fields with key fields SalesOrganization, DistributionChannel, OrganizationDivision, SalesOffice. It has 1 association to related views. It is exposed through 1 OData service (UI_TRDGCONTR_MANAGEV4). Part of development package ODATA_SD_S4H_COMMON.

1 data source(s) Exposed by 1 service(s) 6 fields

Data Sources (1)

SourceAliasJoin Type
I_SalesAreaSalesOffice SalesAreaSalesOffice from

Associations (1)

CardinalityTargetAliasCondition
[0..*] I_SalesOfficeText _Text $projection.SalesOffice = _Text.SalesOffice

Annotations (16)

NameValueLevelField
AbapCatalog.sqlViewName CSAREAOFFICEVH view
AbapCatalog.compiler.compareFilter true view
ClientDependent true view
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label Sales Office view
ObjectModel.usageType.dataClass #ORGANIZATIONAL view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.dataCategory #VALUE_HELP view
VDM.viewType #CONSUMPTION view
UI.headerInfo.typeName Sales Office view
UI.headerInfo.typeNamePlural Sales Offices view
Search.searchable true view
Consumption.valueHelpDefault.fetchValues #AUTOMATICALLY_WHEN_DISPLAYED view
Consumption.ranked true view
Metadata.ignorePropagatedAnnotations true view

OData Services (1)

ServiceBindingVersionContractRelease
UI_TRDGCONTR_MANAGEV4 UI_TRDGCONTR_MANAGEV4 V4 C1 NOT_RELEASED

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY SalesOrganization I_SalesAreaSalesOffice SalesOrganization
KEY DistributionChannel I_SalesAreaSalesOffice DistributionChannel
KEY OrganizationDivision I_SalesAreaSalesOffice OrganizationDivision
KEY SalesOffice I_SalesAreaSalesOffice SalesOffice
SalesOfficeName
_Text _Text 
@AbapCatalog: {
   sqlViewName: 'CSAREAOFFICEVH',
   compiler.compareFilter: true
}

@ClientDependent: true 
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Sales Office' 

@ObjectModel: {
  usageType: {
    dataClass: #ORGANIZATIONAL,
    serviceQuality: #A,
    sizeCategory: #S
  },
  dataCategory: #VALUE_HELP
}

@VDM: {
  viewType: #CONSUMPTION
}

@UI.headerInfo:{ 
  typeName:       'Sales Office',
  typeNamePlural: 'Sales Offices'
}

@Search.searchable: true

@Consumption:{
  valueHelpDefault.fetchValues:#AUTOMATICALLY_WHEN_DISPLAYED,
  ranked: true
}

@Metadata.ignorePropagatedAnnotations: true

define view C_SalesOfficeValueHelp 
  as select from I_SalesAreaSalesOffice as SalesAreaSalesOffice
  
  association [0..*] to I_SalesOfficeText  as _Text on $projection.SalesOffice = _Text.SalesOffice
{   
    @Search: {
      defaultSearchElement: true,
      ranking: #LOW }
    @UI: {
      lineItem: [{ position: 30, importance: #HIGH }],
      selectionField:[{ position: 30 }]
    }
    key SalesAreaSalesOffice.SalesOrganization,
    
    @Search: {
      defaultSearchElement: true,
      ranking: #LOW }
    @UI: {
      lineItem: [{ position: 40, importance: #HIGH }],
      selectionField:[{ position: 40 }]
    }
    key SalesAreaSalesOffice.DistributionChannel,
    
    @Search: {
      defaultSearchElement: true,
      ranking: #LOW }
    @UI: {
      lineItem: [{ position: 50, importance: #HIGH }],
      selectionField:[{ position: 50 }]
    }
    key SalesAreaSalesOffice.OrganizationDivision,
    
    @ObjectModel.text.element: ['SalesOfficeName']
    @Search: {
      defaultSearchElement: true,
      ranking: #HIGH,
      fuzzinessThreshold: 0.9  }
    @UI: {
      lineItem: [{ position: 10, importance: #HIGH }],
      selectionField:[{ position: 10 }]
    }
    key SalesAreaSalesOffice.SalesOffice,
    
    @Semantics.text: true
    @Search: {
     defaultSearchElement: true,
     ranking: #LOW,
     fuzzinessThreshold: 0.8 }
    @UI: {
      lineItem: [{ position: 20, importance: #HIGH }],
      selectionField:[{ position: 20 }]
    }
    SalesAreaSalesOffice._SalesOffice._Text[1:Language=$session.system_language].SalesOfficeName,
    
//  Will be removed after DC2208    

    _Text  
}

Learn More