C_MasterDataChangeProcessStep

@AbapCatalog.sqlViewName: 'CMDCHGPROCSTEP'
@EndUserText.label: 'Master Data Change Process Step'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@VDM.viewType: #CONSUMPTION
@ObjectModel: {
//    compositionRoot: true,

//    transactionalProcessingDelegated:true,

    createEnabled:true,
    updateEnabled:true,
    deleteEnabled:true,
    draftEnabled:false,
    usageType.serviceQuality: #C,
    usageType.sizeCategory : #L,
    usageType.dataClass: #MIXED,
    entityChangeStateId: 'MDChgProcessUpdateToken' }
@AccessControl.authorizationCheck: #CHECK
@Search.searchable: true
@Metadata.allowExtensions: true
@ObjectModel.delegatedAction: [
  { name: 'GET_GRADES', exposureName: 'GetProcessStepGrades' }
]
define view C_MasterDataChangeProcessStep
  as select from I_MDChgProcessStepTP      as Step
    join         I_MasterDataChangeProcess as Process on Step.MasterDataChangeProcessUUID = Process.MasterDataChangeProcessUUID
  association [1..1] to C_MasterDataChangeProcess     as _Root                     on  _Root.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
  association [1..1] to I_MasterDataChangeProcess     as _RootUpdateToken          on  _RootUpdateToken.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
  association [0..*] to I_MDChgProcModifdObjects      as _ModifiedObjects          on  _ModifiedObjects.MasterDataChangeProcess = Step.MasterDataChangeProcess
                                                                                   and _ModifiedObjects.MDChgProcessStep        = Step.MDChgProcessStep

  association [1..1] to C_MDChangeProcessLogHeader    as _MDChangeProcessLogHeader on  _MDChangeProcessLogHeader.MDChgProcessStepUUID = $projection.MDChgProcessStepUUID

  association [0..1] to C_MDChgProcessStepDescription as _StepDescription          on  _StepDescription.MDChgProcessStepUUID = $projection.MDChgProcessStepUUID


{
      @UI.hidden: true
  key Step.MDChgProcessStepUUID,
      Step.MasterDataChangeProcessUUID,
      @ObjectModel.readOnly: true
      _RootUpdateToken.MDChgProcessUpdateToken,
      @Search.defaultSearchElement: true
      //      cast( Step.MasterDataChangeProcess as mdc_process_id_alpha_out ) as

      @UI.lineItem: [{ position : 10 }]
      Step.MasterDataChangeProcess,
      @UI.lineItem: [{ position : 20 }]
      Step.MDChgProcessStep,
      Step.MDChgProcessStepType,
      @ObjectModel.readOnly: true
      _StepDescription.MDChgProcessStepDescription,
      Step.MDChgProcessStepStatus,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_STEP_CALC_EXIT'
      cast ( ' ' as abap_boolean preserving type )                                as MDChangeProcessStepHasError,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_STEP_CALC_EXIT'
      cast ( 0 as abap.int4 )                                                     as MDChgProcStepNumberOfWarnings,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_STEP_CALC_EXIT'
      cast ( 0 as abap.int4 )                                                     as MDChgProcessStepNumberOfErrors,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_STEP_CALC_EXIT'
      cast ( 0 as abap.int4 )                                                     as MDChgProcStpNumberOfExceptions,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      sum ( _ModifiedObjects.MDChgProcModifdObjectsCount )                        as MDChgProcModifdObjectsCount,
      //      @ObjectModel.readOnly: true

      //      @ObjectModel.virtualElement: true

      //      @ObjectModel.virtualElementCalculatedBy: 'ABAP:cl_mdc_process_step_calc_exit'

      //      cast ( ' ' as abap_boolean preserving type )                as MDChgProcStpHasMappingAdapter,

      @ObjectModel.readOnly: true
      //      @ObjectModel.virtualElement: true

      //      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_STEP_CALC_EXIT'

      @Semantics.quantity.unitOfMeasure: 'MDChangeProcStepProgressUnit'
      cast ( Step._StepProgress.MDChgProcStpProgressRatioInPct as abap.dec(3,0) ) as MDChgProcStpProgressRatioInPct,
      //      cast( 0 as abap.dec( 3, 0 ) )                        as MDChgProcStpProgressRatioInPct,

      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      cast( '%' as msehi )                                                        as MDChangeProcStepProgressUnit,
      Step.MDChgProcessStepAdapter,
      Step.MDChgProcessStepAdapterConfign,
      Step.MDChgProcessStepChkPointIsActv,
      Step.MDChgProcessStepOriglNumber,
      Step.MDChgProcessStepOriglSqncNmbr,
      Step.MDChgProcessStepStartIsReqd,
      Step.MDChgProcessSrceObjectTypeCode,
      Step.MDChgProcessStepFilterChain,
      Step.MDChgProcessStepStartDateTime,
      Step.MDChgProcessStepFinishDateTime,
      Step.MDChgProcessStepConfign,
      Step.MDChgProcessStpOwnConfignIsRqd,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      cast ( ' ' as abap_boolean preserving type )                                as MDChangeProcessStepIsTransient,
      Step.MDChgProcIsAdhocStep,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_STEP_CALC_EXIT'
      cast ( ' ' as abap_boolean preserving type )                                as MDChgProcStepScheduleIsRecmdd,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_STEP_CALC_EXIT'
      cast( '' as mdc_business_system )                                           as MDChgProcessSrceSystem, //for cross app navigation to SOM

      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_STEP_CALC_EXIT'
      cast( '' as mdc_source_id  )                                                as MDChgProcessSrceObject, //for cross app navigation to SOM

      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_STEP_CALC_EXIT'
      cast ( '' as boole_d preserving type )                                      as MDChgProcStepIsRollbackAllowed,
      @ObjectModel.readOnly: true
      cast ( case
        when Process.MDChgProcessCurrentStepNumber = Step.MDChgProcessStep then 'X'
        else ' ' end as boole_d preserving type )                                 as MDChgProcessStepIsCurrentStep,

      Step.MDChgProcessStepWrkflwDefID,
      Step.MDChgProcessStepWrkflwHandle,
      Step.MDChgProcessStepWrkflwSts,
      Step.MDChgProcessStepWrkflwOvrlDcsn,

      //      count( distinct MDChgProcessStepUUID )                as MDChgProcessStepsCount,

      /* Associations */
      //I_MDChgProcessStepTP

      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT ]
      _Root,
      //      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]

      //      @ObjectModel.readOnly: true

      _MDChangeProcessLogHeader,
      _ModifiedObjects
}
group by
  Step.MDChgProcessStepUUID,
  Step.MasterDataChangeProcessUUID,
  _RootUpdateToken.MDChgProcessUpdateToken,
  Step.MasterDataChangeProcess,
  Step.MDChgProcessStep,
  Step.MDChgProcessStepType,
  Step.MDChgProcessStepStatus,
  Step.MDChgProcessStepAdapter,
  Step.MDChgProcessStepAdapterConfign,
  Step.MDChgProcessStepChkPointIsActv,
  Step.MDChgProcessStepOriglNumber,
  Step.MDChgProcessStepOriglSqncNmbr,
  Step.MDChgProcessStepStartIsReqd,
  Step.MDChgProcessSrceObjectTypeCode,
  Step.MDChgProcessStepFilterChain,
  Step.MDChgProcessStepStartDateTime,
  Step.MDChgProcessStepFinishDateTime,
  Step.MDChgProcessStepConfign,
  Step.MDChgProcessStpOwnConfignIsRqd,
  Step.MDChgProcIsAdhocStep,
  Step.MDChgProcessStepWrkflwDefID,
  Step.MDChgProcessStepWrkflwHandle,
  Step.MDChgProcessStepWrkflwSts,
  Step.MDChgProcessStepWrkflwOvrlDcsn,
  Step._StepProgress.MDChgProcStpProgressRatioInPct,
  _StepDescription.MDChgProcessStepDescription,
  Process.MDChgProcessCurrentStepNumber