C_CAInvcgOvwBillgDocHeader

@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations: [ '_CAInvcgUserContact' ]
@EndUserText.label: 'Abrechnungsbelegkopf anzeigen'
@Consumption.semanticObject: 'CABillgDocument'
@Metadata.allowExtensions: true
@ObjectModel:{
  usageType:{
    serviceQuality: #D,
    sizeCategory: #XL,
    dataClass: #MIXED
  },
  semanticKey: ['CABillgDocument']
}
define view entity C_CAInvcgOvwBillgDocHeader
  as select from I_CABillgDocHeader as _CABillgDocHeader
  association [0..1] to I_CABillgDocInvcgDoc     as _CABillgDocInvcgDoc     on  $projection.CABillgDocument = _CABillgDocInvcgDoc.CABillgDocument

  // Value help with tables

  association [0..1] to I_BusinessPartner        as _BusinessPartner        on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [0..1] to I_ContractAccountPartner as _ContractAccountPartner on  $projection.ContractAccount = _ContractAccountPartner.ContractAccount
                                                                            and $projection.BusinessPartner = _ContractAccountPartner.BusinessPartner
                                                                            and $projection.BusinessPartner = _ContractAccountPartner.BusinessPartner
  association [0..1] to I_ContractAccountHeader  as _ContractAccountHeader  on  $projection.ContractAccount = _ContractAccountHeader.ContractAccount

  association [0..1] to I_CAInvcgDocumentType    as _CAInvcgDocumentType    on  $projection.CAInvcgDocumentType            = _CAInvcgDocumentType.CAInvcgDocumentType
                                                                            and $projection.CAApplicationArea              = _CAInvcgDocumentType.CAApplicationArea
                                                                            and _CAInvcgDocumentType.NameNumberRangeObject = 'FKKINVBILL'
  association [0..1] to C_CAInvcgUserContact     as _CAInvcgUserContact     on  $projection.CreatedByUser = _CAInvcgUserContact.ContactCardID

  // extension

  association [0..1] to E_CABillgDocHeader       as _Extension              on  $projection.CABillgDocument = _Extension.CABillgDocument
{
      //BILLDOCNO

  key _CABillgDocHeader.CABillgDocument,

      //INVDOCNO

      @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_EXIT_BILLDOC_DSP'
      CAInvoicingDocument                                                                                                                                             as CAInvoicingDocument,

      //GPART

      @Semantics: { name.fullName: true }
      _BusinessPartner.FirstName,

      @Semantics: { name.fullName: true }
      _BusinessPartner.LastName,

      _BusinessPartner.BusinessPartnerFullName,

      concat_with_space(_BusinessPartner._CurrentDefaultAddress._StandardAddress.StreetName, _BusinessPartner._CurrentDefaultAddress._StandardAddress.HouseNumber, 1) as StreetName,


      concat_with_space(_BusinessPartner._CurrentDefaultAddress._StandardAddress.PostalCode, _BusinessPartner._CurrentDefaultAddress._StandardAddress.CityName, 1)    as AddressCityName,

      _BusinessPartner._CurrentDefaultAddress._StandardAddress.Country,

      @ObjectModel.text.element: ['BusinessPartnerFullName']
      _CABillgDocHeader.BusinessPartner,

      //VKONT

      @ObjectModel.text.element: ['ContractAccountName']
      _CABillgDocHeader.ContractAccount,

      _ContractAccountHeader.ContractAccountName,

      //bill_type

      @ObjectModel.text.element: ['CABillgTypeText']
      _CABillgDocHeader.CABillgType,

      //date_from

      _CABillgDocHeader.CABillgDocPeriodStartDate,

      //date_to

      _CABillgDocHeader.CABillgDocPeriodEndDate,

      //crdate

      @Consumption.hidden: true
      _CABillgDocHeader.CABillgDocCreationDate,

      //crtime

      @Consumption.hidden: true
      _CABillgDocHeader.CABillgDocCreationTime,

      //combined field of crdate and crtime

      @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_FILTER_DATETIME'
      cast(dats_tims_to_tstmp(_CABillgDocHeader.CABillgDocCreationDate, _CABillgDocHeader.CABillgDocCreationTime,
      abap_system_timezone($session.client, 'NULL'),
      $session.client, 'NULL') as billdoc_crtsmp_kk)                                                                                                                  as CABillgDocCreationDateTime,

      //revreason

      @ObjectModel.text.element: ['CABillgDocReversalReasonText']
      _CABillgDocHeader.CABillgDocumentReversalReason,

      //simulated

      _CABillgDocHeader.CABillgIsDocumentSimulated,

      //refdocno

      _CABillgDocHeader.CABillgDocumentExternal,

      //log_system

      _CABillgDocHeader.LogicalSystem,

      //applk

      @ObjectModel.foreignKey.association: '_CAApplicationArea'
      _CABillgDocHeader.CAApplicationArea,

      //srcprocess

      @ObjectModel.text.element: ['CABillgDocOriginProcessText']
      _CABillgDocHeader.CABillgDocOriginProcess,

      //srcdoctype

      _CABillgDocHeader.CAInvcgSourceDocumentType,

      //techdoctype

      @ObjectModel.text.element: ['CAInvcgDocTechDocTypeText']
      _CABillgDocHeader.CAInvcgTechnicalDocumentType,

      //doctype

      @ObjectModel.text.element: ['CAInvcgDocumentTypeText']
      _CABillgDocHeader.CAInvcgDocumentType,

      //targprocess

      @ObjectModel.text.element:  [  'CAInvcgTargetProcText']
      _CABillgDocHeader.CAInvcgTargetProcess,

      //mdcat

      @ObjectModel.text.element: ['CAInvcgMasterDataTypeText']
      _CABillgDocHeader.CAInvcgMasterDataType,

      //gpart_inv

      _CABillgDocHeader.CAInvcgAltvBusinessPartner,

      //vkont_inv

      _CABillgDocHeader.CAInvcgAltvContractAccount,

      //bill_basedate

      _CABillgDocHeader.CABillgBaseDate,

      //bill_curr

      _CABillgDocHeader.CABillgCurrency,

      //inv_curr

      _CABillgDocHeader.CAInvcgCurrency,

      //tax_det_type

      @ObjectModel.foreignKey.association: '_CATaxDetnType'
      @Consumption:       { valueHelp: '_CATaxDetnType' }
      @ObjectModel.text.element: ['CATaxDetnTypeText']
      _CABillgDocHeader.CATaxDetnType,

      //tax_date_type

      @ObjectModel.text.element: ['CATaxDateTypeText']
      _CABillgDocHeader.CATaxDateType,

      //inv_category

      @ObjectModel.text.element: ['CAInvcgCategoryText']
      _CABillgDocHeader.CAInvcgCategory,

      //separate_inv

      @ObjectModel.text.element: ['CAInvcgControlOfInvcgUnitTxt']
      _CABillgDocHeader.CAInvcgControlOfInvoicingUnit,

      //invoice_first

      _CABillgDocHeader.CAInvcgFirstDate,

      //reversaldoc

      @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_EXIT_BILLDOC_DSP'
      _CABillgDocHeader.CABillgReversalDocument,

      //reverseddoc

      @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_EXIT_BILLDOC_DSP'
      _CABillgDocHeader.CABillgReversedDocument,

      //adjustmentdoc

      @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_EXIT_BILLDOC_DSP'
      _CABillgDocHeader.CABillgAdjustmentDocument,

      //adjusteddoc

      @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_EXIT_BILLDOC_DSP'
      _CABillgDocHeader.CABillgAdjustedDocument,

      //corrcat

      @ObjectModel.text.element: ['CAInvcgCorrectionCatText']
      _CABillgDocHeader.CAInvcgCorrectionCategory,

      //trigdeleted

      _CABillgDocHeader.CaInvcgIsOrderDeleted,

      //xinfbill

      @Consumption:       { valueHelp: '_CABillgExistsAddInvcg' }
      @ObjectModel.text.element: ['CABillgAdditionalInvoiceText']
      _CABillgDocHeader.CABillgHasAdditionalInvoice,

      //invlock

      @ObjectModel.text.element:            ['CABillgLockedForInvcgText']
      _CABillgDocHeader.CABillgLockedForInvoicing,

      //add_group

      _CABillgDocHeader.CABillgGrpgOfAdditionalItems,

      //xinvbill_x

      _CABillgDocHeader.CABillgDocHasRefObjects,

      //recnum

      _CABillgDocHeader.CABillgDocumentNumberOfItems,

      //crname

      _CABillgDocHeader.CreatedByUser,

      //billrunno

      _CABillgDocHeader.CABillgDocInternalNumber,

      //bill_process

      @ObjectModel.text.element: ['CABillgProcessText']
      _CABillgDocHeader.CABillgProcess,

      //prepaid_incl

      _CABillgDocHeader.CABillgDocHasPrepaidItems,

      //pprefill_incl

      _CABillgDocHeader.CABillgDocHasRefillItems,

      //revrec_incl

      _CABillgDocHeader.CABillgDocHasRevnRecgnItems,

      //ptsrl

      _CABillgDocHeader.CAPartnerSettlementRule,

      //invstatus

      _CABillgDocHeader.CABillgDocumentInvcgStatus,

      //invcrdate

      _CABillgDocHeader.CAInvcgCreationDate,

      //keypp

      _CABillgDocHeader.CASubAreaForParallelization,

      //altmd_orig_incl

      _CABillgDocHeader.CAAltvMDOriginalIsIncluded,


      _CAInvcgDocumentType._CAInvcgDocumentTypeText[1: Language=$session.system_language].CAInvcgDocumentTypeText,

      _CABillgDocOriginProcess._CABillgDocOriginProcessText[1: Language=$session.system_language].CABillgDocOriginProcessText,

      _CAInvcgTargetProc._CAInvcgTargetProcText[1: Language=$session.system_language].CAInvcgTargetProcText,

      _CAInvcgCategory._CAInvcgCategoryText[1: Language=$session.system_language].CAInvcgCategoryText,

      _CABillgProcess._CABillgProcessText[1: Language=$session.system_language].CABillgProcessText,

      _CABillgType._CABillgTypeText[1: Language=$session.system_language].CABillgTypeText,

      _CAInvcgDocTechDocType._CAInvcgDocTechDocTypeText[1: Language=$session.system_language].CAInvcgDocTechDocTypeText,

      _CABillgDocReversalReason._CABillgDocReversalReasonText[1: Language=$session.system_language].CABillgDocReversalReasonText,

      _CAInvcgMasterDataType._CAInvcgMasterDataTypeText[1: Language=$session.system_language].CAInvcgMasterDataTypeText,

      _CATaxDetnType._CATaxDetnTypeText[1: Language=$session.system_language].CATaxDetnTypeText,

      _CATaxDateType._CATaxDateTypeText[1: Language=$session.system_language].CATaxDateTypeText,

      _CAInvcgControlOfInvcgUnit._CAInvcgControlOfInvcgUnitTxt[1: Language=$session.system_language].CAInvcgControlOfInvcgUnitTxt,

      _CAInvcgCorrectionCat._CAInvcgCorrectionCatText[1: Language=$session.system_language].CAInvcgCorrectionCatText,

      _CABillgExistsAddInvcg._CABillgExistsAddInvcgText[1: Language=$session.system_language].CABillgAdditionalInvoiceText,

      _CABillgLockedForInvcg._CABillgLockedForInvcgText[1: Language=$session.system_language].CABillgLockedForInvcgText,

      // Make association public

      _ContractAccountPartner,
      _ContractAccountHeader,
      _CABillgDocInvcgDoc,
      _BusinessPartner,
      _CAInvcgAltvBusinessPartner,
      _CAInvcgAltvContractAccount,
      _CABillgReversalDocument,
      _CABillgReversedDocument,
      _CABillgAdjustedDocument,
      _CABillgAdjustmentDocument,
      _CAApplicationArea,
      _CABillgCurrency,
      _CAInvcgCurrency,
      _CABillgDocOriginProcess,
      _CAInvcgTargetProc,
      _CAInvcgCategory,
      _CABillgProcess,
      _CABillgType,
      _CAInvcgDocTechDocType,
      _CAInvcgMasterDataType,
      _CATaxDetnType,
      _CATaxDateType,
      _CAInvcgDocumentType,
      _CAInvcgControlOfInvcgUnit,
      _CAInvcgCorrectionCat,
      _CABillgExistsAddInvcg,
      _CABillgLockedForInvcg,
      _CABillgDocReversalReason,

      _CAInvcgUserContact,

      concat('00000000', _CABillgDocHeader.CABillgDocument )                                                                                                          as CAInvcgSourceDocumentNumber,

      'INVBI'                                                                                                                                                         as CAInvcgSourceDocumentCat
}