A_SalesOrderItemSimulation_2

@VDM: {
  lifecycle.contract.type: #PUBLIC_REMOTE_API,
  usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE],
  viewType: #CONSUMPTION
}

@AccessControl: {
    authorizationCheck: #MANDATORY,
    personalData.blocking: #('TRANSACTIONAL_DATA')
}

@EndUserText.label: 'Sales Order Item Simulation'

@Metadata.ignorePropagatedAnnotations: true

@OData: {
  entityType.name: 'SalesOrderItem_Type'
}

@ObjectModel: {
   semanticKey: ['SalesOrder','SalesOrderItem'],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   },
   query.implementedBy: 'ABAP:CL_SD_SO_SIMLN_RAP_V4_QRY'
}

@AbapCatalog.extensibility: {
  extensible: true,
  dataSources: ['_Extension'],
  elementSuffix: 'SDI',
  quota: {
    maximumFields: 204, //This is calculated with formula - 2* <Customer Percentage from SCFD_REGISTRY> * <max number of fields in SCFD_REGISTRY>

    maximumBytes: 100000  //Set to maximum allowed bytes

  }
}

define view entity A_SalesOrderItemSimulation_2
  as select from I_SalesOrderItem as SalesOrderItem
  composition [0..*] of A_SalesOrderItemPartnerSimln_2 as _ItemPartner
  composition [0..*] of A_SlsOrdItmPrcgElmntSimln_2    as _ItemPricingElement
  composition [0..*] of A_SlsOrdScheduleLineSimln_2    as _ScheduleLine

  association [0..1] to A_VarCnfContextSimulation      as _VariantConfiguration on  $projection.VarConfigurationBusObjectType = _VariantConfiguration.VarConfigurationBusObjectType
                                                                                and $projection.VarConfigurationBusObjectKey  = _VariantConfiguration.VarConfigurationBusObjectKey
  association [0..1] to I_SlsDocItemEnhancedFields     as _ItemEnhancedFields   on  $projection.SalesOrder     = _ItemEnhancedFields.SalesDocument
                                                                                and $projection.SalesOrderItem = _ItemEnhancedFields.SalesDocumentItem

  association        to parent A_SalesOrderSimulation_2       as _SalesOrder    on  $projection.SalesOrder = _SalesOrder.SalesOrder
  //Extension Association

  association [1]    to E_SalesDocumentItemBasic          as _Extension         on  $projection.SalesOrder     = _Extension.SalesDocument
                                                                                and $projection.SalesOrderItem = _Extension.SalesDocumentItem
{
  key SalesOrderItem.SalesOrder,
  key SalesOrderItem.SalesOrderItem,

      SalesOrderItem.HigherLevelItem,

      @Consumption.hidden: true
      @Semantics.nullValueIndicatorFor: 'HigherLevelItem'
      cast( '' as rap_null_value_indicator )                                                   as HigherLevelItem_H,

      SalesOrderItem.SalesOrderItemCategory,

      @Semantics.text: true
      SalesOrderItem.SalesOrderItemText,

      SalesOrderItem.Product,
      SalesOrderItem.OriginallyRequestedMaterial,

      @ObjectModel.sapObjectNodeTypeReference: 'ProductGroup'
      SalesOrderItem.ProductGroup,
      SalesOrderItem.MaterialByCustomer,
      SalesOrderItem.InternationalArticleNumber,

      SalesOrderItem.PurchaseOrderByCustomer,
      SalesOrderItem.UnderlyingPurchaseOrderItem,
      SalesOrderItem.CorrespncExternalReference,
      SalesOrderItem.PurchaseOrderByShipToParty,
      SalesOrderItem.UndrlgPurOrdItmByShipToParty,
      SalesOrderItem.CorrespncExtRefByShipToParty,

      @Semantics.quantity.unitOfMeasure: 'OrderQuantitySAPUnit'
      @Semantics.quantity.unitOfMeasureSapCode: 'OrderQuantitySAPUnit'
      @Semantics.quantity.unitOfMeasureIsoCode: 'OrderQuantityISOUnit'
      SalesOrderItem.ConfdDelivQtyInOrderQtyUnit,
      SalesOrderItem.OrderQuantityUnit                                                         as OrderQuantitySAPUnit,
      cast(_OrderQuantityUnit.UnitOfMeasureISOCode as sd_ord_qty_isounit preserving type)      as OrderQuantityISOUnit,



      @Semantics.quantity.unitOfMeasure: 'RequestedQuantitySAPUnit'
      @Semantics.quantity.unitOfMeasureSapCode: 'RequestedQuantitySAPUnit'
      @Semantics.quantity.unitOfMeasureIsoCode: 'RequestedQuantityISOUnit'
      @Semantics.valueRange.minimum: '0'
      SalesOrderItem.RequestedQuantity,

      // @Semantics.unitOfMeasure: true

      SalesOrderItem.RequestedQuantityUnit                                                     as RequestedQuantitySAPUnit,
      cast(_RequestedQuantityUnit.UnitOfMeasureISOCode as sd_reqd_qty_isounit preserving type) as RequestedQuantityISOUnit,

      //Reference

      SalesOrderItem.ReferenceSDDocument,
      @Consumption.hidden: true
      @Semantics.nullValueIndicatorFor: 'ReferenceSDDocument'
      cast( '' as rap_null_value_indicator )                                                   as ReferenceSDDocumentIsNull,

      SalesOrderItem.ReferenceSDDocumentItem,
      @Consumption.hidden: true
      @Semantics.nullValueIndicatorFor: 'ReferenceSDDocumentItem'
      cast( '' as rap_null_value_indicator )                                                   as ReferenceSDDocumentItemIsNull,

      SalesOrderItem.ReferenceSDDocumentCategory,
      @Consumption.hidden: true
      @Semantics.nullValueIndicatorFor: 'ReferenceSDDocumentCategory'
      cast( '' as rap_null_value_indicator )                                                   as ReferenceSDDocumentCatIsNull,

      @Semantics.quantity.unitOfMeasure: 'ItemWeightSAPUnit'
      @Semantics.quantity.unitOfMeasureSapCode: 'ItemWeightSAPUnit'
      @Semantics.quantity.unitOfMeasureIsoCode: 'ItemWeightISOUnit'
      SalesOrderItem.ItemGrossWeight,
      @Semantics.quantity.unitOfMeasure: 'ItemWeightSAPUnit'
      @Semantics.quantity.unitOfMeasureSapCode: 'ItemWeightSAPUnit'
      @Semantics.quantity.unitOfMeasureIsoCode: 'ItemWeightISOUnit'
      SalesOrderItem.ItemNetWeight,
      SalesOrderItem.ItemWeightUnit                                                            as ItemWeightSAPUnit,
      cast(_ItemWeightUnit.UnitOfMeasureISOCode as sd_itm_wgt_isounit preserving type)         as ItemWeightISOUnit,

      @Semantics.quantity.unitOfMeasure: 'ItemVolumeSAPUnit'
      @Semantics.quantity.unitOfMeasureSapCode: 'ItemVolumeSAPUnit'
      @Semantics.quantity.unitOfMeasureIsoCode: 'ItemVolumeISOUnit'
      SalesOrderItem.ItemVolume,
      SalesOrderItem.ItemVolumeUnit                                                            as ItemVolumeSAPUnit,
      cast(_ItemVolumeUnit.UnitOfMeasureISOCode as sd_itm_vol_isounit preserving type)         as ItemVolumeISOUnit,

      _ItemEnhancedFields._RequestedDeliveryDate.RequestedDeliveryDate,
      _ItemEnhancedFields._ConfirmedDeliveryDate.ConfirmedDeliveryDate,
      SalesOrderItem.PricingDate,
      SalesOrderItem.ServicesRenderedDate,
      SalesOrderItem.BillingDocumentDate,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      SalesOrderItem.NetAmount,
      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      SalesOrderItem.TransactionCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      SalesOrderItem.TaxAmount,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      SalesOrderItem.Subtotal1Amount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      SalesOrderItem.Subtotal2Amount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      SalesOrderItem.Subtotal3Amount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      SalesOrderItem.Subtotal4Amount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      SalesOrderItem.Subtotal5Amount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      SalesOrderItem.Subtotal6Amount,

      @ObjectModel.sapObjectNodeTypeReference: 'CustomerGroup'
      SalesOrderItem.CustomerGroup,

      SalesOrderItem.Batch,
      SalesOrderItem.Plant,
      @ObjectModel.sapObjectNodeTypeReference: 'StorageLocation'
      SalesOrderItem.StorageLocation,
      @ObjectModel.sapObjectNodeTypeReference: 'ShippingPoint'
      SalesOrderItem.ShippingPoint,
      SalesOrderItem.ShippingType,
      SalesOrderItem.Route,
      SalesOrderItem.DeliveryPriority,
      SalesOrderItem.PartialDeliveryIsAllowed,
      SalesOrderItem.MaxNmbrOfPartialDelivery,
      @ObjectModel.sapObjectNodeTypeReference: 'DeliveryDateTypeRule'
      SalesOrderItem.DeliveryDateTypeRule,
      SalesOrderItem.ReceivingPoint,
      SalesOrderItem.DeliveryGroup,

      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsClassification'
      SalesOrderItem.IncotermsClassification,
      SalesOrderItem.IncotermsLocation1,
      SalesOrderItem.IncotermsLocation2,
      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsVersion'
      SalesOrderItem.IncotermsVersion,
      SalesOrderItem.CustomerPaymentTerms,
      SalesOrderItem.FixedValueDate,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerPriceGroup'
      SalesOrderItem.CustomerPriceGroup,
      @ObjectModel.sapObjectNodeTypeReference: 'MaterialPricingGroup'
      cast (MaterialPricingGroup as productpricinggroup preserving type )                      as MaterialPricingGroup,

      SalesOrderItem.BusinessArea,
      SalesOrderItem.ProfitCenter,
      @ObjectModel.sapObjectNodeTypeReference: 'MaterialAccountAssignmentGroup'
      SalesOrderItem.MatlAccountAssignmentGroup,

      SalesOrderItem._WBSElementBasicData_2.WBSElementExternalID                               as WBSElementExternalID,

      @ObjectModel.sapObjectNodeTypeReference: 'BillingBlockReason'
      SalesOrderItem.ItemBillingBlockReason,
      @ObjectModel.sapObjectNodeTypeReference: 'SalesDocumentRjcnReason'
      SalesOrderItem.SalesDocumentRjcnReason,

      SalesOrderItem.ProductConfiguration,
      //@Consumption.hidden: true

      //SalesOrderItem.VarConfigurationBusObjectKey,

      //@Consumption.hidden: true

      //SalesOrderItem.VarConfigurationBusObjectType,


      SalesOrderItem.SlsContrAutoAssgmtIDForSlsOrd,
      @Consumption.hidden: true
      @Semantics.nullValueIndicatorFor: 'SlsContrAutoAssgmtIDForSlsOrd'
      cast( '' as rap_null_value_indicator )                                                   as SlsContrAutoAssgmtIDIsNull,

      @ObjectModel.sapObjectNodeTypeReference: 'SDProcessStatus'
      SalesOrderItem.SDProcessStatus,
      @ObjectModel.sapObjectNodeTypeReference: 'SalesDocPurchaseConfStatus'
      SalesOrderItem.PurchaseConfirmationStatus,
      @ObjectModel.sapObjectNodeTypeReference: 'SalesDocRejectionStatus'
      SalesOrderItem.SDDocumentRejectionStatus,
      @ObjectModel.sapObjectNodeTypeReference: 'SalesDocDeliveryStatus'
      SalesOrderItem.DeliveryStatus,
      @ObjectModel.sapObjectNodeTypeReference: 'SalesDocItemBillingBlockStatus'
      SalesOrderItem.BillingBlockStatus,
      @ObjectModel.sapObjectNodeTypeReference: 'SlsDocItemGenIncompltnStatus'
      SalesOrderItem.ItemGeneralIncompletionStatus,
      @ObjectModel.sapObjectNodeTypeReference: 'SalesDocDeliveryBlockStatus'
      SalesOrderItem.DeliveryBlockStatus,
      SalesOrderItem.SlsOrderItemDownPaymentStatus,
      @ObjectModel.sapObjectNodeTypeReference: 'OrderRelatedBillingStatus'
      SalesOrderItem.OrderRelatedBillingStatus,
      SalesOrderItem.ChmlCmplncStatus,
      SalesOrderItem.DangerousGoodsStatus,
      SalesOrderItem.SafetyDataSheetStatus,
      SalesOrderItem.TrdCmplncEmbargoSts,
      SalesOrderItem.TrdCmplncSnctndListChkSts,
      SalesOrderItem.OvrlTrdCmplncLegalCtrlChkSts,


      //Parent

      @ObjectModel.filter.enabled: false
      @ObjectModel.sort.enabled: false
      _SalesOrder,

      //Compositions

      @ObjectModel.filter.enabled: false
      _ItemPartner,
      @ObjectModel.filter.enabled: false
      _ItemPricingElement,
      @ObjectModel.filter.enabled: false
      _ScheduleLine,
      @ObjectModel.filter.enabled: false
      _VariantConfiguration,

      @Consumption.hidden: true
      case when SalesOrderItem.ProductConfiguration is not initial
        then cast(concat(SalesOrderItem.SalesOrder, SalesOrderItem.SalesOrderItem) as ibobjkey)
        else null
      end                                                                                      as VarConfigurationBusObjectKey,

      @Consumption.hidden: true
      case when SalesOrderItem.ProductConfiguration is not initial
        then cast('SalesOrderItem' as sbo_node_type)
        else null
      end                                                                                      as VarConfigurationBusObjectType,

      //used for ETAG

      @Consumption.hidden: true
      _SalesOrder.LastChangeDateTime,

      // For Access control

      @Consumption.hidden: true
      _SalesOrder.SalesOrderType,
      @Consumption.hidden: true
      _SalesOrder.OrganizationDivision,
      @Consumption.hidden: true
      _SalesOrder.SalesOrganization,
      @Consumption.hidden: true
      _SalesOrder.DistributionChannel
}