A_SalesOrderSimulation_2

@VDM: {
  lifecycle.contract.type: #PUBLIC_REMOTE_API,
  usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE],
  viewType: #CONSUMPTION
}

@AccessControl: {
    authorizationCheck: #MANDATORY,
    personalData.blocking: #('TRANSACTIONAL_DATA')
}

@EndUserText.label: 'Sales Order Header Simulation'

@Metadata.ignorePropagatedAnnotations: true

@OData: {
  entityType.name: 'SalesOrder_Type'
}

@ObjectModel: {
   representativeKey: 'SalesOrder',
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   },
   query.implementedBy: 'ABAP:CL_SD_SO_SIMLN_RAP_V4_QRY'
}

@AbapCatalog.extensibility: {
  extensible: true,
  dataSources: ['_Extension'],  
  elementSuffix: 'SDH',
  quota: {
    maximumFields: 204, 
    maximumBytes: 100000
  }  
}  


define root view entity A_SalesOrderSimulation_2
    as select from I_SalesOrder as SalesOrder
    composition [0..*] of A_SalesOrderItemSimulation_2          as _Item
    composition [0..*] of A_SalesOrderPartnerSimln_2            as _Partner
    composition [0..*] of A_SlsOrdPricingElementSimln_2           as _PricingElement
    
    association [0..1] to I_SlsOrganizationDistrChnl            as _SlsOrganizationDistrChnl on  $projection.SalesOrganization   = _SlsOrganizationDistrChnl.SalesOrganization
                                                                                  and $projection.DistributionChannel = _SlsOrganizationDistrChnl.DistributionChannel
    association [1]    to E_SalesDocumentBasic                  as _Extension             on  $projection.SalesOrder = _Extension.SalesDocument 
    
{
    
    key SalesOrder.SalesOrder,
    
    @ObjectModel.sapObjectNodeTypeReference: 'SalesOrderType'
    cast(SalesOrder.SalesOrderType as auart_spr preserving type ) as SalesOrderType,
    
    SalesOrder.SalesOrderProcessingType,
    
    SalesOrder.SoldToParty,
    
    SalesOrder.SalesOrganization,

    SalesOrder.DistributionChannel,
    
    _SlsOrganizationDistrChnl.ReferenceDistributionChannel,
    
    SalesOrder.OrganizationDivision,
    
    SalesOrder.SalesOffice,
    SalesOrder.SalesGroup,
    SalesOrder.SalesDistrict,
    
    SalesOrder.CreatedByUser,
    SalesOrder.CreationDate,
    SalesOrder.CreationTime,
    
    case tstmp_is_valid(cast(SalesOrder.LastChangeDateTime as abap.dec(15,0)))
       when 0 then cast( dats_tims_to_tstmp( SalesOrder.CreationDate, SalesOrder.CreationTime, 'UTC', $session.client, 'NULL' ) as last_changed_date_time )
        else cast( SalesOrder.LastChangeDateTime as last_changed_date_time )
    end                                                                                              as LastChangeDateTime,
    
    SalesOrder.PurchaseOrderByCustomer,
  
    SalesOrder.PurchaseOrderByShipToParty,
    @ObjectModel.sapObjectNodeTypeReference: 'PurchaseOrderTypeByCustomer'
    SalesOrder.CustomerPurchaseOrderType,
    SalesOrder.CustomerPurchaseOrderDate,
    SalesOrder.CorrespncExternalReference,
    SalesOrder.CorrespncExtRefByShipToParty,
    SalesOrder.BusinessSolutionOrder,
    
    SalesOrder.ReferenceSDDocument,
    @Consumption.hidden: true
    @Semantics.nullValueIndicatorFor: 'ReferenceSDDocument'
    cast( '' as rap_null_value_indicator ) as ReferenceSDDocumentIsNull,
    
    SalesOrder.ReferenceSDDocumentCategory,
    @Consumption.hidden: true
    @Semantics.nullValueIndicatorFor: 'ReferenceSDDocumentCategory'
    cast( '' as rap_null_value_indicator ) as ReferenceSDDocumentCatIsNull,
    
    @ObjectModel.sapObjectNodeTypeReference: 'SalesDocumentReason'
    SalesOrder.SDDocumentReason,
    
    SalesOrder.SalesOrderDate,
    SalesOrder.RequestedDeliveryDate,
    SalesOrder.PricingDate,
    SalesOrder.ServicesRenderedDate,
    SalesOrder.BillingDocumentDate,
    
    @Semantics.amount.currencyCode: 'TransactionCurrency'
    SalesOrder.TotalNetAmount,
    @ObjectModel.sapObjectNodeTypeReference: 'Currency'
    //@Semantics.currencyCode: true

    SalesOrder.TransactionCurrency,
        
    @ObjectModel.sapObjectNodeTypeReference: 'DeliveryDateTypeRule'
    SalesOrder.DeliveryDateTypeRule,
    SalesOrder.ShippingCondition,
    SalesOrder.CompleteDeliveryIsDefined,
    SalesOrder.SlsDocIsRlvtForProofOfDeliv,
    SalesOrder.ShippingType,
    SalesOrder.ReceivingPoint,
    
    @ObjectModel.sapObjectNodeTypeReference: 'IncotermsClassification'
    SalesOrder.IncotermsClassification,
    @ObjectModel.sapObjectNodeTypeReference: 'IncotermsVersion'
    SalesOrder.IncotermsVersion,
    SalesOrder.IncotermsLocation1,
    SalesOrder.IncotermsLocation2,
    
    SalesOrder.SDPricingProcedure,
    @ObjectModel.sapObjectNodeTypeReference: 'CustomerPriceGroup'
    SalesOrder.CustomerPriceGroup,
    SalesOrder.PriceListType,
    SalesOrder.FixedValueDate,
    SalesOrder.TaxDepartureCountry,
    SalesOrder.VATRegistrationCountry,
    SalesOrder.IsEUTriangularDeal,
    SalesOrder.CustomerPaymentTerms,
    @ObjectModel.sapObjectNodeTypeReference: 'PaymentMethod'
    SalesOrder.PaymentMethod,
    SalesOrder.BillingCompanyCode,
    SalesOrder.ControllingArea,
    
    @ObjectModel.sapObjectNodeTypeReference: 'CustomerAccountAssignmentGroup'
    SalesOrder.CustomerAccountAssignmentGroup,
    SalesOrder.AssignmentReference,
    SalesOrder.AccountingDocExternalReference,
    SalesOrder.CustomerCreditAccount,
    
    @ObjectModel.sapObjectNodeTypeReference: 'BillingBlockReason'
    SalesOrder.HeaderBillingBlockReason,
    SalesOrder.DeliveryBlockReason,
    @ObjectModel.sapObjectNodeTypeReference: 'SalesOrderApprovalReason'
    SalesOrder.SalesOrderApprovalReason,
    
    SalesOrder.SlsContrAutoAssgmtIDForSlsOrd,
    @Consumption.hidden: true
    @Semantics.nullValueIndicatorFor: 'SlsContrAutoAssgmtIDForSlsOrd'
    cast( '' as rap_null_value_indicator ) as SlsContrAutoAssgmtIDIsNull,   
    
    @ObjectModel.sapObjectNodeTypeReference: 'CustomerGroup'
    SalesOrder.CustomerGroup,
    @ObjectModel.sapObjectNodeTypeReference: 'AdditionalCustomerGroup1'
    SalesOrder.AdditionalCustomerGroup1,
    @ObjectModel.sapObjectNodeTypeReference: 'AdditionalCustomerGroup2'
    SalesOrder.AdditionalCustomerGroup2,
    @ObjectModel.sapObjectNodeTypeReference: 'AdditionalCustomerGroup3'
    SalesOrder.AdditionalCustomerGroup3,
    @ObjectModel.sapObjectNodeTypeReference: 'AdditionalCustomerGroup4'
    SalesOrder.AdditionalCustomerGroup4,
    @ObjectModel.sapObjectNodeTypeReference: 'AdditionalCustomerGroup5'
    SalesOrder.AdditionalCustomerGroup5,           
        
    cast( '' as vdm_sdoc_crdt_chk_is_tb_dsbld ) as CreditCheckIsToBeDisabled,    
        
    @ObjectModel.sapObjectNodeTypeReference: 'OverallSDProcessStatus'
    SalesOrder.OverallSDProcessStatus,
    @ObjectModel.sapObjectNodeTypeReference: 'SlsDocOvrlPurchaseConfStatus'
    SalesOrder.OverallPurchaseConfStatus,
    @ObjectModel.sapObjectNodeTypeReference: 'SlsDocOvrlDeliveryBlockStatus'
    SalesOrder.OverallDeliveryBlockStatus,
    SalesOrder.OverallBillingBlockStatus,
    @ObjectModel.sapObjectNodeTypeReference: 'SalesDocOverallDeliveryStatus'
    SalesOrder.OverallDeliveryStatus,
    @ObjectModel.sapObjectNodeTypeReference: 'TotalCreditCheckStatus'
    SalesOrder.TotalCreditCheckStatus,
    @ObjectModel.sapObjectNodeTypeReference: 'OverallSDDocumentRejectionSts'
    SalesOrder.OverallSDDocumentRejectionSts,
    SalesOrder.TotalBlockStatus,
    @ObjectModel.sapObjectNodeTypeReference: 'SlsDocGenIncompletionStatus'
    SalesOrder.HdrGeneralIncompletionStatus,
    @ObjectModel.sapObjectNodeTypeReference: 'SlsDocOvrlItmGenIncompltnSts'
    SalesOrder.OvrlItmGeneralIncompletionSts,
    @ObjectModel.sapObjectNodeTypeReference: 'OverallSDDocReferenceStatus'
    SalesOrder.OverallSDDocReferenceStatus,
    @ObjectModel.sapObjectNodeTypeReference: 'SalesDocApprovalStatus'
    SalesOrder.SalesDocApprovalStatus,
    SalesOrder.OverallChmlCmplncStatus,
    SalesOrder.OverallDangerousGoodsStatus,
    SalesOrder.OverallSafetyDataSheetStatus,
    SalesOrder.OverallTrdCmplncEmbargoSts,
    SalesOrder.OvrlTrdCmplncSnctndListChkSts,
    SalesOrder.OvrlTrdCmplncLegalCtrlChkSts,
    SalesOrder.SalesOrderDownPaymentStatus,
    @ObjectModel.sapObjectNodeTypeReference: 'OverallOrdReltdBillgStatus'
    SalesOrder.OverallOrdReltdBillgStatus,
    
    //Compositions

    @ObjectModel.filter.enabled: false
    _Item,
    @ObjectModel.filter.enabled: false
    _Partner,
    @ObjectModel.filter.enabled: false
    _PricingElement
}