I_FMEALongText

@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@EndUserText.label: 'Long Text for FMEA'
@VDM.viewType: #BASIC
@ObjectModel: {
    dataCategory: #TEXT,
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #L,
        serviceQuality: #C
    }
}
define view entity I_FMEALongText as select from plmm_audit_ltext 
    association [0..1] to I_FMEANodeHierarchy as _FMEANodeHierarchy
    on $projection.FMEANodeUUID = _FMEANodeHierarchy.FMEANodeUUID
    association [1..1] to I_Language as _Language            
      on $projection.Language = _Language.Language
{
    @ObjectModel.foreignKey.association: '_FMEANodeHierarchy'
    key cast( guid as plmt_fmea_node_guid preserving type ) as FMEANodeUUID,
    key counter as LongTextInternalNumber,
    @ObjectModel.foreignKey.association: '_Language'
    @Semantics.language: true
    key langu as Language,
    textid as LongTextID,
  
    content     as FMEALongText, 
    created_by  as LongTextCreatedByUser,
    created_at  as LongTextCreatedAt,
    changed_by  as LongTextLastChangedByUser,
    changed_at  as LongTextLastChangedAt,
    
    //Association

    _FMEANodeHierarchy,
    _Language
    
}