C_ProbSolvingProcStepExect

@AbapCatalog.sqlViewName: 'CPRSOLPROCSTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations:  [ '_CreatedByUserContactCard', '_LastChangedByUserContactCard' ]

@EndUserText.label: 'Problem-Solving Process Step'
@VDM: {
    viewType: #CONSUMPTION
}
@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #M, 
        serviceQuality: #B },
    representativeKey: 'ProbSolvingProcStp',
    semanticKey:  [ 'ProbSolvingProc', 'ProbSolvingProcStp' ],

// Begin Draft 2.0

    compositionRoot: false,
    transactionalProcessingDelegated:true,
    createEnabled: false,
    updateEnabled: true,
    deleteEnabled: false 
}
@Metadata.allowExtensions: true

/* !! The presentationVariant is overridden locally in the annotations.xml !! */
@UI.presentationVariant: { 
                id: 'DefaultLineItem',       
                sortOrder: [{ by: 'ProbSolvingProcStpSortNumber', direction: #ASC }],
                visualizations: [{type: #AS_LINEITEM }],
                requestAtLeast: ['ProbSolvingProcStpSortNumber']
}

define view C_ProbSolvingProcStepExect as select from I_ProbSolvingProcStpTP as _ProbSolvingProcStp

    association [1..1] to C_ProbSolvingProcExect    as _ProbSolvingProc    on $projection.ProbSolvingProc = _ProbSolvingProc.ProbSolvingProc
    association [0..1] to C_ProbSolvingProcProbDesc as _ProbSolvingProcProbDesc on $projection.ProbSolvingProc = _ProbSolvingProcProbDesc.ProbSolvingProc
    association [0..*] to C_ProbSolvingProcPrtcpnt  as _ProbSolvingProcPrtcpnt  on $projection.ProbSolvingProc = _ProbSolvingProcPrtcpnt.ProbSolvingProc
    association [0..*] to C_ProbSolvingProcCause    as _ProbSolvingProcCause    on $projection.ProbSolvingProc = _ProbSolvingProcCause.ProbSolvingProc
    association [0..*] to C_ProbSolvingProcCauseDsp as _ProbSolvingProcCauseDsp on $projection.ProbSolvingProc = _ProbSolvingProcCauseDsp.ProbSolvingProc

    association [0..*] to C_ProbSolvingProcStepQltyTask as _ProbSolvingProcStepQltyTask on  $projection.ProbSolvingProc = _ProbSolvingProcStepQltyTask.ProbSolvingProc and
                                                                                            $projection.ProbSolvingProcStp = _ProbSolvingProcStepQltyTask.ProbSolvingProcStp
                                                                                            
    association [0..1] to C_ProbSolvingProcAssmt    as _ProbSolvingProcAssmt    on $projection.ProbSolvingProc = _ProbSolvingProcAssmt.ProbSolvingProc 
    association [0..*] to C_ProbSolvingProcStpCmnt  as _ProbSolvingProcStpCmnt  on $projection.ProbSolvingProc    = _ProbSolvingProcStpCmnt.ProbSolvingProc
                                                                               and $projection.ProbSolvingProcStp = _ProbSolvingProcStpCmnt.ProbSolvingProcStp
                                                                                            
    /* Text denormalization */
    association [0..1] to I_ProbSolvingProcStpDesc as _StpDescInCurrentLanguage on  $projection.ProbSolvingProcType = _StpDescInCurrentLanguage.ProbSolvingProcType and
                                                                                    $projection.ProbSolvingProcStp = _StpDescInCurrentLanguage.ProbSolvingProcStp and
                                                                                    _StpDescInCurrentLanguage.Language = $session.system_language                                                                                
{
  @ObjectModel.foreignKey.association: '_ProbSolvingProc'
  key ProbSolvingProc, 
  key ProbSolvingProcStp,
      ProbSolvingProcType,
      ProbSolvingProcStpSortNumber,
      @ObjectModel.readOnly: true
      _StpDescInCurrentLanguage.ProbSolvingProcStpDesc,
      
      MasterLanguage,
      @ObjectModel.text.element: ['ProbSolvingProcStpLfcycStsText']  
      ProbSolvingProcStpLfcycSts,
      @ObjectModel.readOnly: true
      _ProbSolvingProcStpLfcycSts._ProbSolvingProcStpLfcycStsT[1:Language = $session.system_language].ProbSolvingProcStpLfcycStsText,
      CreatedByUser,
      ProbSolvingStpCreatedDateTime,
      LastChangedByUser,
      ProbSolvingStpLastChgdDteTime,  
      
      /* Step Configuration - Content Area Flags */      
      ProbSolvingProcStpHasTeam,
      ProbSolvingProcStpHasProbDesc,
      ProbSolvingProcStpHasFreeTasks,
      ProbSolvingProcStpHasCauses,
      ProbSolvingProcStpHasPlndTsks,
      ProbSolvingProcStpHasFnshdTsks,
      ProbSolvingProcStpHasComments,
      ProbSolvingProcStpHasAssmt,
      ProbSolvingProcStpHasTimeLine,
 
  @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
  _ProbSolvingProc,
  @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
  _ProbSolvingProcStpCmnt,

  _ProbSolvingProcProbDesc,
  _ProbSolvingProcPrtcpnt,
  _ProbSolvingProcCause,
  _ProbSolvingProcCauseDsp,
  _ProbSolvingProcStepQltyTask,
  _ProbSolvingProcAssmt,
   
  _ProbSolvingProcStp._CreatedByUserContactCard,
  _ProbSolvingProcStp._LastChangedByUserContactCard,
  _ProbSolvingProcStp._ProbSolvingProcStpConfign,
  _ProbSolvingProcStp._ProbSolvingProcStpLfcycSts
    
}