C_FMEAEffectFDP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Effects of FMEA'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
@ObjectModel.modelingPattern:           #OUTPUT_FORM_DATA_PROVIDER
@ObjectModel.supportedCapabilities:  [  #OUTPUT_FORM_DATA_PROVIDER   ]
@VDM: { viewType: #CONSUMPTION }

define view entity C_FMEAEffectFDP
  as select from I_FMEAEffectNode as _FMEANode

  association [0..1] to I_FMEALongText as _FMEANodeLongText on  $projection.FMEAEffectOriginUUID         = _FMEANodeLongText.FMEANodeUUID
                                                            and _FMEANodeLongText.Language               = $session.system_language
                                                            and _FMEANodeLongText.LongTextInternalNumber = 1

{
  key FMEANodeUUID                                                                                                                       as FMEAEffectUUID,
      FMEANode                                                                                                                           as FMEAEffect,
      FMEAHeaderUUID,
      FMEANodeType,
      FMEANodeListType,
      FMEAItemType,
      FMEANodeReferenceUUID,
      FMEAParentNodeUUID,
      FMEAFailureModeUUID,
      FMEAEffectOriginUUID,
      case when _FMEAEffectOrigin.FMEANodeUUID is null then _FMEANode._FMEANode.FMEAValuationProfile
      else _FMEAEffectOrigin.FMEAValuationProfile end                                                                                    as FMEAValuationProfile,
      case when _FMEAEffectOrigin.FMEANodeUUID is null then _FMEANode._FMEANode.FMEAHasValuation
      else _FMEAEffectOrigin.FMEAHasValuation end                                                                                        as FMEAHasValuation,
      case when _FMEAEffectOrigin.FMEANodeUUID is null then _FMEANode._FMEANode.FMEAValnProfileValuation
      else _FMEAEffectOrigin.FMEAValnProfileValuation end                                                                                as FMEAValnProfileValuation,
      case when _FMEAEffectOrigin.FMEANodeUUID is null then _FMEANode._FMEANode.FMEAValuationScoreValue
      else _FMEAEffectOrigin.FMEAValuationScoreValue end                                                                                 as FMEAValuationScoreValue,
      _FMEAEffectOrigin._FMEANodeText[ 1:Language = $session.system_language ].FMEANodeDescription                                       as FMEAEffectDescription,
      _FMEANodeLongText.FMEALongText                                                                                                     as FMEAEffectLongText,

      //Function of Effect

      case when FMEAItemType = '805' then
        case  when _FMEAReferenceNode.FMEANodeReferenceUUID is null then ''
        else _FMEAReferenceNode._FMEANodeHierarchy._FMEAParentNodeAssignment.FMEANode
        end
      else _FMEANodeHierarchy._FMEAParentNodeAssignment.FMEANode   //FMEAItemtype = 813

      end                                                                                                                                as FMEAEffectFunction,
      //Text retrieval assumes that if a link is given in the Effect, the parent of the corresponding failure mode is the function

      _FMEAEffectOrigin._FMEANodeHierarchy._FMEAParentNodeText[ 1:Language = $session.system_language ].FMEANodeDescription              as FMEAEffectFunctionDescription,
      _FMEAEffectOrigin._FMEANodeHierarchy._FMEAParentNodeLongText[ 1:Language = $session.system_language ].FMEALongText                 as FMEAEffectFunctionLongText,

      //Element of Effect

      case when FMEAItemType = '805' then
        case  when _FMEAReferenceNode.FMEANodeReferenceUUID is null then ''
        else _FMEAReferenceNode._FMEANodeHierarchy._FMEANodeParent._FMEAParentNodeAssignment.FMEANode
        end
      else _FMEANodeHierarchy._FMEANodeParent._FMEAParentNodeAssignment.FMEANode   //FMEAItemtype = 813

      end                                                                                                                                as FMEAEffectElement,
      case when FMEAItemType = '805' then
        case  when _FMEAReferenceNode.FMEANodeReferenceUUID is null then ''
        else 
          case when _FMEAReferenceNode._FMEANodeHierarchy._FMEANodeParent._FMEAParentNode.FMEANodeReferenceObjectType is initial then
            _FMEAReferenceNode._FMEANodeHierarchy._FMEANodeParent._FMEAParentNode._FMEANodeText[ 1:Language = $session.system_language ].FMEANodeDescription
          else
            _FMEAReferenceNode._FMEANodeHierarchy._FMEANodeParent._FMEAParentNode._FMEAReference._FMEAText[ 1:Language = $session.system_language ].FMEADescription
          end
        end
      else 
        case when _FMEANodeHierarchy._FMEANodeParent._FMEAParentNode.FMEANodeReferenceObjectType is initial then 
          _FMEANodeHierarchy._FMEANodeParent._FMEAParentNodeText[ 1:Language = $session.system_language ].FMEANodeDescription
        else
          _FMEANodeHierarchy._FMEANodeParent._FMEAParentNode._FMEAReference._FMEAText[ 1:Language = $session.system_language ].FMEADescription
        end
      end                                                                                                                                as FMEAEffectElementDescription,
      //_FMEAEffectOrigin._FMEANodeHierarchy._FMEANodeParent._FMEAParentNodeLongText[ 1:Language = $session.system_language ].FMEALongText as FMEAEffectElementLongText,


      ChangedDateTime,
      CreationDate,
      

      /* Associations */
      _FailureModeEffectAnalysis,
      _FMEANodeChild,
      _FMEANodeText,
      _FMEAReferenceNode,
      _FMEATask,
      _FMEANodeHierarchy,
      _FMEAEffectOrigin
}