C_ProbSolvingProcStepQltyTask

@AccessControl.authorizationCheck: #CHECK

@EndUserText.label: 'Quality Tasks of a Problem-Solving Process Step'
@VDM: {
    viewType: #CONSUMPTION
}
@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #M, 
        serviceQuality: #B },
    representativeKey: 'QualityTaskInternalId',
    semanticKey:  [ 'QualityTask' ],

// Begin Draft 2.0

    compositionRoot: false,
    transactionalProcessingDelegated: true,
    draftEnabled:  false,
    createEnabled: false,
    updateEnabled: false,
    deleteEnabled: false  
}
@Analytics.technicalName: 'CPRSOLPROCQTSK'

@Metadata.allowExtensions: true

define view entity C_ProbSolvingProcStepQltyTask as select from I_QualityTaskTP

    association [0..1] to I_QualityTaskLongText as _QualityTaskDetailedDesc    on  $projection.QualityTaskInternalId = _QualityTaskDetailedDesc.QualityTaskInternalId and
                                                                                   $projection.MasterLanguage = _QualityTaskDetailedDesc.Language and
                                                                                   _QualityTaskDetailedDesc.LongTextInternalNumber = 2 and
                                                                                   _QualityTaskDetailedDesc.LongTextID = 'LTXT'

    association [0..1] to C_ProbSolvingProcExect as _ProbSolvingProc           on $projection.ProbSolvingProc = _ProbSolvingProc.ProbSolvingProc
    association [0..1] to C_ProbSolvingProcStepExect as _ProbSolvingProcStep   on  $projection.ProbSolvingProc = _ProbSolvingProcStep.ProbSolvingProc
                                                                               and $projection.ProbSolvingProcStp = _ProbSolvingProcStep.ProbSolvingProcStp
    association [0..1] to C_ProbSolvingProcCause as _ProbSolvingProcCause      on  $projection.ProbSolvingProc = _ProbSolvingProcCause.ProbSolvingProc
                                                                               and $projection.ProbSolvingProcCause = _ProbSolvingProcCause.ProbSolvingProcCause
                                                                                   
{
    key QualityTaskInternalId,
        QualityTask,
        
        QualityTaskOrigin,
        MasterLanguage,
        
        QualityTaskText,
        QualityTaskCode,
        QualityTaskCodeGroup,
        QualityTaskLifecycleStatus,
        QualityTaskProcessor,
        
        NotifTaskTimeZone,
        NotifTaskPlannedEndDate,
        NotifTaskPlannedEndTime, 
        NotifTaskCompletionDate,
        NotifTaskCompletionTime,     
        
        @ObjectModel.foreignKey.association: '_ProbSolvingProc'
        ProbSolvingProc,
        @ObjectModel.foreignKey.association: '_ProbSolvingProcStep'
        ProbSolvingProcStp,
        @ObjectModel.foreignKey.association: '_ProbSolvingProcCause'
        ProbSolvingProcCause,

        @ObjectModel.foreignKey.association: '_PredecessorQualityTask'
        PredecessorQltyTaskIntNumber,
        @ObjectModel.text.element: [ 'PredecessorQltyTaskText']
        cast( I_QualityTaskTP._PredecessorQualityTask.QualityTask     as vdm_predecessorqltytask     preserving type )  as PredecessorQltyTask,
        @Semantics.text: true
        cast( I_QualityTaskTP._PredecessorQualityTask.QualityTaskText as vdm_predecessorqltytaskdesc preserving type )  as PredecessorQltyTaskText,

        CreatedByUser,
        CreationDate,
        CreationTime,
        LastChangedByUser,
        LastChangeDate,
        LastChangeTime,

        _QualityTaskStatus,
        _QltyTskCodeGroup,
        _QltyTskCode,
        _QualityTaskProcessor,
        _QualityTaskDetailedDesc,
        _ProbSolvingProc,
        _ProbSolvingProcStep,
        _ProbSolvingProcCause,
        _PredecessorQualityTask,
        
        _CreatedByUserContactCard,
        _LastChangedByUserContactCard
} 
where     QualityTaskOrigin = '02'
      and IsDeleted         <> 'X'
      and QualityTaskArchivingStatus is initial