@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Business Partner Governance'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@Metadata.allowExtensions: true
@Search.searchable: true
@VDM.viewType: #CONSUMPTION
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
@ObjectModel.semanticKey: ['MasterDataChangeProcess', 'MDChgProcessSrceSystem', 'MDChgProcessSrceObject']
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define root view entity C_BusinessPartnerGovTP
provider contract transactional_query
as projection on I_BusinessPartnerGovTP as BusinessPartnerGovernance
association [0..*] to C_BPProcessChangesUnion as _Changes on $projection.MasterDataChangeProcess = _Changes.MasterDataChangeProcess
and $projection.MDChgProcessStep = _Changes.MDChgProcessStep
and $projection.MDChgProcessSrceSystem = _Changes.MDChgProcessSrceSystem
and $projection.MDChgProcessSrceObject = _Changes.MDChgProcessSrceObject
association [0..*] to C_BusPartGovRelationshipList as _BPRelationships on $projection.MDChgProcessSrceObject = _BPRelationships.MDChgProcessSrceBusPart1
and $projection.BusinessPartnerUUID = _BPRelationships.BusinessPartnerUUID
and $projection.MasterDataChangeProcessForEdit = _BPRelationships.MasterDataChangeProcess
association [0..*] to C_BPGovContactPersonList as _BPContactPersons on $projection.MDChgProcessSrceObject = _BPContactPersons.MDChgProcessSrceBusPart1
and $projection.BusinessPartnerUUID = _BPContactPersons.BusinessPartnerUUID
and $projection.MasterDataChangeProcessForEdit = _BPContactPersons.MasterDataChangeProcess
association [0..*] to C_BPGovPersonContactPersonList as _BPPersonContactPersons on $projection.MDChgProcessSrceObject = _BPPersonContactPersons.MDChgProcessSrceBusPart1
and $projection.BusinessPartnerUUID = _BPPersonContactPersons.BusinessPartnerUUID
and $projection.MasterDataChangeProcessForEdit = _BPPersonContactPersons.MasterDataChangeProcess
association [0..*] to C_BPGovObjPgIdnReferenceRecord as _BPIdentificationRefRecord on $projection.MasterDataChangeProcess = _BPIdentificationRefRecord.MasterDataChangeProcess
and $projection.MDChgProcessSrceSystem = _BPIdentificationRefRecord.MDChgProcessSrceSystem
and $projection.MDChgProcessSrceObject = _BPIdentificationRefRecord.MDChgProcessSrceObject
and $projection.BusinessPartnerUUID = _BPIdentificationRefRecord.BusinessPartnerUUID
association [0..*] to C_BPInclRelshpProcChangesUnion as _BusinessPartnerChanges on $projection.MasterDataChangeProcess = _BusinessPartnerChanges.MasterDataChangeProcess
and $projection.MDChgProcessStep = _BusinessPartnerChanges.MDChgProcessStep
and $projection.MDChgProcessSrceSystem = _BusinessPartnerChanges.MDChgProcessSrceSystem
and $projection.MDChgProcessSrceObject = _BusinessPartnerChanges.MDChgProcessSrceObject
association [0..*] to C_MDChgProcessSrceObjectChange as _MDChgProcSrceObjectChanges on $projection.MDChgProcessSrceObjectTypeCode = _MDChgProcSrceObjectChanges.MDChgProcessSrceObjectTypeCode
and $projection.MasterDataChangeProcess = _MDChgProcSrceObjectChanges.MasterDataChangeProcess
and $projection.MDChgProcessStep = _MDChgProcSrceObjectChanges.MDChgProcessStep
and $projection.MDChgProcessSrceSystem = _MDChgProcSrceObjectChanges.MDChgProcessSrceSystem
and $projection.MDChgProcessSrceObject = _MDChgProcSrceObjectChanges.MDChgProcessSrceObject
{
//I_BusinessPartnerGovTP
key BusinessPartnerUUID,
key MasterDataChangeProcess,
key MDChgProcessSrceSystem,
key MDChgProcessSrceObject,
MDChgProcessStep,
@ObjectModel.editableFieldFor: 'MasterDataChangeProcess'
MasterDataChangeProcessForEdit,
MDChangeProcessNumberDisplay,
MDChgProcessSrceObjectTypeCode,
@Search.defaultSearchElement: true
@ObjectModel.text.element: ['BusinessPartnerFullName']
BusinessPartner,
@ObjectModel.text.element: ['BusinessPartnerCategoryText']
BusinessPartnerCategory,
_BusinessPartnerCategory._Text.BusinessPartnerCategoryText : localized,
@ObjectModel.text.element: ['AuthorizationGroupName']
AuthorizationGroup,
_AuthorizationGroup._Text.AuthorizationGroupName : localized,
PersonNumber,
ETag,
MDChgProcessIsStarted,
MDChgProcessIsIdle,
_Process._CurrentStep.MDChgProcessStepWrkflwSts,
_Process._CurrentStep.MDChgProcessStepWrkflwOvrlDcsn,
_Process.MDChangeProcessPriority,
@Semantics.businessDate.at: true
_Process.MasterDataChangeProcessDueDate,
_Process.MasterDataChangeProcessReason,
BusinessPartnerName,
@Semantics.text:true
BusinessPartnerFullName,
InternationalLocationNumber1,
InternationalLocationNumber2,
InternationalLocationNumber3,
Industry,
@ObjectModel.text.element: ['FormOfAddressName']
FormOfAddress,
_FormOfAddress._Text.FormOfAddressName : localized,
@ObjectModel.text.element: ['AcademicTitleName']
AcademicTitle,
_AcademicTitleValueHelp._Text.AcademicTitleName : localized,
@ObjectModel.text.element: ['AcademicTitle2Name']
AcademicTitle2,
_AcademicTitle2._Text.AcademicTitleName as AcademicTitle2Name : localized,
@ObjectModel.text.element: ['NameFormatDescription']
NameFormat,
_NameFormat._Text.NameFormatDescription : localized,
@ObjectModel.text.element: ['CountryFreeText']
NameCountry,
_NameCountry._Text.CountryName as CountryFreeText : localized,
@ObjectModel: { text.element: ['BusinessPartnerGroupingText'] }
BusinessPartnerGrouping,
_BusinessPartnerGrouping._Text.BusinessPartnerGroupingText : localized,
@ObjectModel: { text.element: ['BusinessPartnerTypeDesc'] }
BusinessPartnerType as BusinessPartnerType_2,
_BusinessPartnerType._Text.BusinessPartnerTypeDesc : localized,
@ObjectModel.text.element: ['LanguageName']
Language,
_Language.LanguageName,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
@ObjectModel.text.element: ['CorrespondenceLanguageName']
CorrespondenceLanguage,
_CorrespondenceLanguage.LanguageName as CorrespondenceLanguageName,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
SearchTerm1,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
SearchTerm2,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
BPLastNameSearchHelp,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
BPFirstNameSearchHelp,
IndependentAddressID,
IsMarkedForArchiving,
@ObjectModel.text.element: ['ContactPermissionName']
ContactPermission,
_ContactPermission._Text.ContactPermissionName : localized,
BusinessPartnerIDByExtSystem,
@ObjectModel.text.element: ['BusinessPartnerOrgShortName']
LegalEntityOfOrganization,
_BusinessPartnerLegalEntity._Text.BusinessPartnerOrgShortName : localized,
@ObjectModel.text.element: ['BusinessPartnerPrintFormatText']
BusinessPartnerPrintFormat,
_PrintFormat._Text.BusinessPartnerPrintFormatText : localized,
@ObjectModel.text.element: ['BusPartDataOriginTypeText']
BusinessPartnerDataOriginType,
_DataOriginType._Text.BusPartDataOriginTypeText : localized,
BusinessPartnerIsNotReleased,
IsNotContractuallyCapable,
ActiveAuthorizationGroup,
DataControllerSet,
DataController1,
DataController2,
DataController3,
DataController4,
DataController5,
DataController6,
DataController7,
DataController8,
DataController9,
DataController10,
BPDataControllerIsNotRequired,
/* Administrative Data */
@Semantics.user.createdBy: true
@ObjectModel: { text.element: ['CreatedByUserName'] }
CreatedByUser,
@Semantics.text:true
_CreatedByUser.UserDescription as CreatedByUserName,
CreationDate,
CreationTime,
@Semantics.user.lastChangedBy: true
@ObjectModel: { text.element: ['LastChangedByUserName'] }
LastChangedByUser,
@Semantics.text:true
_LastChangedByUser.UserDescription as LastChangedByUserName,
LastChangeDate,
LastChangeTime,
BusinessPartnerIsBlocked,
IsBusinessPurposeCompleted,
_DpiRFCDestAvailable.ExtlyPrvddBPInfoHasNoRFCDest as ExtlyPrvddBPInfoHasNoRFCDest,
/* Category dependent common data */
BPPersonDataIsDisplayed,
BusPartPersonDataIsHidden,
BusPartOrgDataIsHidden,
BusPartGroupDataIsHidden,
BusPartAddrLanguageIsHidden,
/* Person Data */
@ObjectModel.text.element: ['FormOfAddressName']
FormOfAddressPerson,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
FirstName,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
LastName,
AdditionalLastName,
BusinessPartnerBirthName,
MiddleName,
@ObjectModel.text.element: ['BusPartSuplmntNameDescription']
BusinessPartnerSupplementName,
_BusPartSupplementName._Text.BusPartSuplmntNameDescription : localized,
@ObjectModel.text.element: ['LastNamePrefixName']
LastNamePrefix,
@Semantics.text:true
_BusPartPrefixName.LastNamePrefixName,
@ObjectModel.text.element: ['LastNameSecondPrefixName']
LastNameSecondPrefix,
_LastNameSecondPrefixName.LastNamePrefixName as LastNameSecondPrefixName,
PersonFullName,
BusinessPartnerNicknameLabel,
Initials,
cast( IsNaturalPerson as boole_d preserving type ) as IsNaturalPerson,
// IsNaturalPerson,
BirthDate,
BusinessPartnerBirthplaceName,
BusinessPartnerDeathDate,
@ObjectModel.text.element: ['BusPartBirthDateStatusText']
BusinessPartnerBirthDateStatus,
_BusPartBirthDateStatus._Text.BusPartBirthDateStatusText : localized,
NaturalPersonEmployerName,
@ObjectModel.text.element: ['OccupationDescription']
BusinessPartnerOccupation,
_Occupation._Text.OccupationDescription : localized,
@ObjectModel.text.element: ['MaritalStatusName']
BusPartMaritalStatus,
_MaritalStatus._Text.MaritalStatusName : localized,
@ObjectModel.text.element: ['NationalityName']
BusPartNationality,
_Nationality._Text.NationalityName : localized,
@ObjectModel.text.element: ['BusPartNonResCoOriginCntryName']
NonResidentCompanyOriginCntry,
_NonResidentCompOriginCntry._Text.CountryShortName as BusPartNonResCoOriginCntryName : localized,
IsMale,
IsFemale,
IsSexUnknown,
@ObjectModel.text.element: ['GenderCodeNameText']
GenderCodeName,
_GenderCode._Text.GenderCodeNameText : localized,
// Name,
AdditionalName,
/* Organization Data */
@ObjectModel.text.element: ['FormOfAddressName']
FormOfAddressOrganization,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
OrganizationBPName1,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
OrganizationBPName2,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
OrganizationBPName3,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
OrganizationBPName4,
@ObjectModel.text.element: ['LegalFormShortName']
LegalForm,
_BusinessPartnerLegalForm._Text.LegalFormShortName : localized,
OrganizationFoundationDate,
OrganizationLiquidationDate,
/* Group Data */
@ObjectModel.text.element: ['FormOfAddressName']
FormOfAddressGroup,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
GroupBusinessPartnerName1,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
GroupBusinessPartnerName2,
@ObjectModel.text.element: ['BusPartGroupTypeShortDesc']
BusinessPartnerGroupType,
_GroupType._Text.BusPartGroupTypeShortDesc : localized,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPATP2_CALC_EXIT'
virtual BusinessPartnerImageURL : abap.sstring( 260 ),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPATP2_CALC_EXIT'
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
virtual BankCountryKey : bu_banks,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPATP2_CALC_EXIT'
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
virtual Role : bu_partnerrole,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_GOVERN_CALC_EXIT'
virtual BusinessPartnerRoleDescription : abap.sstring( 255 ),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPATP2_CALC_EXIT'
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
virtual BankNumber : bankl,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPATP2_CALC_EXIT'
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
virtual BankAccount : bankn,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPATP2_CALC_EXIT'
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
virtual IBAN : iban,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPATP2_CALC_EXIT'
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
virtual BPIdentificationType : bu_id_type,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPATP2_CALC_EXIT'
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
virtual BPIdentificationNumber : bu_id_number,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPATP2_CALC_EXIT'
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
virtual BPTaxType : bptaxtype,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPATP2_CALC_EXIT'
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
virtual BPTaxNumber : bptaxnum,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
_BusinessPartnerAddressDsp.StreetDisplayName,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
_BusinessPartnerAddressDsp.CityDisplayName,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
@ObjectModel.text.element: ['CountryForDisplayName']
_BusinessPartnerAddressDsp.CountryForDisplay,
_BusinessPartnerAddressDsp._Country._Text.CountryName as CountryForDisplayName : localized,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
_BusinessPartnerAddressDsp.PostalCodeForDisplay,
_BusinessPartnerStandardAddr.StreetName as StreetName,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
_BusinessPartnerStandardAddr.HouseNumber as HouseNumber,
_BusinessPartnerStandardAddr.CityName as CityName,
_BusinessPartnerStandardAddr.PostalCode as PostalCode,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
@ObjectModel.text.element: ['RegionName']
_BusinessPartnerStandardAddr.Region as Region,
_BusinessPartnerStandardAddr._Region._RegionText.RegionName : localized,
@ObjectModel.text.element: ['CountryName']
_BusinessPartnerStandardAddr.Country as Country,
_BusinessPartnerStandardAddr._Country._Text.CountryName : localized,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
_BusinessPartnerStandardAddr.POBox as POBox,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
_BusinessPartnerStandardAddr.POBoxPostalCode as POBoxPostalCode,
// @ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_GOVERN_CALC_EXIT'
virtual AddressLine1Text : abap.sstring( 260 ),
_BusinessPartnerStandardAddr.AddressLine2Text as AddressLine2Text,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
@ObjectModel.text.element: ['CommunicationMediumTypeName']
_BusinessPartnerStandardAddr.PrfrdCommMediumType as PrfrdCommMediumType,
_BusinessPartnerStandardAddr._CommType._Text.CommunicationMediumTypeName : localized,
// @ObjectModel.text.element: ['AddrCorrespondenceLanguageName']
// _BusinessPartnerStandardAddr.CorrespondenceLanguage as AddressCorrespondenceLanguage,
// _BusinessPartnerStandardAddr._Language.LanguageName as AddrCorrespondenceLanguageName,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
_BusinessPartnerStandardAddr._StandardPhoneNumber.PhoneNumber as PhoneNumber,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
_BusinessPartnerStandardAddr._StandardPhoneNumber.PhoneNumberExtension as PhoneNumberExtension,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
@ObjectModel.text.element: ['TelephoneCountryName']
_BusinessPartnerStandardAddr._StandardPhoneNumber.DestinationLocationCountry as DestinationLocationCountry,
_BusinessPartnerStandardAddr._StandardPhoneNumber._Country._Text.CountryName as TelephoneCountryName : localized,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
_BusinessPartnerStandardAddr._StandardMobileNumber.MobilePhoneNumber as MobilePhoneNumber,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
@ObjectModel.text.element: ['MobileCountryName']
_BusinessPartnerStandardAddr._StandardMobileNumber.MobilePhoneCountry as MobilePhoneCountry,
_BusinessPartnerStandardAddr._StandardMobileNumber._Country._Text.CountryName as MobileCountryName : localized,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
_BusinessPartnerStandardAddr._StandardFaxNumber.AddressFaxNumber as AddressFaxNumber,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
_BusinessPartnerStandardAddr._StandardFaxNumber.FaxNumberExtension as FaxNumberExtension,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
@ObjectModel.text.element: ['FaxCountryName']
_BusinessPartnerStandardAddr._StandardFaxNumber.FaxCountry as FaxCountry,
_BusinessPartnerStandardAddr._StandardFaxNumber._Country._Text.CountryName as FaxCountryName : localized,
@ObjectModel.filter.transformedBy: 'ABAP:CL_BP_BUPATP2_FILTER_EXIT'
_BusinessPartnerStandardAddr._StandardEmailAddress.EmailAddress as EmailAddress,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_GOVERN_CALC_EXIT'
virtual BPMultiIndustrySystIsAvailable : abap_boolean,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_GOVERN_CALC_EXIT'
virtual MDAddrValdtnServiceIsCnfgrd : abap_boolean,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_GOVERN_CALC_EXIT'
virtual BusPartAddrLayoutStdIsHidden : abap_boolean,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_GOVERN_CALC_EXIT'
virtual US_BusPartAddrLayoutIsHidden : abap_boolean,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_GOVERN_CALC_EXIT'
virtual CA_BusPartAddrLayoutIsHidden : abap_boolean,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_GOVERN_CALC_EXIT'
virtual JP_BusPartAddrLayoutIsHidden : abap_boolean,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_GOVERN_CALC_EXIT'
virtual BusPartRelationshipIsHidden : abap_boolean,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_GOVERN_CALC_EXIT'
virtual MDChgProcDtaControllerIsHidden : abap_boolean,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPAPROCTP2_CALC_EXIT'
virtual MDChgProcStepIsAfterFederation : abap_boolean,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_GOVERN_CALC_EXIT'
@Semantics.text: true
virtual MDChgProcBPChangesAreHidden : abap_boolean,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_GOVERN_CALC_EXIT'
virtual MDChangeProcessSourceSystemOwn : mdg_business_system,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_GOVERN_CALC_EXIT'
virtual BPCntctPersnCrteButtonIsHidden : abap_boolean,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_GOVERN_CALC_EXIT'
virtual BPRelshpCreateButtonIsHidden : abap_boolean,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_GOVERN_CALC_EXIT'
virtual BusPartReplicationIsHidden : abap_boolean,
// _BusinessPartnerStandardAddr._StandardWebsiteURL.URLFieldLength as URLFieldLength,
// _BusinessPartnerStandardAddr._StandardWebsiteURL.WebsiteURL as WebsiteURL,
_Process : redirected to composition child C_BPChangeProcessGovTP,
_BusinessPartnerRole : redirected to composition child C_BusinessPartnerRoleGovTP,
_BusinessPartnerAddress : redirected to composition child C_BusinessPartnerAddressGovTP,
_BusinessPartnerIdentification : redirected to composition child C_BusPartIdentificationGovTP,
_BusinessPartnerTaxNumber : redirected to composition child C_BusPartTaxNumberGovTP,
_BusinessPartnerIndustry : redirected to composition child C_BusPartIndustryGovTP,
_BusinessPartnerBank : redirected to composition child C_BusinessPartnerBankGovTP,
_BusinessPartnerDataController : redirected to composition child C_BPDataControllerGovernanceTP,
_BusinessPartnerStandardAddr : redirected to C_BusinessPartnerAddressGovTP,
_BusinessPartnerAddressUsage : redirected to C_BusPartAddressUsageGovTP,
/* Associations */
_BusinessPartnerGrouping,
_BusinessPartnerType,
_BusinessPartnerLegalEntity,
_PrintFormat,
_ContactPermission,
_DataOriginType,
_BusinessPartnerCategory,
_BusinessPartnerLegalForm,
_AuthorizationGroup,
_FormOfAddress,
@ObjectModel.filter.enabled: false
_BPRelationships,
@ObjectModel.filter.enabled: false
_BPContactPersons,
@ObjectModel.filter.enabled: false
_BPPersonContactPersons,
_BPIdentificationRefRecord,
@ObjectModel.filter.enabled: false
_BusinessPartnerChanges,
@ObjectModel.filter.enabled: false
_MDChgProcSrceObjectChanges,
@ObjectModel.filter.enabled: false
_Changes
}