C_MfgOrderDefectRecord

@AbapCatalog.sqlViewName: 'CMFGORDDEFREC'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@ObjectModel: {
    usageType: {
        dataClass: #MIXED,
        sizeCategory: #XL,
        serviceQuality: #D },
    representativeKey: 'DefectInternalID',
    semanticKey:  [ 'Defect', 'DefectCode', 'ManufacturingOrderOperation', 'OpActyNtwkElementExternalID'],
// Begin Draft 2.0

    compositionRoot: true,
    transactionalProcessingDelegated:true,
    draftEnabled:  true,
    createEnabled: true,
    updateEnabled: 'EXTERNAL_CALCULATION',
    deleteEnabled: true
}
@Metadata.allowExtensions: true
@UI.headerInfo: {
    typeName: 'Defect',
    typeNamePlural: 'Defects',
    title: {value: 'Defect', label: 'Defect'},
    description: {value: 'DefectText'}
}
@EndUserText.label: 'Consumption view for defect'

@UI.presentationVariant: [{requestAtLeast: ['SitnNumberOfInstances', 'DefectText', 'DefectiveQuantity', 'SerialNumber']}]

define view C_MfgOrderDefectRecord
  as select from I_Defect_TP as Defect

  association [0..1] to I_NotificationItem            as _NotificationItem            on  _NotificationItem.ReferencedDefect = Defect.DefectInternalID
                                                                                      and _NotificationItem.IsDeleted        = ''

  association [0..1] to I_SitnInstceIndicator         as _Sitn                        on  _Sitn.SitnInstceAnchorObjectKey = $projection.Defect
                                                                                      and _Sitn.SitnDefAnchorObject       = 'Defect'

  association [0..1] to I_Equipment                   as _Equip                       on  Defect.Equipment = _Equip.Equipment

  association [0..1] to I_InspectionSubset            as _InspectionSubset            on  _InspectionSubset.InspectionLot               = $projection.InspectionLot
                                                                                      and _InspectionSubset.InspPlanOperationInternalID = $projection.InspPlanOperationInternalID
                                                                                      and _InspectionSubset.InspectionSubsetInternalID  = $projection.InspectionSubsetInternalID
  association [0..1] to I_ShopFloorItem               as _ShopFloorItem               on  Defect.Material          = _ShopFloorItem.Material
                                                                                      and $projection.serialnumber = _ShopFloorItem.SerialNumber
  association [0..1] to I_MfgOrdDefectDecision        as _DefectDecision              on  _DefectDecision.Notification     = $projection.DefectInternalID
                                                                                      and _DefectDecision.NotificationItem = '0000'

  //Association to child nodes

  association [0..*] to I_DefectLongTextTP            as _DefectLongTextTP            on  $projection.DefectInternalID = _DefectLongTextTP.DefectInternalID
  association [1..1] to I_MfgOrderOperation           as _MfgOrderOperation           on  _MfgOrderOperation.OrderInternalBillOfOperations = $projection.OrderInternalID
                                                                                      and _MfgOrderOperation.OrderIntBillOfOperationsItem  = $projection.InspPlanOperationInternalID
  association [1..1] to I_MfgOrderOperationBasic      as _MfgOrderOperationBasic      on  _MfgOrderOperationBasic.OrderInternalBillOfOperations = $projection.OrderInternalID
                                                                                      and _MfgOrderOperationBasic.OrderIntBillOfOperationsItem  = $projection.InspPlanOperationInternalID
  association [1..1] to I_OperationActivityText       as _OperationActivityText       on  $projection.ProductionOrderOperationActy = _OperationActivityText.OperationActivity
                                                                                      and $projection.ProductionOrderOpActyVers    = _OperationActivityText.OperationActyVersionCounter
                                                                                      and _OperationActivityText.Language          = $session.system_language
  association [1..1] to I_OpActyInstceOpActyNtwkElmnt as _OpActyInstceOpActyNtwkElmnt on  _OpActyInstceOpActyNtwkElmnt.ManufacturingOrder          = $projection.ProductionOrder
                                                                                      and _OpActyInstceOpActyNtwkElmnt.OrderOperationInternalID    = $projection.InspPlanOperationInternalID
                                                                                      and _OpActyInstceOpActyNtwkElmnt.OperationActivity           = $projection.ProductionOrderOperationActy
                                                                                      and _OpActyInstceOpActyNtwkElmnt.OperationActyVersionCounter = $projection.ProductionOrderOpActyVers
  association [1..1] to I_OpActyInstceNtwkElmntBasic  as _OpActyInstceNtwkElmntBasic  on  _OpActyInstceNtwkElmntBasic.ManufacturingOrder          = $projection.ProductionOrder
                                                                                      and _OpActyInstceNtwkElmntBasic.OrderOperationInternalID    = $projection.InspPlanOperationInternalID
                                                                                      and _OpActyInstceNtwkElmntBasic.OperationActivity           = $projection.ProductionOrderOperationActy
                                                                                      and _OpActyInstceNtwkElmntBasic.OperationActyVersionCounter = $projection.ProductionOrderOpActyVers
  association [0..1] to I_MfgActionReasonCode         as _MfgActionReasonCode         on  _MfgActionReasonCode.MfgActionReasonCodeGroupCtlg  = $projection.DefectCodeCatalog
                                                                                      and _MfgActionReasonCode.MfgActionReasonCodeGroup      = $projection.DefectCodeGroup
                                                                                      and _MfgActionReasonCode.ManufacturingActionReasonCode = $projection.DefectCode
                                                                                      and _MfgActionReasonCode.Version                       = $projection.DefectCodeVersion
  association [0..1] to I_DefectCodeText              as _DefectCodeText              on  $projection.DefectCodeGroup = _DefectCodeText.DefectCodeGroup
                                                                                      and $projection.DefectCode      = _DefectCodeText.DefectCode
                                                                                      and _DefectCodeText.Language    = $session.system_language
  association [0..*] to C_ReworkBOOVersionDefectCode  as _ReworkBOOVersionDefectCode  on  $projection.DefectCodeGroup                           = _ReworkBOOVersionDefectCode.DefectCodeGroup
                                                                                      and $projection.DefectCode                                = _ReworkBOOVersionDefectCode.DefectCode
                                                                                      and ( --Non-serialized rework routings only if Defect is not bound to a serial number
                                                                                         (
                                                                                           (
                                                                                             $projection.serialnumber                           = ''
                                                                                             or $projection.serialnumber                        is null
                                                                                           )
                                                                                           and _ReworkBOOVersionDefectCode.OpActyConfIsSFIBased = ''
                                                                                         )
                                                                                         or( --Serialized rework routings only if Defect is bound to a serial number
                                                                                           $projection.serialnumber                             > ''
                                                                                           and $projection.serialnumber                         is not null
                                                                                           and _ReworkBOOVersionDefectCode.OpActyConfIsSFIBased = 'X'
                                                                                         )
                                                                                       )
  association [0..*] to I_MaterialText                as _MaterialText                on  $projection.Material = _MaterialText.MaterialName
{

      @UI.facet: [
        {
          position: 10,
          id: 'REWORK',
          label: 'Rework Routings',
          purpose: #STANDARD,
          targetElement: '_ReworkBOOVersionDefectCode'
        }
      ]

  key Defect.DefectInternalID,
      @ObjectModel.readOnly: true
      _Equip.SerialNumber,
      //      @UI: {

      //        textArrangement: #TEXT_LAST,

      //        lineItem: [{position: 10}, {position: 10, qualifier: 'OADETAILS'}

      //        ]

      //      }

      //      @ObjectModel.text.element: ['DefectText']

      Defect,
      @UI.hidden: true
      Defect.DefectCategory,
      @UI.hidden: true
      Defect.CreatedByUser,
      @UI.hidden: true
      Defect.CreationDate,
      @UI.hidden: true
      Defect.LastChangedByUser,
      @UI.hidden: true
      Defect.LastChangeDate,
      @UI.hidden: true
      DefectText,
      @UI.hidden: true
      Defect.DefectCodeCatalog,
      @UI.hidden: true
      Defect.DefectCodeGroup,
      @ObjectModel.text.association: '_DefectCodeText'
      @UI: {
        lineItem: [{position: 20}, {position: 20, qualifier: 'OADETAILS'}]
      }
      Defect.DefectCode,
      @UI.hidden: true
      Defect.DefectCodeVersion,
      @UI.hidden: true
      DefectObjectCodeCatalog,
      @UI.hidden: true
      DefectObjectCodeGroup,
      @UI.hidden: true
      DefectObjectCode,
      @UI.hidden: true
      DefectObjectCodeVersion,
      @UI.hidden: true
      Defect.DefectCauseCodeCatalog,
      @UI.hidden: true
      Defect.DefectCauseCodeGroup,
      @UI.hidden: true
      Defect.DefectCauseCode,
      @UI.hidden: true
      Defect.DefectCauseCodeVersion,
      @UI.hidden: true
      Defect.DefectiveQuantity,
      @UI.hidden: true
      Defect.DefectiveQuantityUnit,
      @UI.hidden: true
      Defect.DefectIsCreatedAutomatically,
      @UI.hidden: true
      Defect.ProductionOrderOperationActy,
      @ObjectModel: {
        text.association: '_OperationActivityText',
        readOnly: true
      }
      @UI: {
        textArrangement: #TEXT_FIRST,
        lineItem: [{position: 60}]
      }
      _OpActyInstceNtwkElmntBasic.OpActyNtwkElementExternalID,
      @UI.hidden: true
      @ObjectModel.readOnly: true
      _OpActyInstceNtwkElmntBasic.OpActyNtwkInstance,
      @UI.hidden: true
      @ObjectModel.readOnly: true
      _OpActyInstceNtwkElmntBasic.OpActyNtwkElement,
      @ObjectModel.readOnly: true
      @ObjectModel.text.element: ['MfgOrderOperationText']
      @UI: {
        textArrangement: #TEXT_FIRST,
        lineItem: [{position: 50}]
      }
      cast(_MfgOrderOperationBasic.ManufacturingOrderOperation as manufacturingorderoperation preserving type) as ManufacturingOrderOperation,
      @UI.hidden: true
      @ObjectModel.readOnly: true
      _MfgOrderOperationBasic.MfgOrderOperationText,
      @ObjectModel.readOnly: true
      _MfgOrderOperationBasic.ManufacturingOrder,
      @UI.hidden: true
      @ObjectModel.readOnly: true
      _MfgOrderOperationBasic._MfgOrder.ManufacturingOrderText,
      @UI.hidden: true
      Defect.ProductionOrderOpActyVers,
      @UI.hidden: true
      Defect.Batch,
      @UI.hidden: true
      Defect.DefectiveSingleUnit,
      @UI.hidden: true
      Defect.ProductionOrder,
      @UI.hidden: true
      Defect.OrderInternalID,
      @UI.hidden: true
      Defect.CreationTime,
      @UI.hidden: true
      Defect.LastChangeTime,
      @UI.hidden: true
      Defect.DefectClass,
      @UI.hidden: true
      Defect.NumberOfDefects,
      @UI.hidden: true
      Defect.InspPlanOperationInternalID,
      @UI.hidden: true
      Defect.InspectionCharacteristic,
      @UI.hidden: true
      Defect.InspectionSubsetInternalID,
      //      @UI.hidden: true

      //      @ObjectModel.readOnly: true

      //      _InspectionSubset.ShopFloorItem,

      @UI.hidden: true
      Defect.MaterialSample,
      @UI.hidden: true
      Defect.WorkCenterTypeCode,
      @UI.hidden: true
      Defect.MainWorkCenterInternalID,
      @UI.hidden: true
      Defect.MainWorkCenterPlant,
      @UI.hidden: true
      Defect.MainWorkCenter,
      @UI.hidden: true
      Defect.Equipment,
      @UI.hidden: true
      Defect.FunctionalLocation,
      @UI.hidden: true
      Defect.IsDeleted,
      @UI.hidden: true
      Defect.DefectOrigin,
      @UI.hidden: true
      @ObjectModel.text.association: '_MaterialText'
      Defect.Material,
      @UI.hidden: true
      Defect.Plant,
      @UI.hidden: true
      Defect.InspectionLot,
      @UI.hidden: true
      Defect.CatalogProfile,
      @UI.hidden: true
      Defect.ChangedDateTime,
      @ObjectModel.text.element: 'DefectLifecycleStatusText'
      @UI: {
        textArrangement: #TEXT_ONLY
        //lineItem: [{position: 60}, {position: 60, qualifier: 'OADETAILS'}]

      }
      Defect.DefectLifecycleStatus,
      @UI.hidden: true
      @ObjectModel.readOnly: true
      _DefectStatus._DefectStatusText[1: Language=$session.system_language].DefectLifecycleStatusText,
      @UI.hidden: true
      Defect.ProblemAnalysisStatus,
      @UI.hidden: true
      Defect.QualityIssueReference,
      @UI.hidden: true
      Defect.MasterLanguage,
      @ObjectModel.readOnly: true
      @ObjectModel.text.element: ['NotificationText']
      @UI: {
        textArrangement: #TEXT_LAST,
        lineItem: [{position: 30}]
      }
      @Consumption.semanticObject:'QualityNotification'
      _NotificationItem.Notification,
      @UI.hidden: true
      @ObjectModel.readOnly: true
      _NotificationItem._Notification.NotificationText                                                         as NotificationText,
      @ObjectModel.readOnly: true
      @UI: {
        lineItem: [{position: 40}]
      }
      @EndUserText.label: 'Notification Item'
      _NotificationItem.NotificationItem,
      @ObjectModel.readOnly: true
      @ObjectModel.text.element: ['MfgDefectDecisionName']
      @UI: {

        lineItem: [{position: 70}]
       }
      @EndUserText.label: 'Decision'
      _DefectDecision.MfgDefectDecision,
      @UI.hidden: true
      @ObjectModel.readOnly: true
      @Semantics.text: true
      _DefectDecision._DefectDecisionVH._Text[1: Language=$session.system_language].MfgDefectDecisionName,

      @ObjectModel.readOnly: true
      _Sitn.SitnNumberOfInstances,
      Defect.BOMItemInstanceUUID,
      Defect.ProducedMaterial,
      Defect.ProducedSerialNumber,


      /* Associations */
      _DefectLongTextTP,
      _DefectStatus,
      _DefectCodeText,
      _InspectionLot,
      _ShopFloorItem,
      _InspectionSubset,
      _DefectDecision,
      _MfgOrderOperation,
      _OperationActivityText,
      _MaterialText,
      _OpActyInstceOpActyNtwkElmnt,
      _MfgActionReasonCode,
      _ReworkBOOVersionDefectCode,
      _NotificationItem
      //_Notification

}