C_CAInvcgOvwDisp

@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Fakturierungsübersicht für Vertr.konten'
@Consumption.semanticObject: 'ContractAccount'
@Metadata.allowExtensions: true
@ObjectModel:{
  usageType:{
    serviceQuality: #C,
    sizeCategory: #L,
    dataClass: #MIXED
  }
}
define view entity C_CAInvcgOvwDisp
  as select from I_ContractAccountPartner as _ContractAccountPartner

  // UI FACETS

  association [0..*] to C_CAInvcgOvwInvcgDocHeader   as _CAInvcgOvwInvcgDocHeader   on  $projection.ContractAccount = _CAInvcgOvwInvcgDocHeader.ContractAccount
                                                                                    and $projection.BusinessPartner = _CAInvcgOvwInvcgDocHeader.BusinessPartner
  association [0..*] to C_CAInvcgOvwBillgDocHeader   as _CAInvcgOvwBillgDocHeader   on  $projection.ContractAccount = _CAInvcgOvwBillgDocHeader.ContractAccount
                                                                                    and $projection.BusinessPartner = _CAInvcgOvwBillgDocHeader.BusinessPartner
  association [0..*] to C_CAInvcgOvwBillgPln         as _CAInvcgOvwBillgPln         on  $projection.ContractAccount = _CAInvcgOvwBillgPln.ContractAccount
                                                                                    and $projection.BusinessPartner = _CAInvcgOvwBillgPln.BusinessPartner

  association [0..*] to C_CAInvcgOvwBillgReq         as _CAInvcgOvwBillgReq         on  $projection.ContractAccount = _CAInvcgOvwBillgReq.ContractAccount
                                                                                    and $projection.BusinessPartner = _CAInvcgOvwBillgReq.BusinessPartner

  association [0..*] to C_CAInvcgDocContractAccount  as _CAInvcgDocContractAccount  on  $projection.ContractAccount = _CAInvcgDocContractAccount.ContractAccount
  association [0..*] to C_CAInvcgClrfctnCase         as _CAInvcgClrfctnCase         on  $projection.ContractAccount = _CAInvcgClrfctnCase.ContractAccount
  association [0..*] to C_CAInvcgDocReversalRequest  as _CAInvcgDocReversalRequest  on  $projection.ContractAccount = _CAInvcgDocReversalRequest.ContractAccount
                                                                                    and $projection.BusinessPartner = _CAInvcgDocReversalRequest.BusinessPartner
  association [0..*] to C_CAInvcgOvwInvcgRequest     as _CAInvcgRequest             on  $projection.ContractAccount = _CAInvcgRequest.ContractAccount
                                                                                    and $projection.BusinessPartner = _CAInvcgRequest.BusinessPartner
  association [0..*] to C_CABillgDocReversalRequest  as _CABillgDocReversalRequest  on  $projection.ContractAccount = _CABillgDocReversalRequest.ContractAccount
                                                                                    and $projection.BusinessPartner = _CABillgDocReversalRequest.BusinessPartner
  association [0..*] to C_CABllbleItmReversalRequest as _CABllbleItmReversalRequest on  $projection.ContractAccount = _CABllbleItmReversalRequest.ContractAccount
                                                                                    and $projection.BusinessPartner = _CABllbleItmReversalRequest.BusinessPartner
  association [0..*] to C_CAInvcgOvwPrvdrContr       as _CAInvcgOvwPrvdrContr       on  $projection.ContractAccount = _CAInvcgOvwPrvdrContr.ContractAccount
                                                                                    and $projection.BusinessPartner = _CAInvcgOvwPrvdrContr.BusinessPartner
  association [0..*] to C_CAInvcgChargeAndDiscount   as _CAInvcgChargeAndDiscount   on  $projection.ContractAccount = _CAInvcgChargeAndDiscount.ContractAccount
                                                                                    and $projection.BusinessPartner = _CAInvcgChargeAndDiscount.BusinessPartner
{

         //VKONT

         @ObjectModel.text.element: [ 'ContractAccountName' ]
  key    _ContractAccountPartner.ContractAccount,

         //GPART

         @ObjectModel.text.element: [ 'BusinessPartnerFullName']

  key    _ContractAccountPartner.BusinessPartner,

         //GPART

         _ContractAccountPartner._BusinessPartner.FirstName,

         _ContractAccountPartner._BusinessPartner.LastName,

         _ContractAccountPartner._BusinessPartner.BusinessPartnerFullName,

         cast( concat_with_space(_ContractAccountPartner._BusinessPartner._CurrentDefaultAddress._StandardAddress.StreetName,
                                 _ContractAccountPartner._BusinessPartner._CurrentDefaultAddress._StandardAddress.HouseNumber, 1)
               as adress_gfn_kk preserving type )  as StreetName,


         cast( concat_with_space(_ContractAccountPartner._BusinessPartner._CurrentDefaultAddress._StandardAddress.PostalCode,
                                 _ContractAccountPartner._BusinessPartner._CurrentDefaultAddress._StandardAddress.CityName, 1)
               as city_gfn_kk preserving type )    as AddressCityName,


         cast( _BusinessPartner._CurrentDefaultAddress._StandardAddress._Country._Text[1: Language=$session.system_language].CountryName
               as country_gfn_kk preserving type ) as Country,

         //VKONT

         _ContractAccountPartner._ContrAcc.ContractAccountName,

         //INV_CATEGORY

         _ContractAccountPartner.CAInvcgCategory,

         //INV_SCHEDULE

         _ContractAccountPartner.CAInvcgSchedule,

         //INV_CURR

         _ContractAccountPartner.CATargetCurrencyForInvoicing,

         //INV_FORM_DET_KEY

         _ContractAccountPartner.CADetnCodeForAltvInvoiceForm,

         //INV_CYCLE

         @Consumption.valueHelpDefinition: [{ entity: { name: 'I_CABillgCycle', element: 'CABillgCycle' } }]
         _ContractAccountPartner.CABillgCycle,

         //INV_CYCLE_DAY

         _ContractAccountPartner.CALastDayOfBillingPeriod,

         //INV_CYCLE_START

         _ContractAccountPartner.CAStartDateForBillingPeriod,

         //CreationDate

         _ContractAccountPartner.CreationDate,

         _ContractAccountPartner.CAAuthorizationGroup,

         _ContractAccountPartner.CAStandardCompanyCode,

         // Make association public

         _ContrAcc                                 as _ContractAccountHeader,

         _BusinessPartner,

         _CAInvcgOvwInvcgDocHeader,

         _CAInvcgOvwBillgDocHeader,

         _CAInvcgOvwBillgPln,

         _CAInvcgOvwBillgReq,

         _CAInvcgDocContractAccount,

         _CAInvcgOvwPrvdrContr,

         _CAInvcgChargeAndDiscount,

         _CAInvcgClrfctnCase,

         _CAInvcgDocReversalRequest,

         _CABillgDocReversalRequest,

         _CABllbleItmReversalRequest,

         _InvcgCategory                            as _CAInvcgCategory,

         _InvcgSchedule                            as _CAInvcgSchedule,

         _BillgCycle                               as _CABillgCycle,

         _CurrencyForInvoicing,

         _ContrAcc,

         _CAInvcgRequest
}