I_FMEAEFFECTNODE

CDS View

FMEA Effect Node

I_FMEAEFFECTNODE is a CDS View in S/4HANA. FMEA Effect Node. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
C_FMEAEffectFDP view_entity from CONSUMPTION Effects of FMEA
I_FMEAEffectNodeTP view_entity from TRANSACTIONAL Transactional Processing for FMEA Node 
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'FMEA Effect Node'
@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #M,
    serviceQuality: #C
}
define view entity I_FMEAEffectNode
  as select from I_FMEANode as FMEANode
  association [0..*] to I_FMEANodeText as _FMEANodeText      on $projection.FMEANodeUUID = _FMEANodeText.FMEANodeUUID
  association [0..1] to I_FMEANode     as _FMEANode          on $projection.FMEANodeUUID = _FMEANode.FMEANodeUUID
  association [0..1] to I_FMEANode     as _FMEAReferenceNode on $projection.FMEANodeReferenceUUID = _FMEAReferenceNode.FMEANodeUUID
  association [0..1] to I_FMEANode     as _FMEAEffectOrigin  on $projection.FMEAEffectOriginUUID = _FMEAEffectOrigin.FMEANodeUUID
{
  key FMEANode.FMEANodeUUID,
      FMEANode._FMEANodeAssignment.FMEANode,
      FMEANode.FMEAHeaderUUID,
      FMEANode.FMEANodeType,
      FMEANode.FMEANodeListType,
      FMEANode.FMEAItemType,
      FMEANode.FMEANodeReferenceUUID,
      FMEANode.FMEANodeReferenceObjectType,
      FMEANode._FMEANodeHierarchy.FMEAParentNodeUUID,
      FMEANode._FMEANodeHierarchy.FMEAParentNodeUUID as FMEAFailureModeUUID,
      case  when _FMEAReferenceNode.FMEANodeReferenceUUID is not null then
        case when _FMEAReferenceNode._FMEAReferenceNode.FMEANodeReferenceUUID is null then _FMEAReferenceNode.FMEANodeUUID
        else _FMEAReferenceNode.FMEANodeReferenceUUID //_FMEAReferenceNode.FMEANodeUUID

        end
      else hextobin('00000000000000000000000000000000')
      end          as FMEAEffectOriginUUID,

      ChangedDateTime,
      FMEANode._FMEANodeAssignment.CreationDate,
      //Associations

      _FMEANode,
      _FMEAReferenceNode,
      _FMEAEffectOrigin,
      _FailureModeEffectAnalysis,
      _FMEANodeHierarchy,
      _FMEANodeChild,
      _FMEATask,
      _FMEANodeText
}
where
  FMEAItemType = '805'

union select from I_FMEANode as FMEANode
  inner join      I_FMEAFailureNet as _FailureNet on FMEANode.FMEANodeReferenceUUID = _FailureNet.FMEANodeReferenceUUID
  inner join      I_FMEANode       as _Failure    on  FMEANode.FMEAHeaderUUID = _Failure.FMEAHeaderUUID
                                                  and _FailureNet.FMEANodeUUID = _Failure.FMEANodeUUID

association [0..*] to I_FMEANodeText as _FMEANodeText      on $projection.FMEANodeUUID = _FMEANodeText.FMEANodeUUID
association [0..1] to I_FMEANode     as _FMEANode          on $projection.FMEANodeUUID = _FMEANode.FMEANodeUUID
association [0..1] to I_FMEANode     as _FMEAReferenceNode on FMEANode.FMEANodeReferenceUUID = _FMEAReferenceNode.FMEANodeUUID
association [0..1] to I_FMEANode     as _FMEAEffectOrigin  on $projection.FMEAEffectOriginUUID = _FMEAEffectOrigin.FMEANodeUUID
{
  key FMEANode.FMEANodeUUID,
      FMEANode._FMEANodeAssignment.FMEANode,
      FMEANode.FMEAHeaderUUID,
      FMEANode.FMEANodeType,
      FMEANode.FMEANodeListType,
      FMEANode.FMEAItemType,
      FMEANode.FMEANodeReferenceUUID,
      FMEANode.FMEANodeReferenceObjectType,
      FMEANode._FMEANodeHierarchy.FMEAParentNodeUUID,
      _Failure.FMEANodeUUID as FMEAFailureModeUUID,
      case  when _FMEAReferenceNode.FMEANodeReferenceUUID is not null then 
        _FMEAReferenceNode.FMEANodeUUID
      else hextobin('00000000000000000000000000000000')        
      end          as FMEAEffectOriginUUID,

      _FMEANode.ChangedDateTime,
      FMEANode._FMEANodeAssignment.CreationDate,
      
      //Associations

      _FMEANode,
      _FMEAReferenceNode,
     _FMEAEffectOrigin,      
      FMEANode._FailureModeEffectAnalysis,
      FMEANode._FMEANodeHierarchy,
      FMEANode._FMEANodeChild,
      FMEANode._FMEATask,
      _FMEANodeText
}
where
  _FMEANode.FMEAItemType = '813'

Learn More