C_CAInvcgDocReversalRequest

@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Stornoauftrag für Fakt.belege'
@Metadata.allowExtensions: true
@ObjectModel:{
  usageType:{
    serviceQuality: #D,
    sizeCategory: #L,
    dataClass: #TRANSACTIONAL
  },
  semanticKey: ['CAInvoicingDocument']
}
define view entity C_CAInvcgDocReversalRequest
  as select from I_CAInvcgDocReversalRequest as _CAInvcgDocReversalRequest
  association [0..1] to C_CAInvcgDocHeader as _CAInvcgDocHeader on $projection.CAInvoicingDocument = _CAInvcgDocHeader.CAInvoicingDocument
{
      //  INVDOCNO

  key _CAInvcgDocReversalRequest.CAInvoicingDocument,

      // REVTASK

  key _CAInvcgDocReversalRequest.CARvslTsk,

      // STATUS

      @ObjectModel.text.element: ['CAReversalRequestStatusText']
      _CAInvcgDocReversalRequest.CAReversalRequestStatus,

      // revreason

      @ObjectModel.text.element: ['CAInvcgDocReversalReasonText']
      _CAInvcgDocReversalRequest.CAInvcgDocumentReversalReason,

      // stodt

      _CAInvcgDocReversalRequest.CAReversalRequestDate,

      // inv_type

      @ObjectModel.text.element: ['CAInvcgTypeText']
      _CAInvcgDocReversalRequest.CAInvcgType,

      // inv_process

      @ObjectModel.text.element: ['CAInvcgProcessText']
      _CAInvcgDocReversalRequest.CAInvcgProcess,

      // inv_category

      @ObjectModel.text.element: ['CAInvcgCategoryText']
      _CAInvcgDocReversalRequest.CAInvcgCategory,

      // crname

      _CAInvcgDocReversalRequest.CreatedByUser,

      // crdate

      @Consumption.hidden: true
      _CAInvcgDocReversalRequest.CreationDate,

      // crtime

      @Consumption.hidden: true
      _CAInvcgDocReversalRequest.CreationTime,

      //combined field of crdate and crtime

      @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_FILTER_DATETIME'
      cast(dats_tims_to_tstmp(_CAInvcgDocReversalRequest.CreationDate, _CAInvcgDocReversalRequest.CreationTime,
      abap_system_timezone($session.client, 'NULL'),
      $session.client, 'NULL') as crtimestamp_kk)   as CreationDateTime,


      // Hidden fields

      // gpart

      @ObjectModel.text.element: ['BusinessPartnerFullName']
      _CAInvcgDocReversalRequest.BusinessPartner,

      _CAInvcgDocReversalRequest._CAInvcgDocHeader._BusinessPartner.BusinessPartnerFullName,

      // gpart_sel

      _CAInvcgDocReversalRequest.CABusinessPartnerDocRlvt,

      // vkont

      @ObjectModel.text.element: ['ContractAccountName']
      _CAInvcgDocReversalRequest.ContractAccount,

      @Semantics.text:true
      _CAInvcgDocReversalRequest._CAInvcgDocHeader._ContractAccountPartner.ContractAccountName,

      // vkont_sel

      _CAInvcgDocReversalRequest.CAContractAccountDocRlvt,

      // mdcat

      @ObjectModel.text.element: ['CAInvcgMasterDataTypeText']
      _CAInvcgDocReversalRequest.CAInvcgMasterDataType,

      // invdoc_crdate

      @Consumption.hidden: true
      _CAInvcgDocReversalRequest.CAInvcgCreationDate,

      // invdoc_crtime

      @Consumption.hidden: true
      _CAInvcgDocReversalRequest.CAInvcgCreationTime,

      //combined field of invdoc_crdate and invdoc_crtime

      @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_FILTER_DATETIME'
      cast(dats_tims_to_tstmp(_CAInvcgDocReversalRequest.CAInvcgCreationDate, _CAInvcgDocReversalRequest.CAInvcgCreationTime,
      abap_system_timezone($session.client, 'NULL'),
      $session.client, 'NULL') as invdoc_crtsmp_kk) as CAInvcgCreationDateTime,

      // invpercat

      @ObjectModel.text.element: ['CAInvcgPeriodCatText']
      _CAInvcgDocReversalRequest.CAInvcgDocPeriodCategory,

      // invperiod

      _CAInvcgDocReversalRequest.CAInvcgDocPeriodDate,

      // faedn

      _CAInvcgDocReversalRequest.CANetDueDate,

      // total_curr

      _CAInvcgDocReversalRequest.TransactionCurrency,

      // total_amt

      _CAInvcgDocReversalRequest.CAAmountInTransactionCurrency,

      // loedt

      _CAInvcgDocReversalRequest.CADeletionDate,


      _CAInvcgDocReversalReason._CAInvcgDocReversalReasonText[1: Language=$session.system_language].CAInvcgDocReversalReasonText,

      @Semantics.text:true
      _CAReversalRequestStatus._CAReversalRequestStatusText[1: Language=$session.system_language].CAReversalRequestStatusText,

      _CAInvcgType._CAInvcgTypeText[1: Language=$session.system_language].CAInvcgTypeText,

      _CAInvcgProcess._CAInvcgProcessText[1: Language=$session.system_language].CAInvcgProcessText,

      _CAInvcgCategory._CAInvcgCategoryText[1: Language=$session.system_language].CAInvcgCategoryText,

      _CAInvcgMasterDataType._CAInvcgMasterDataTypeText[1: Language=$session.system_language].CAInvcgMasterDataTypeText,

      _CAInvcgPeriodCat._CAInvcgPeriodCatText[1: Language=$session.system_language].CAInvcgPeriodCatText,

      _CAInvcgDocHeader
}