C_MasterDataMyBPChangeProcess

@EndUserText.label: 'Master Data My BP Change Process'
@VDM.viewType: #CONSUMPTION
@ObjectModel: {
    compositionRoot: true,
    transactionalProcessingDelegated:true,
    createEnabled:false,
    updateEnabled:false,
    deleteEnabled:false,
    draftEnabled:false,
    usageType.serviceQuality: #C,
    usageType.sizeCategory : #L,
    usageType.dataClass: #MIXED,
    alternativeKey: [{
        id : 'MASTERDATACHANGEPROCESS',
        uniqueness : #UNIQUE_IF_NOT_INITIAL,
        element : ['MASTERDATACHANGEPROCESS']
    }]
//    entityChangeStateId: 'MDChgProcessUpdateToken'

}
@AccessControl.authorizationCheck: #CHECK
@Search.searchable: true
@Metadata.allowExtensions: true
@ObjectModel.semanticKey: ['MasterDataChangeProcess']
@ObjectModel.delegatedAction: [
  { name: 'ERASE_PROCESS', exposureName: 'DeleteProcess' },
  { name: 'ERASE_PROCESS_WITH_REASON', exposureName: 'DeleteProcessWithReason' }
]
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
define root view entity C_MasterDataMyBPChangeProcess
  as select from I_MasterDataChangeProcessTP as Root

  association [0..*] to C_MDChangeProcessSource        as _Source               on  _Source.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
  association [0..*] to C_MasterDataChangeProcessStep  as _Step                 on  _Step.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
  association [0..*] to C_MDChgProcessRelatedProcess   as _RelatedProcess       on  _RelatedProcess.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID

  association [0..1] to I_MDChgProcessSrceRecordsCntr  as _NumberOfSouceRecords on  _NumberOfSouceRecords.MDChgProcessSourceUUID = $projection.MasterDataChangeProcessUUID
  association [0..1] to P_MDMyBPChangeProcessCount     as _EntityCounterBP      on  _EntityCounterBP.MasterDataChangeProcess = $projection.MasterDataChangeProcess
  association [0..1] to P_MDMyBPRelChangeProcessCount  as _EntityCounterBPRel   on  _EntityCounterBPRel.MasterDataChangeProcess = $projection.MasterDataChangeProcess
  association [0..1] to P_MDMyBPHierChangeProcessCount as _EntityCounterBPHier  on  _EntityCounterBPHier.MasterDataChangeProcess = $projection.MasterDataChangeProcess
  association [0..1] to P_MDChangeProcessStatusState   as _ProcessState         on  _ProcessState.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
  association [0..1] to C_MDChangeProcessCriticality   as _Criticality          on  _Criticality.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
  association [0..1] to C_MDChangeProcessProgressRatio as _Ratio                on  _Ratio.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
  association [0..1] to C_MDChgProcessStepDescription  as _StepDescription      on  _StepDescription.MasterDataChangeProcess = $projection.MasterDataChangeProcess
                                                                                and _StepDescription.MDChgProcessStep        = $projection.MDChgProcessCurrentStepNumber

  association [0..1] to C_MDMyBPChgProcStatusStateVH   as _ProcessStateVH       on  _ProcessStateVH.MDChgProcessStatusStateCode = $projection.MDChgProcessStatusStateCode
  association [0..1] to C_MDChangeProcessGoalValueHelp as _ProcessGoalVH        on  _ProcessGoalVH.MDChgProcessGoal = $projection.MDChgProcessGoal
  association [0..*] to C_MasterDataChangeProcessGoal  as _ProcessGoalText      on  _ProcessGoalText.MDChgProcessGoal = $projection.MDChgProcessGoal
  association [0..1] to C_MDChangeProcessGoalProperty  as _GoalProperty         on  _GoalProperty.MDChgProcessGoal = $projection.MDChgProcessGoal
  association [0..1] to I_MDChangeProcessTypeVH        as _ProcessTypeVH        on  _ProcessTypeVH.MDChgProcessTypeID             = $projection.MDChgProcessTypeID
                                                                                and _ProcessTypeVH.MDChgProcessSrceObjectTypeCode = $projection.MDChgProcessSrceObjectTypeCode
                                                                                and _ProcessTypeVH.MDChgProcessGoal               = $projection.MDChgProcessGoal
  association [0..1] to I_MDChangeProcessReasonText    as _ReasonText           on  _ReasonText.MasterDataChangeProcessReason  = $projection.MasterDataChangeProcessReason
                                                                                and _ReasonText.MDChgProcessSrceObjectTypeCode = $projection.MDChgProcessSrceObjectTypeCode
                                                                                and _ReasonText.Language                       = $session.system_language
  association [0..1] to I_MDChangeProcessPriorityText  as _PriorityText         on  _PriorityText.MDChangeProcessPriority = $projection.MDChangeProcessPriority
                                                                                and _PriorityText.Language                = $session.system_language
  association [0..1] to I_MDChgProcessTypeText         as _ProcessTypeText      on  _ProcessTypeText.MDChgProcessTypeID = $projection.MDChgProcessTypeID
  association [0..1] to C_MDChangeProcessStrategyVH    as _ProcessStrategyVH    on  _ProcessStrategyVH.MDChgProcessDuplicateStrategy = $projection.MDChgProcessDuplicateStrategy
  association [0..*] to C_BusinessPartnerGovTP         as _BusinessPartner      on  _BusinessPartner.MasterDataChangeProcess = $projection.MasterDataChangeProcess
  association [0..*] to C_BPHierarchyGovernanceTP      as _BPHierarchy          on  _BPHierarchy.MasterDataChangeProcess = $projection.MasterDataChangeProcess
  association [0..*] to C_BPHierarchyNodeGovernanceTP  as _BPHierarchyNode      on  _BPHierarchyNode.MasterDataChangeProcess = $projection.MasterDataChangeProcess
{
  key Root.MasterDataChangeProcessUUID,
      @EndUserText.label: 'Process'
      @ObjectModel.text.element: ['MDChgProcessDescription']
      @ObjectModel.readOnly: true
      Root.MasterDataChangeProcess                                                      as MasterDataChangeProcess,
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @Search.fuzzinessThreshold: 0.8
      @UI.hidden: true
      cast( Root.MasterDataChangeProcess as mdc_process_id_alpha_out )                  as MDChangeProcessNumberDisplay,
      @Semantics.text:true
      @Search.ranking: #HIGH
      @Search.fuzzinessThreshold: 0.8
      Root.MDChgProcessDescription,
      @Consumption.valueHelpDefinition: [{ association: '_ProcessTypeVH', distinctValues: true }]
      @ObjectModel.text.association: '_ProcessTypeText'
      @ObjectModel.text.control: #ASSOCIATED_TEXT_UI_HIDDEN
      @Search.ranking: #LOW
      Root.MDChgProcessTypeID,
      @Consumption.valueHelpDefinition: [{ association: '_ProcessGoalVH', distinctValues: true }]
      @ObjectModel.text.association: '_ProcessGoalText'
      @ObjectModel.text.control: #ASSOCIATED_TEXT_UI_HIDDEN
      @Search.ranking: #LOW
      Root.MDChgProcessGoal,
      @Search.ranking: #LOW
      Root.MDChgProcessStatus,
      Root.MDChgProcessSrceObjectTypeCode,
      Root.MDChgProcessWorkflowTemplate,
      Root.MDChgProcessCreationDate,
      Root.MDChgProcessCreationTime,
      @ObjectModel.readOnly: true
      @ObjectModel.filter.transformedBy: 'ABAP:CL_MDC_PROCESS_FLT_SORT_EXIT'
      @ObjectModel.sort.transformedBy: 'ABAP:CL_MDC_PROCESS_FLT_SORT_EXIT'
      cast( dats_tims_to_tstmp(Root.MDChgProcessCreationDate, Root.MDChgProcessCreationTime, 'UTC', $session.client, 'NULL')
        as timestamp preserving type )                                                  as MDChgProcessCreationDateTime,
      Root.MDChgProcessChangeDate,
      Root.MDChgProcessChangeTime,
      Root.MDChgProcessDelSrceDataIsRqd,
      Root.MDChgProcessFinishDate,
      Root.MDChgProcessFinishTime,
      Root.MDChgProcessUpdateToken,
      Root.MDChgProcessIsStarted,
      Root.MDChgProcessIsInitialized,
      Root.MDChgProcessIsFinalized,
      Root.MDChgProcessLastStepIsFinished,
      Root.MDChgProcessCurrentStepNumber,
      Root.MDChgProcessChkPointIsActive,
      Root.MDChgProcessCompletionIsReqd,
      Root.MDChgProcessWrkFlwDeltnIsRqd,
      Root.MDChgProcessSrceDeletionIsRqd,
      Root.MDChgProcessFilterChain,
      Root.MDChgProcessErrorsAreLogged,
      Root.MDChgProcessLastActKey,
      @EndUserText.label: 'Related Process'
      Root.MDChgProcessPredecessor,
      Root.MDChgProcessFinalDateTime,
      Root.MDChgProcessNextStpAtDateTime,
      @Consumption.valueHelpDefinition: [{ association: '_ProcessStrategyVH', distinctValues: true }]
      @ObjectModel.foreignKey.association: '_ProcessStrategyVH'
      @Search.ranking: #LOW
      Root.MDChgProcessDuplicateStrategy,
      Root.MDChgProcessIsReliable,
      Root.MDChgProcessProtectionReason,
      @Consumption.filter: { selectionType : #SINGLE,
                             defaultValue : ''
      }
      @EndUserText.label: 'Deleted'
      Root.MDChgProcessIsErased,
      @ObjectModel.readOnly: true
      _Criticality.MDChgProcessStatusCriticality                                        as MDChgProcessStatusCriticality,
      @ObjectModel.readOnly: true
      cast( '%' as msehi )                                                              as MDChangeProcessProgressUnit,
      @ObjectModel.readOnly: true
      _Ratio.MDChgProcPrgrsRatioInPercent                                               as MDChgProcPrgrsRatioInPercent,
      @ObjectModel.readOnly: true
      _Ratio.MDChangeProcessNumberOfSteps,
      @ObjectModel.readOnly: true
      @Consumption.valueHelpDefinition: [{ association: '_ProcessStateVH', distinctValues: true }]
      @ObjectModel.foreignKey.association: '_ProcessStateVH'
      @ObjectModel.text.association: '_ProcessStateVH'
      @EndUserText.label: 'Process Status'
      _ProcessState.MDChgProcessStatusStateCode                                         as MDChgProcessStatusStateCode,
      @ObjectModel.readOnly: true
      @EndUserText.label: 'Process Status'
      @EndUserText.quickInfo: 'Process Status'
      @UI.hidden: true
      _ProcessState.MDChgProcessStatusStateName                                         as MDChgProcessStatusStateName,
      @ObjectModel.readOnly: true
      @EndUserText.label: 'Data Source'
      cast( '' as abap.char( 60 ) )                                                     as MDChgProcessSrceSystem,
      @Consumption.filter: { selectionType : #SINGLE,
                             defaultValue : ''
      }
      @ObjectModel.readOnly: true
      @EndUserText.label: 'Obsolete'
      cast(
        case when Root.MDChgProcessIsStarted = 'X'
             and _NumberOfSouceRecords.MDChgProcessNmbrOfSrceRecords = 0
        then 'X'
        else ''
      end as abap_boolean preserving type )                                             as MDChangeProcessIsObsolete,
      @Semantics.businessDate.at: true
      Root.MasterDataChangeProcessDueDate,
      @ObjectModel.text.element: [ 'MDChangeProcessReasonText' ]
      @ObjectModel.text.control: #ASSOCIATED_TEXT_UI_HIDDEN
      Root.MasterDataChangeProcessReason,
      @ObjectModel.readOnly: true
      _ReasonText.MDChangeProcessReasonText                                             as MDChangeProcessReasonText,
      @ObjectModel.readOnly: true
      @ObjectModel.text.element: [ 'MDChangeProcessReasonText' ]
      concat( Root.MDChgProcessSrceObjectTypeCode, Root.MasterDataChangeProcessReason ) as MDChgProcObjectTypeCodeReason,
      @ObjectModel.text.element: [ 'MDChangeProcessPriorityText' ]
      @ObjectModel.text.control: #ASSOCIATED_TEXT_UI_HIDDEN
      Root.MDChangeProcessPriority,
      @ObjectModel.readOnly: true
      _PriorityText.MDChangeProcessPriorityText                                         as MDChangeProcessPriorityText,

      /* Associations */
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _Source,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _Step,
      @ObjectModel.readOnly: true
      _StepDescription.MDChgProcessStepDescription                                      as MDChgProcessTypeStepDspDesc,
      @ObjectModel.readOnly: true
      _StepDescription.MDChgProcessStepType                                             as MDChgProcessTypeStepDesc,

      @EndUserText.label: 'BusinessPartners'
      _EntityCounterBP.MDChgProcNmbrOfBPSourceRecords,
      @EndUserText.label: 'Relationships'
      _EntityCounterBPRel.MDNmbrOfBPRelshpSourceRecords,
      @EndUserText.label: 'Hierarchies'
      _EntityCounterBPHier.MDNumberOfBPHierSourceRecords,

      _ProcessGoalVH,
      _RelatedProcess,
      _ProcessStateVH,
      _ProcessTypeVH,
      _ProcessGoalText,
      _GoalProperty,
      _ProcessTypeText,
      _ProcessStrategyVH,
      _EntityCounterBP,
      _EntityCounterBPRel,
      _EntityCounterBPHier,
      _BusinessPartner,
      _BPHierarchy,
      _BPHierarchyNode

}
where
       MDChgProcessRequestor          = $session.user
  and(
       MDChgProcessSrceObjectTypeCode =  '147'
    or MDChgProcessSrceObjectTypeCode =  '1405'
    or MDChgProcessSrceObjectTypeCode =  '986'
    or MDChgProcessSrceObjectTypeCode =  '987'
  )
  and(
       MDChgProcessGoal               =  'G'
    or MDChgProcessGoal               =  'U'
  )
  and  MDChgProcessIsFinalized        <> 'X'