C_PurOrdRefDocPC

@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'CPURORDREFDOCPC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Reference Documents PO Creation - Purchase Contract Items'
@Search.searchable: true
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MIXED

@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

define view C_PurOrdRefDocPC
  as select from    I_PurchaseContractItem      as ctr_item
    left outer join I_PurchaseContract          as ctr_header      on ctr_item.PurchaseContract = ctr_header.PurchaseContract
    left outer join I_PurchaseContractRelevance as ctr_consumption on ctr_consumption.PurchaseContract = ctr_header.PurchaseContract
    left outer join I_PurOrdAcctAssignmentTP    as AccAssLine      on  ctr_item.PurchaseContract     = AccAssLine.PurchaseOrder
                                                                   and ctr_item.PurchaseContractItem = AccAssLine.PurchaseOrderItem
    left outer join I_SalesOrderItem            as so_item         on  AccAssLine.SalesOrder     = so_item.SalesOrder
                                                                   and AccAssLine.SalesOrderItem = so_item.SalesOrderItem

  association [0..1] to P_Purordmaintaincustproj       as _Project                    on  $projection.WBSElementInternalID = _Project.WBSElementInternalID
  association [0..1] to I_Supplier                     as _Supplier                   on  $projection.Supplier = _Supplier.Supplier
  association [0..1] to I_Plant                        as _Plant                      on  $projection.Plant = _Plant.Plant
  association [0..1] to I_PurchasingGroup              as _PurgGrp                    on  $projection.PurchasingGroup = _PurgGrp.PurchasingGroup
  association [0..1] to I_CostCenterText               as _CostCenterText             on  $projection.ControllingArea = _CostCenterText.ControllingArea
                                                                                      and $projection.CostCenter      = _CostCenterText.CostCenter
                                                                                      and $projection.ValidityEndDate = _CostCenterText.ValidityEndDate
                                                                                      and _CostCenterText.Language    = $session.system_language
  association [0..1] to I_MaterialText                 as _MaterialText               on  $projection.ManufacturerMaterial = _MaterialText.Material
                                                                                      and _MaterialText.Language           = $session.system_language
  association [0..1] to I_MaterialGroupText            as _MaterialGroupText          on  $projection.MaterialGroup   = _MaterialGroupText.MaterialGroup
                                                                                      and _MaterialGroupText.Language = $session.system_language
  association [0..1] to I_UnitOfMeasureText            as _UnitOfMeasureText          on  $projection.PurchaseOrderPriceUnit = _UnitOfMeasureText.UnitOfMeasure
                                                                                      and _UnitOfMeasureText.Language        = $session.system_language
  association [0..1] to I_BusinessPartner              as _BusinessPartner            on  $projection.ServicePerformer = _BusinessPartner.BusinessPartner
  association [0..1] to I_GlAccountTextInCompanycode   as _GlAccountTextInCompanycode on  $projection.GLAccount                = _GlAccountTextInCompanycode.GLAccount
                                                                                      and $projection.CompanyCode              = _GlAccountTextInCompanycode.CompanyCode
                                                                                      and _GlAccountTextInCompanycode.Language = $session.system_language

  -------------------------------------------------------------------------------------------
  -- Value-Help Associations                                                               --
  -------------------------------------------------------------------------------------------

  association [0..1] to C_PurchasingGroupValueHelp     as _PurchasingGroupVH          on  _PurchasingGroupVH.PurchasingGroup = $projection.PurchasingGroup

  association [0..*] to C_MM_SupplierValueHelp         as _SupplierValueHelp          on  _SupplierValueHelp.Supplier = $projection.Supplier

  association [0..*] to C_MM_MaterialValueHelp         as _MaterialValueHelp          on  _MaterialValueHelp.Material = $projection.ManufacturerMaterial

  association [0..*] to C_MM_ServicePerformerValueHelp as _ServicePerformerValueHelp  on  _ServicePerformerValueHelp.ServicePerformer = $projection.ServicePerformer

  association [0..1] to C_MM_MaterialGroupValueHelp    as _MaterialGroupVH            on  _MaterialGroupVH.MaterialGroup = $projection.MaterialGroup

  association [0..*] to C_MM_PlantValueHelp            as _PlantValueHelp             on  _PlantValueHelp.Plant = $projection.Plant

  association [0..1] to I_MM_SalesOrderValueHelp       as _SalesOrder                 on  _SalesOrder.SalesOrder = $projection.SalesOrder

  association [0..1] to I_MM_CostCenterValueHelp       as _CostCenter                 on  _CostCenter.CostCenter      = $projection.CostCenter
                                                                                      and _CostCenter.ControllingArea = $projection.ControllingArea
                                                                                      and _CostCenter.ValidityEndDate = $projection.ValidityEndDate

  association [0..1] to I_MM_WBSElementValueHelp       as _WBSElementVH               on  _WBSElementVH.WBSElementInternalID = $projection.WBSElementInternalID
                                                                                      and _WBSElementVH.WBSElementExternalID = $projection.WBSElement

  association [0..1] to I_MM_ControllingAreaVH         as _ControllingAreaValueHelp   on  $projection.ControllingArea = _ControllingAreaValueHelp.ControllingArea

{
       @UI.hidden: true
  key  ctr_item.PurchaseContract                 as PurchaseOrder,
       @UI.hidden: true
  key  ctr_item.PurchaseContractItem             as PurchaseOrderItem,
  key  AccAssLine.AccountAssignmentNumber        as AccountAssignmentNumber,
       @UI.hidden: true
       ''                                        as PurchasingInfoRecord,
       ctr_header.PurchasingOrganization         as PurchasingOrganization,
       @EndUserText.label: 'Purchasing Info Record Category'
       cast('' as esokz)                         as PurchasingInfoRecordCategory,
       //@UI.selectionField: {position: 40 }

       @Consumption: { valueHelp: '_PlantValueHelp' }
       @ObjectModel.foreignKey.association: '_PlantValueHelp'
       ctr_item.Plant                            as Plant,
       @EndUserText.label: 'Fixed Vendor'
       cast('' as abap.char(10))                 as FixedSupplier,
       @EndUserText.label: 'Desired Vendor'
       cast('' as abap.char(10))                 as FixedSupplierName,
       cast('' as abap.char(10))                 as PurchaseRequisition,
       @UI.hidden: true
       cast('' as abap.numc(5))                  as PurchaseRequisitionItem,
       @UI.hidden: true
       _Plant.PlantName                          as PlantName,
       @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 1 }
       ctr_item.PurchaseContract                 as PurchasingDocument,
       @UI.hidden: true
       'K'                                       as PurchasingDocumentCategory,
       @ObjectModel: {
        readOnly: true
       }
       ''                                        as IsAdvancedPurchaseOrder,
       @UI.hidden: true
       ctr_header.PurchasingDocumentDeletionCode as PurchasingDocumentDeletionCode,
       ctr_item.StorageLocation                  as StorageLocation,
       @UI.selectionField: { position: 20 }
       @Consumption: { valueHelp: '_MaterialValueHelp' }
       @ObjectModel.foreignKey.association: '_MaterialValueHelp'
       @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 1 }
       ctr_item.ManufacturerMaterial             as ManufacturerMaterial,
       @UI.hidden: true
       ctr_item.Material                         as Material,
       @UI.hidden: true
       _MaterialText.MaterialName                as MaterialName,
       ''                                        as MaterialType,
       //@UI.selectionField: { position: 30 }

       @Consumption: { valueHelp: '_MaterialGroupVH' }
       @ObjectModel.foreignKey.association: '_MaterialGroupVH'
       ctr_item.MaterialGroup                    as MaterialGroup,
       @UI.hidden: true
       _MaterialGroupText.MaterialGroupName      as MaterialGroupName,
       @UI.selectionField: { position: 10 }
       @Consumption: { valueHelp: '_SupplierValueHelp',filter.mandatory: true }
       @ObjectModel.foreignKey.association: '_SupplierValueHelp'
       ctr_header.Supplier                       as Supplier,
       @UI.hidden: true
       _Supplier.SupplierName                    as SupplierName,
       ctr_header.PurchaseContractType           as PurchasingDocumentType,
       @UI.hidden: true
       ''                                        as PurchasingDocumentSubtype,
       ctr_item.PurchaseContractItemText         as PurchasingDocumentItemText,
       @Semantics: { quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit' }
       cast(0 as abap.dec( 13, 3 ))              as PurchaseOrderQty,
       @Semantics: { unitOfMeasure: true }
       @UI.hidden: true
       ctr_item.OrderQuantityUnit                as PurchaseOrderQuantityUnit,
       @Semantics: { amount.currencyCode: 'Currency' }
       ctr_item.ContractNetPriceAmount           as PurchaseOrderNetPriceAmount,
       @Semantics: { currencyCode: true }
       @UI.hidden: true
       ctr_header.DocumentCurrency               as Currency,
       @Semantics: { quantity.unitOfMeasure: 'PurchaseOrderPriceUnit' }
       ctr_item.NetPriceQuantity                 as PurchaseOrderNetPriceQuantity,
       @Semantics: { unitOfMeasure: true }
       @UI.hidden: true
       ctr_item.OrderPriceUnit                   as PurchaseOrderPriceUnit,
       @UI.hidden: true
       _UnitOfMeasureText.UnitOfMeasureLongName  as PurchaseOrderPriceUnitName,
       //@UI.selectionField: { position: 60 }

       @Consumption: { valueHelp: '_PurchasingGroupVH' }
       @ObjectModel.foreignKey.association: '_PurchasingGroupVH'
       ctr_header.PurchasingGroup                as PurchasingGroup,
       @UI.hidden: true
       _PurgGrp.PurchasingGroupName              as PurchasingGroupName,
       ctr_header.CompanyCode                    as CompanyCode,
       @UI.hidden: true
       cast('' as abap.char(25))                 as CompanyCodeName,
       @EndUserText.label: 'Purchase Requisition Item Text'
       cast('' as abap.char(40))                 as PurchaseRequisitionItemText,
       @UI.hidden: true
       ''                                        as PurchasingDocumentCondition,
       @UI.hidden: true
       ''                                        as PricingProcedure,
       @Semantics.businessDate.from: true
       ctr_header.ValidityStartDate              as ValidityStartDate,
       @Semantics.businessDate.to: true
       ctr_header.ValidityEndDate                as ValidityEndDate,
       ctr_consumption.ContractConsumptionInPct  as ContractConsumptionInPct,
       @UI.hidden: true
       ''                                        as GoodsReceiptIsExpected,
       @UI.hidden: true
       ''                                        as GoodsReceiptIsNonValuated,
       @UI.hidden: true
       ''                                        as InvoiceIsExpected,
       @UI.hidden: true
       ''                                        as InvoiceIsGoodsReceiptBased,
       @UI.hidden: true
       cast(0 as abap.dec( 5, 1 ))               as OverdelivTolrtdLmtRatioInPct,
       @UI.hidden: true
       ''                                        as UnlimitedOverdeliveryIsAllowed,
       @UI.hidden: true
       cast(0 as abap.dec( 5, 1 ))               as UnderdelivTolrtdLmtRatioInPct,
       @UI.hidden: true
       cast(0 as abap.dec( 5, 0 ))               as OrderItemQtyToBaseQtyNmrtr,
       @UI.hidden: true
       cast(0 as abap.dec( 5, 0 ))               as OrderItemQtyToBaseQtyDnmntr,
       @UI.hidden: true
       ''                                        as PurchaseOrderItemCategory,
       @UI.hidden: true
       ''                                        as IsDeleted,
       //@UI.selectionField: { position: 50 }

       @Consumption: { valueHelp: '_ServicePerformerValueHelp' }
       @ObjectModel.foreignKey.association: '_ServicePerformerValueHelp'
       ''                                        as ServicePerformer,
       @UI.hidden: true
       ''                                        as ServicePerformerName,
       @UI.hidden: true
       ''                                        as ProductType,
       @UI.hidden: true
       ''                                        as RefPurchaseOutlineAgreement,
       @UI.hidden: true
       cast('00000' as abap.numc(5))             as RefPurchOutlineAgrmtItem,
       @UI.hidden: true
       ''                                        as SupplierMaterialNumber,
       @UI.hidden: true
       cast('00000000' as abap.dats)             as DeliveryDate,
       @UI.hidden: true
       cast('00000000' as abap.dats)             as PerformancePeriodStartDate,
       @UI.hidden: true
       cast('00000000' as abap.dats)             as PerformancePeriodEndDate,
       @UI.hidden: true
       cast(0 as abap.dec( 5, 0 ))               as OrderPriceUnitToOrderUnitNmrtr,
       @UI.hidden: true
       cast(0 as abap.dec( 5, 0 ))               as OrdPriceUnitToOrderUnitDnmntr,
       _Project.CustomerProjectName              as CustomerProjectName,
       AccAssLine.ProfitCenter                   as ProfitCenter,
       @UI.hidden: true
       AccAssLine.WBSElementInternalID           as WBSElementInternalID,
       //@UI.selectionField: { position: 90 }

       @Consumption: { valueHelp: '_WBSElementVH' }
       @ObjectModel.foreignKey.association: '_WBSElementVH'
       @EndUserText.label: 'WBS Element'
       _Project.WBSElement                       as WBSElement,
       AccAssLine.FunctionalArea                 as FunctionalArea,
       AccAssLine.GLAccount                      as GLAccount,
       @UI.hidden: true
       _GlAccountTextInCompanycode.GLAccountName as GLAccountName,
       //@UI.selectionField: { position: 80 }

       @ObjectModel.foreignKey.association: '_CostCenter'
       AccAssLine.CostCenter                     as CostCenter,
       @UI.hidden: true
       _CostCenterText.CostCenterName            as CostCenterName,
       @ObjectModel.foreignKey.association: '_ControllingAreaValueHelp'
       @Consumption.valueHelp: '_ControllingAreaValueHelp'
       AccAssLine.ControllingArea                as ControllingArea,
       //@UI.selectionField: { position: 70 }

       @ObjectModel.foreignKey.association: '_SalesOrder'
       AccAssLine.SalesOrder                     as SalesOrder,
       AccAssLine.SalesOrderItem                 as SalesOrderItem,
       @EndUserText.label:'Purchase Requisition Description'
       @Consumption.filter.hidden: true
       cast('' as abap.char(4))                  as PurReqnDescription,
       @Consumption.hidden: true
       _BusinessPartner,

       _PurchasingGroupVH,
       _SupplierValueHelp,
       _MaterialValueHelp,
       _ServicePerformerValueHelp,
       _MaterialGroupVH,
       _PlantValueHelp,
       _WBSElementVH,
       _CostCenter,
       _SalesOrder,
       _ControllingAreaValueHelp
}
where
      PurchasingDocumentDeletionCode        =  ' '
  and ctr_header.ValidityEndDate            >= $session.system_date
  and ctr_header.ReleaseIsNotCompleted      <> 'X'
  and ctr_item.PurgDocAggrgdSubitemCategory <> 'C'
  and ctr_item.PurgConfigurableItemNumber =  ''