C_MM_ServicePerformerValueHelp
Service Performer Value Help
C_MM_ServicePerformerValueHelp is a Consumption CDS View that provides data about "Service Performer Value Help" in SAP S/4HANA. It reads from 2 data sources (I_BusinessPartnerSupplier, I_ContingentWorker) and exposes 21 fields with key fields ServicePerformer, Supplier. It has 2 associations to related views. Part of development package ODATA_MM_COMMONS_VH.
Data Sources (2)
| Source | Alias | Join Type |
|---|---|---|
| I_BusinessPartnerSupplier | _BusinessPartnerSupplier | inner |
| I_ContingentWorker | I_ContingentWorker | from |
Associations (2)
| Cardinality | Target | Alias | Condition |
|---|---|---|---|
| [0..1] | I_BusinessPartner | _BusinessPartner | I_ContingentWorker.BusinessPartner = _BusinessPartner.BusinessPartner |
| [0..1] | I_Supplier | _Supplier | _BusinessPartnerSupplier.Supplier = _Supplier.Supplier |
Annotations (15)
| Name | Value | Level | Field |
|---|---|---|---|
| AbapCatalog.sqlViewName | CMMSRVCPERFRMRVH | view | |
| AbapCatalog.compiler.compareFilter | true | view | |
| AccessControl.authorizationCheck | #CHECK | view | |
| AccessControl.personalData.blocking | #REQUIRED | view | |
| VDM.viewType | #CONSUMPTION | view | |
| ObjectModel.semanticKey | ServicePerformer | view | |
| ObjectModel.representativeKey | ServicePerformer | view | |
| ObjectModel.usageType.dataClass | #MASTER | view | |
| ObjectModel.usageType.serviceQuality | #C | view | |
| ObjectModel.usageType.sizeCategory | #L | view | |
| EndUserText.label | Service Performer Value Help | view | |
| ClientHandling.algorithm | #SESSION_VARIABLE | view | |
| ObjectModel.dataCategory | #VALUE_HELP | view | |
| Search.searchable | true | view | |
| Consumption.ranked | true | view |
Fields (21)
| Key | Field | Source Table | Source Field | Description |
|---|---|---|---|---|
| KEY | ServicePerformer | I_ContingentWorker | BusinessPartner | Service Performer ID |
| KEY | Supplier | I_BusinessPartnerSupplier | Supplier | Supplier ID |
| IsBusinessPurposeCompleted | I_ContingentWorker | IsBusinessPurposeCompleted | ||
| SupplierName | _Supplier | OrganizationBPName1 | Supplier Name | |
| ServicePerformerName | _BusinessPartner | BusinessPartnerName | Performer Full Name | |
| AuthorizationGroup | _BusinessPartner | AuthorizationGroup | ||
| FirstName | _BusinessPartner | FirstName | Performer First Name | |
| LastName | _BusinessPartner | LastName | Performer Last Name | |
| DataControllerSet | _BusinessPartner | DataControllerSet | ||
| DataController1 | _BusinessPartner | DataController1 | ||
| DataController2 | _BusinessPartner | DataController2 | ||
| DataController3 | _BusinessPartner | DataController3 | ||
| DataController4 | _BusinessPartner | DataController4 | ||
| DataController5 | _BusinessPartner | DataController5 | ||
| DataController6 | _BusinessPartner | DataController6 | ||
| DataController7 | _BusinessPartner | DataController7 | ||
| DataController8 | _BusinessPartner | DataController8 | ||
| DataController9 | _BusinessPartner | DataController9 | ||
| DataController10 | _BusinessPartner | DataController10 | ||
| Person | _BusinessPartner | BusinessPartner | ||
| _Supplier | _Supplier |
@AbapCatalog.sqlViewName: 'CMMSRVCPERFRMRVH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck:#CHECK
@AccessControl.personalData.blocking: #REQUIRED
@VDM.viewType: #CONSUMPTION
@ObjectModel.semanticKey: 'ServicePerformer'
@ObjectModel.representativeKey: 'ServicePerformer'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@EndUserText.label: 'Service Performer Value Help'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.dataCategory: #VALUE_HELP
@Search.searchable: true
@Consumption.ranked: true
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view C_MM_ServicePerformerValueHelp
as select from I_ContingentWorker
inner join I_BusinessPartnerSupplier as _BusinessPartnerSupplier on I_ContingentWorker.Supplier = _BusinessPartnerSupplier.BusinessPartner
association [0..1] to I_BusinessPartner as _BusinessPartner on I_ContingentWorker.BusinessPartner = _BusinessPartner.BusinessPartner
association [0..1] to I_Supplier as _Supplier on _BusinessPartnerSupplier.Supplier = _Supplier.Supplier
{
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
@ObjectModel.text.element: [ 'ServicePerformerName' ]
@EndUserText.label: 'Service Performer ID'
key I_ContingentWorker.BusinessPartner as ServicePerformer,
@Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
@ObjectModel.foreignKey.association: '_Supplier'
@EndUserText.label: 'Supplier ID'
key _BusinessPartnerSupplier.Supplier as Supplier,
@Consumption.hidden: true
I_ContingentWorker.IsBusinessPurposeCompleted as IsBusinessPurposeCompleted,
@Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
@EndUserText.label: 'Supplier Name'
_Supplier.OrganizationBPName1 as SupplierName,
@Semantics.text: true
@EndUserText.label: 'Performer Full Name'
_BusinessPartner.BusinessPartnerName as ServicePerformerName,
@Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
_BusinessPartner.AuthorizationGroup as AuthorizationGroup,
@Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
@EndUserText.label: 'Performer First Name'
_BusinessPartner.FirstName as FirstName,
@Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
@EndUserText.label: 'Performer Last Name'
_BusinessPartner.LastName as LastName,
@Consumption.hidden:true
@UI.hidden:true
_BusinessPartner.DataControllerSet,
@Consumption.hidden:true
@UI.hidden:true
_BusinessPartner.DataController1,
@Consumption.hidden:true
@UI.hidden:true
_BusinessPartner.DataController2,
@Consumption.hidden:true
@UI.hidden:true
_BusinessPartner.DataController3,
@Consumption.hidden:true
@UI.hidden:true
_BusinessPartner.DataController4,
@Consumption.hidden:true
@UI.hidden:true
_BusinessPartner.DataController5,
@Consumption.hidden:true
@UI.hidden:true
_BusinessPartner.DataController6,
@Consumption.hidden:true
@UI.hidden:true
_BusinessPartner.DataController7,
@Consumption.hidden:true
@UI.hidden:true
_BusinessPartner.DataController8,
@Consumption.hidden:true
@UI.hidden:true
_BusinessPartner.DataController9,
@Consumption.hidden:true
@UI.hidden:true
_BusinessPartner.DataController10,
@Consumption.hidden:true
@UI.hidden:true
@ObjectModel.text.element:null
_BusinessPartner.BusinessPartner as Person,
// @Consumption.hidden: true
_Supplier
}
Learn More
- What Is a CDS View in SAP S/4HANA?
- Types of CDS Views: Basic, Composite, Consumption, and Transactional
- SAP Tables vs CDS Views — Key Differences
- Understanding Data Lineage in SAP S/4HANA
- VDM (Virtual Data Model) in SAP S/4HANA Explained
- CDS View Annotations — A Complete Guide
- CDS View Field Mapping and Associations
- Understanding the SAP S/4HANA Data Model
- CDS View Extensions and Custom Fields in SAP S/4HANA
- Released APIs and Stability Contracts in SAP S/4HANA