C_ProbSolvingProcCause

@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations:  [ '_CreatedByUserContactCard', '_LastChangedByUserContactCard' ]

@EndUserText.label: 'Problem Solving Process Cause'
@VDM: {
    viewType: #CONSUMPTION
}
@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #M, 
        serviceQuality: #C },
    representativeKey: 'ProbSolvingProcCause',
    semanticKey:  [ 'ProbSolvingProc', 'ProbSolvingProcCause' ],

// Begin Draft 2.0

    compositionRoot: false,
    transactionalProcessingDelegated:true,
    createEnabled: false, // can only be created via action

    updateEnabled: true,
    deleteEnabled: false 
// End Draft

}
@Analytics.technicalName: 'CPRSOLPROCCAUSE'

@Metadata.allowExtensions: true

define view entity C_ProbSolvingProcCause as select from I_ProbSolvingProcCauseTP as _ProbSolvingProcCauseTP 

  association [1..1] to C_ProbSolvingProcExect        as _ProbSolvingProc on  $projection.ProbSolvingProc = _ProbSolvingProc.ProbSolvingProc
  association [0..1] to C_ProbSolvingProcCauseDetDesc as _ProbSolvingProcCauseDetDesc on  $projection.ProbSolvingProc = _ProbSolvingProcCauseDetDesc.ProbSolvingProc
                                                                                      and $projection.ProbSolvingProcCause         = _ProbSolvingProcCauseDetDesc.ProbSolvingProcCause
                                                                                      and $projection.masterlanguage               = _ProbSolvingProcCauseDetDesc.Language
                                                                                      and _ProbSolvingProcCauseDetDesc.ItemCounter = 1
{
       @ObjectModel.foreignKey.association: '_ProbSolvingProc' 
  key _ProbSolvingProcCauseTP.ProbSolvingProc,
  key _ProbSolvingProcCauseTP.ProbSolvingProcCause,
      
      _ProbSolvingProcCauseTP.ProbSolvingProcCauseDesc,
      
      _ProbSolvingProcCauseTP.DefectCauseCodeGroup,
      _ProbSolvingProcCauseTP.DefectCauseCode,

      @ObjectModel.readOnly: true
      _ProbSolvingProc.MasterLanguage,

//     Admin Data

      _ProbSolvingProcCauseTP.CreatedByUser,
      _ProbSolvingProcCauseTP.ProbSolvingCauseCrtedDateTime,
      _ProbSolvingProcCauseTP.LastChangedByUser,
      _ProbSolvingProcCauseTP.ProbSolvingCauseLastChgdDteTme,
      
//    Associations

      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _ProbSolvingProc,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD]
      _ProbSolvingProcCauseDetDesc,

      _ProbSolvingProcCauseTP._DefectCauseCodeGroup,
      _ProbSolvingProcCauseTP._DefectCauseCode,
      
      _ProbSolvingProcCauseTP._CreatedByUserContactCard,
      _ProbSolvingProcCauseTP._LastChangedByUserContactCard

}