I_BUSINESSPARTNERGOVTP

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
//@ObjectModel.sapObjectNodeType.name: 'BusinessPartner'

@Search.searchable
@VDM.lifecycle.contract.type: #NONE//SAP_INTERNAL_API

@VDM.viewType: #TRANSACTIONAL
@EndUserText.label: 'Business Partner (Governance)'
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define root view entity I_BusinessPartnerGovTP
  as select from I_BusinessPartnerGov as Governance
  composition [0..1] of I_BPChangeProcessGovTP         as _Process
  composition [0..*] of I_BusinessPartnerRoleGovTP     as _BusinessPartnerRole
  composition [0..*] of I_BusinessPartnerAddressGovTP  as _BusinessPartnerAddress
  //  composition [0..1] of I_BusPartStandardAddrGovTP  as _BusinessPartnerStdAddr

  composition [0..*] of I_BusPartIdentificationGovTP   as _BusinessPartnerIdentification
  composition [0..*] of I_BusPartTaxNumberGovTP        as _BusinessPartnerTaxNumber
  composition [0..*] of I_BusPartIndustryGovTP         as _BusinessPartnerIndustry
  composition [0..*] of I_BusinessPartnerBankGovTP     as _BusinessPartnerBank
  composition [0..*] of I_BPDataControllerGovernanceTP as _BusinessPartnerDataController
  association [0..*] to I_BusPartAddressUsageGovTP     as _BusinessPartnerAddressUsage on  $projection.BusinessPartnerUUID     = _BusinessPartnerAddressUsage.BusinessPartnerUUID
                                                                                       and $projection.MasterDataChangeProcess = _BusinessPartnerAddressUsage.MasterDataChangeProcess
                                                                                       and $projection.MDChgProcessSrceSystem  = _BusinessPartnerAddressUsage.MDChgProcessSrceSystem
                                                                                       and $projection.MDChgProcessSrceObject  = _BusinessPartnerAddressUsage.MDChgProcessSrceObject
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_BPRoleCategoryAllowListGovTP as _RoleAllowList               on  $projection.MasterDataChangeProcess = _RoleAllowList.MasterDataChangeProcess
                                                                                       and $projection.MDChgProcessSrceSystem  = _RoleAllowList.MDChgProcessSrceSystem
                                                                                       and $projection.MDChgProcessSrceObject  = _RoleAllowList.MDChgProcessSrceObject
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_BusinessPartnerAddressGovTP  as _BusinessPartnerStandardAddr on  $projection.BusinessPartnerUUID            = _BusinessPartnerStandardAddr.BusinessPartnerUUID
                                                                                       and $projection.MasterDataChangeProcess        = _BusinessPartnerStandardAddr.MasterDataChangeProcess
                                                                                       and $projection.MDChgProcessSrceSystem         = _BusinessPartnerStandardAddr.MDChgProcessSrceSystem
                                                                                       and $projection.MDChgProcessSrceObject         = _BusinessPartnerStandardAddr.MDChgProcessSrceObject
                                                                                       and _BusinessPartnerStandardAddr.StandardUsage = 'X'
                                                                                       
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to C_BusinessPartnerAddressDspGov as _BusinessPartnerAddressDsp   on  $projection.MasterDataChangeProcess = _BusinessPartnerAddressDsp.MasterDataChangeProcess
                                                                                       and $projection.MDChgProcessSrceSystem  = _BusinessPartnerAddressDsp.MDChgProcessSrceSystem
                                                                                       and $projection.MDChgProcessSrceObject  = _BusinessPartnerAddressDsp.MDChgProcessSrceObject
  association [0..1] to I_BusinessPartnerGrouping      as _BusinessPartnerGrouping     on  $projection.BusinessPartnerGrouping = _BusinessPartnerGrouping.BusinessPartnerGrouping
  association [0..1] to I_BusPartCategory              as _BusinessPartnerCategory     on  $projection.BusinessPartnerCategory = _BusinessPartnerCategory.BusinessPartnerCategory
  association [0..1] to I_BusinessPartnerLegalForm     as _BusinessPartnerLegalForm    on  $projection.LegalForm = _BusinessPartnerLegalForm.LegalForm
  association [0..1] to I_BuPaLegalEntity              as _BusinessPartnerLegalEntity  on  $projection.LegalEntityOfOrganization = _BusinessPartnerLegalEntity.BPOrganisationLegalEntity
  association [0..1] to I_BusPartAuthorizationGroup    as _AuthorizationGroup          on  $projection.AuthorizationGroup          = _AuthorizationGroup.AuthorizationGroup
                                                                                       and _AuthorizationGroup.AuthorizationObject = 'BUPA'
  association [0..1] to I_BusinessPartnerType          as _BusinessPartnerType         on  $projection.BusinessPartnerType = _BusinessPartnerType.BusinessPartnerType
  association [0..1] to I_BusinessPartnerPrintFormat   as _PrintFormat                 on  $projection.BusinessPartnerPrintFormat = _PrintFormat.BusinessPartnerPrintFormat
  association [0..1] to I_BusPartDataOriginType        as _DataOriginType              on  $projection.BusinessPartnerDataOriginType = _DataOriginType.BusinessPartnerDataOriginType
  association [0..1] to I_BusPartContactPermission     as _ContactPermission           on  $projection.ContactPermission = _ContactPermission.ContactPermission
  association [0..1] to I_BusinessPartnerFormOfAddress as _FormOfAddress               on  $projection.FormOfAddressPerson     = _FormOfAddress.FormOfAddress
                                                                                       and $projection.BusinessPartnerCategory = _FormOfAddress.BusinessPartnerCategory
  association [0..1] to I_BusinessPartnerGroupType     as _GroupType                   on  $projection.BusinessPartnerGroupType = _GroupType.BusinessPartnerGroupType
  association [0..1] to I_BusPartAcademicTitle         as _AcademicTitle2              on  $projection.AcademicTitle2 = _AcademicTitle2.AcademicTitle
  association [0..1] to I_BusPartPrefixName            as _BusPartPrefixName           on  $projection.LastNamePrefix = _BusPartPrefixName.LastNamePrefix
  association [0..1] to I_BusPartPrefixName            as _LastNameSecondPrefixName    on  $projection.LastNameSecondPrefix = _LastNameSecondPrefixName.LastNamePrefix
  association [0..1] to I_LanguageText                 as _Language                    on  $projection.Language = _Language.LanguageCode
                                                                                       and _Language.Language   = $session.system_language
  association [0..1] to I_LanguageText                 as _CorrespondenceLanguage      on  $projection.CorrespondenceLanguage = _CorrespondenceLanguage.LanguageCode
                                                                                       and _CorrespondenceLanguage.Language   = $session.system_language
  association [0..1] to I_Country                      as _NameCountry                 on  $projection.NameCountry = _NameCountry.Country
  association [0..1] to I_Country                      as _Nationality                 on  $projection.BusPartNationality = _Nationality.Country
  association [0..1] to I_Country                      as _NonResidentCompOriginCntry  on  $projection.NonResidentCompanyOriginCntry = _NonResidentCompOriginCntry.Country
  association [0..1] to I_BusPartNameFormat            as _NameFormat                  on  $projection.NameFormat  = _NameFormat.NameFormat
                                                                                       and $projection.NameCountry = _NameFormat.Country
  association [0..1] to I_BusPartSupplementName        as _BusPartSupplementName       on  $projection.BusinessPartnerSupplementName = _BusPartSupplementName.BusinessPartnerSupplementName
  association [0..1] to I_BusPartMaritalStatus         as _MaritalStatus               on  $projection.BusPartMaritalStatus = _MaritalStatus.MaritalStatus
  association [0..1] to I_BusinessPartnerOccupation    as _Occupation                  on  $projection.BusinessPartnerOccupation = _Occupation.BusinessPartnerOccupation
  association [0..1] to I_BusPartBirthDateStatus       as _BusPartBirthDateStatus      on  $projection.BusinessPartnerBirthDateStatus = _BusPartBirthDateStatus.BusinessPartnerBirthDateStatus
  association [0..1] to I_BusPartPersonFullName        as _BusPartPersonFullName       on  $projection.PersonNumber                         = _BusPartPersonFullName.PersonNumber
                                                                                       and _BusPartPersonFullName.AddressRepresentationCode = ' '
                                                                                       and _BusPartPersonFullName.ValidityStartDateTime     = '00010101'
  association [0..1] to I_BPGenderValueHelp            as _GenderCode                  on  $projection.GenderCodeName = _GenderCode.GenderCodeName
  association [0..1] to I_User                         as _CreatedByUser               on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                         as _LastChangedByUser           on  $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [0..1] to I_AcademicTitle                as _AcademicTitleValueHelp      on  $projection.AcademicTitle = _AcademicTitleValueHelp.AcademicTitle
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_MasterDataChangeProcess      as _MasterDataChangeProcess     on  $projection.MasterDataChangeProcess = _MasterDataChangeProcess.MasterDataChangeProcess
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_MDChangeProcessIsIdleTP      as _ProcessIsIdle               on  $projection.MasterDataChangeProcess = _ProcessIsIdle.MasterDataChangeProcess
  //  association [0..1] to I_MDChangeProcessTypeBPGovVH   as _ProcessTemplate             on  $projection.mdchgprocesstypeid = _ProcessTemplate.MDChgProcessTypeID


  association [0..1] to E_BP_D                         as _ExtensionActive             on  $projection.MDChgProcessSrceObject = _ExtensionActive.BusinessPartner
  association [0..1] to E_BusinessPartnerProcess       as _ExtensionProcess            on  $projection.MasterDataChangeProcess = _ExtensionProcess.MasterDataChangeProcess
                                                                                       and $projection.MDChgProcessSrceSystem  = _ExtensionProcess.MDChgProcessSrceSystem
                                                                                       and $projection.MDChgProcessSrceObject  = _ExtensionProcess.MDChgProcessSrceObject
                                                                                       and $projection.MDChgProcessStep        = _ExtensionProcess.MDChgProcessStep
  association [0..1] to I_ExtlyPrvddBPInfoRFCDestAvail as _DpiRFCDestAvailable         on _DpiRFCDestAvailable.ExtlyPrvddBPInfoRFCDestAvaily = 'X'

{
  key cast ( hextobin('00000000000000000000000000000000') as sysuuid_x ) as BusinessPartnerUUID,
  key Governance.MasterDataChangeProcess,
  key Governance.MDChgProcessSrceSystem,
  key Governance.MDChgProcessSrceObject,
      Governance.MDChgProcessStep,
      @ObjectModel.editableFieldFor: 'MasterDataChangeProcess'
      MasterDataChangeProcess                                            as MasterDataChangeProcessForEdit,
      @EndUserText.label: 'Process'
      //      cast(

      //        case MasterDataChangeProcess

      //          when '' then ''

      //          when '000000000000' then ''

      //          else MasterDataChangeProcess

      //        end as mdc_process_id

      //      )                                                                  as MDChangeProcessNumberDisplay,

      MasterDataChangeProcess                                            as MDChangeProcessNumberDisplay,
      cast( '986' as mdc_object_type_code )                              as MDChgProcessSrceObjectTypeCode,
      MDChgProcessGoal,
      @Search.defaultSearchElement: true
      BusinessPartner,
      //      @ObjectModel.text.association: '_BusinessPartnerCategory'

      BusinessPartnerCategory,
      AuthorizationGroup,
      PersonNumber,
      cast( 1000 as mdc_process_update_token )                           as ETag,
      _MasterDataChangeProcess.MDChgProcessIsStarted,
      _ProcessIsIdle.MDChgProcessIsIdle,
      //      _BusinessPartnerStandardAddr.AddressLine1Text,

      //            _BusinessPartnerStandardAddr.AddressLine1Text                                 as AddressLine1Text,

      BusinessPartnerName,
      BusinessPartnerFullName,
      CreatedByUser,
      CreationDate,
      CreationTime,
      LastChangedByUser,
      LastChangeDate,
      LastChangeTime,
      BusinessPartnerIsBlocked,
      IsBusinessPurposeCompleted,
      @Search.fuzzinessThreshold: 0.8
      OrganizationBPName1,
      @Search.fuzzinessThreshold: 0.8
      OrganizationBPName2,
      @Search.fuzzinessThreshold: 0.8
      OrganizationBPName3,
      @Search.fuzzinessThreshold: 0.8
      OrganizationBPName4,
      cast(InternationalLocationNumber1 as bu_location1str)              as InternationalLocationNumber1,
      cast(InternationalLocationNumber2 as bu_location2str)              as InternationalLocationNumber2,
      cast(InternationalLocationNumber3 as bu_location3str)              as InternationalLocationNumber3,
      @ObjectModel.foreignKey.association: '_BusinessPartnerLegalForm'
      LegalForm,
      OrganizationFoundationDate,
      OrganizationLiquidationDate,
      Industry,
      FormOfAddress                                                      as FormOfAddressPerson,
      FormOfAddress                                                      as FormOfAddressOrganization,
      FormOfAddress                                                      as FormOfAddressGroup,
      FormOfAddress,
      BusinessPartnerGrouping,
      @ObjectModel.foreignKey.association: '_BusinessPartnerType'
      BusinessPartnerType,
      @ObjectModel.foreignKey.association: '_PrintFormat'
      BusinessPartnerPrintFormat,
      @ObjectModel.foreignKey.association: '_DataOriginType'
      BusinessPartnerDataOriginType,
      @Search.fuzzinessThreshold: 0.8
      SearchTerm1,
      @Search.fuzzinessThreshold: 0.8
      SearchTerm2,
      BPLastNameSearchHelp,
      BPFirstNameSearchHelp,
      IndependentAddressID,
      IsMarkedForArchiving,
      @ObjectModel.foreignKey.association: '_ContactPermission'
      ContactPermission,
      LegalEntityOfOrganization,
      BusinessPartnerIsNotReleased,
      IsNotContractuallyCapable,
      ActiveAuthorizationGroup,
      CorrespondenceLanguage,

      /* Category dependent common data */
      cast(
        case
          when BusinessPartnerCategory = '1' then 'X'
        else ''
      end as boole_d preserving type)                                    as BPPersonDataIsDisplayed,
      cast(
        case
          when BusinessPartnerCategory = '1' then ''
        else 'X'
      end as boole_d preserving type)                                    as BusPartPersonDataIsHidden,
      cast(
        case
          when BusinessPartnerCategory = '2' then ''
        else 'X'
      end as boole_d preserving type)                                    as BusPartOrgDataIsHidden,
      cast(
        case
          when BusinessPartnerCategory = '3' then ''
        else 'X'
      end as boole_d preserving type)                                    as BusPartGroupDataIsHidden,
      cast(
        case
          when BusinessPartnerCategory = '1' then 'X'
        else ''
      end as boole_d preserving type)                                    as BusPartAddrLanguageIsHidden,

      /* Person Data */
      IsFemale,
      IsMale,
      IsSexUnknown,
      GenderCodeName,
      @Search.fuzzinessThreshold: 0.8
      FirstName,
      @Search.fuzzinessThreshold: 0.8
      LastName,
      case when BusinessPartnerCategory = '1'
           then FirstName
           else OrganizationBPName2
           end                                                           as AdditionalName,
      AdditionalLastName,
      @Search.fuzzinessThreshold: 0.8
      BusinessPartnerBirthName,
      @Search.fuzzinessThreshold: 0.8
      MiddleName,
      AcademicTitle,
      AcademicTitle2,
      BusinessPartnerSupplementName,
      @ObjectModel.foreignKey.association: '_BusPartPrefixName'
      LastNamePrefix,
      LastNameSecondPrefix,
      PersonFullName,
      BusinessPartnerNicknameLabel, //Known as ?

      Initials,
      NameFormat,
      NameCountry,
      Language,
      IsNaturalPerson,
      BirthDate,
      BusinessPartnerBirthplaceName,
      BusinessPartnerDeathDate,
      BusinessPartnerBirthDateStatus,
      NaturalPersonEmployerName,
      BusinessPartnerOccupation,
      BusPartMaritalStatus,
      BusPartNationality,
      BusinessPartnerIDByExtSystem,
      NonResidentCompanyOriginCntry,
      /* Group Data */
      @Search.fuzzinessThreshold: 0.8
      GroupBusinessPartnerName1,
      @Search.fuzzinessThreshold: 0.8
      GroupBusinessPartnerName2,
      BusinessPartnerGroupType,
      cast( '' as boole_d preserving type )                              as MDChgBPRelshpHasChanged,
      
      DataControllerSet,
      DataController1,
      DataController2,
      DataController3,
      DataController4,
      DataController5,
      DataController6,
      DataController7,
      DataController8,
      DataController9,
      DataController10,
      BPDataControllerIsNotRequired,

      /* Extensbility Identifier */
      Origin,

      /* Compositions */
      _Process,
      _BusinessPartnerRole,
      _BusinessPartnerAddress,
      //      _BusinessPartnerStdAddr,

      _BusinessPartnerIdentification,
      _BusinessPartnerTaxNumber,
      _BusinessPartnerIndustry,
      _BusinessPartnerBank,
      _BusinessPartnerDataController,

      /* Associations */
      _BusinessPartnerStandardAddr,
      _BusinessPartnerGrouping,
      _BusinessPartnerCategory,
      _BusinessPartnerLegalForm,
      _BusinessPartnerLegalEntity,
      _AuthorizationGroup,
      _BusinessPartnerType,
      _PrintFormat,
      _DataOriginType,
      _ContactPermission,
      _FormOfAddress,
      _GroupType,
      _AcademicTitle2,
      _BusPartPrefixName,
      _LastNameSecondPrefixName,
      _Language,
      _CorrespondenceLanguage,
      _BusPartSupplementName,
      _NameCountry,
      _Nationality,
      _NonResidentCompOriginCntry,
      _NameFormat,
      _MaritalStatus,
      _Occupation,
      _BusPartBirthDateStatus,
      _BusPartPersonFullName,
      _GenderCode,
      _CreatedByUser,
      _LastChangedByUser,
      _AcademicTitleValueHelp,
      _MasterDataChangeProcess,
      _BusinessPartnerAddressUsage,
      _BusinessPartnerAddressDsp,
      _DpiRFCDestAvailable
}
where
       MasterDataIsCurrent                = 'X'
  and(
       MDChgProcessGoal                   = 'G'
    or MDChgProcessGoal                   = 'U'
    or MDChgProcessGoal                   = 'C'
    or MDChgProcessGoal                   = 'F'
    or MDChgProcessGoal                   = 'P'
    or MDChgProcessGoal                   = 'Y'
    or MDChgProcessGoal                   = 'S'
  )
  and  _RoleAllowList.MasterDataChangeProcess is null // no entry from _RoleAllowList should be available