A_SlsOrdPricingElementSimln_2

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@EndUserText.label: 'Header Pricing Element Simulation'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: {
  semanticKey: ['SalesOrder','PricingProcedureStep','PricingProcedureCounter'],
  usageType: {
    dataClass:      #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory:   #XL
  },
  query.implementedBy: 'ABAP:CL_SD_SO_SIMLN_RAP_V4_QRY'
}

@OData: {
  entityType.name: 'SalesOrderPricingElement_Type'
}

@VDM: {
  lifecycle.contract.type: #PUBLIC_REMOTE_API,
  usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE],
  viewType: #CONSUMPTION
}
define view entity A_SlsOrdPricingElementSimln_2
  as select from I_SalesOrderPricingElement as SalesOrderPricingElement
  association to parent A_SalesOrderSimulation_2 as _SalesOrder on $projection.SalesOrder = _SalesOrder.SalesOrder

{

  key SalesOrderPricingElement.SalesOrder,

  key SalesOrderPricingElement.PricingProcedureStep,

  key SalesOrderPricingElement.PricingProcedureCounter,

      @ObjectModel.sapObjectNodeTypeReference: 'SalesPricingConditionType'
      SalesOrderPricingElement.ConditionType,

      cast(SalesOrderPricingElement._PricingConditionType._Text_2[1: Language=$session.system_language].ConditionTypeName as priceelementdescription) as PriceElementDescription,

      @ObjectModel.sapObjectNodeTypeReference: 'PriceConditionCalculationType'
      SalesOrderPricingElement.ConditionCalculationType,

      @Semantics.amount.currencyCode: 'ConditionCurrency'
      @OData.v2.amount.noDecimalShift: true
      SalesOrderPricingElement.ConditionRateAmount,
      @Semantics.nullValueIndicatorFor: 'ConditionRateAmount'
      @Semantics.booleanIndicator: true
      cast(
        case
          when ConditionRateRatioUnit = ''
           then ''
          else 'X'
        end as boole_d )                                                                               as ConditionRateValueIsRatio,

      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      SalesOrderPricingElement.ConditionCurrency,

      @Semantics.quantity.unitOfMeasure: 'ConditionQuantitySAPUnit'
      @Semantics.quantity.unitOfMeasureSapCode: 'ConditionQuantitySAPUnit'
      @Semantics.quantity.unitOfMeasureIsoCode: 'ConditionQuantityISOUnit'
      SalesOrderPricingElement.ConditionQuantity,
      @Semantics.nullValueIndicatorFor: 'ConditionQuantity'
      @Semantics.booleanIndicator: true
      cast(
        case
          when ConditionQuantity is initial
           then 'X'
          else ''
        end as boole_d )                                                                               as ConditionQuantityIsNull,

      @Semantics.quantity.unitOfMeasure: 'ConditionQuantitySAPUnit'
      @Semantics.quantity.unitOfMeasureSapCode: 'ConditionQuantitySAPUnit'
      @Semantics.quantity.unitOfMeasureIsoCode: 'ConditionQuantityISOUnit'
      SalesOrderPricingElement.ConditionBaseQuantity,
      @Semantics.nullValueIndicatorFor: 'ConditionBaseQuantity'
      @Semantics.booleanIndicator: true
      cast(
        case
          when ConditionCalculationType = 'A'
            or ConditionCalculationType = 'B'
            or ConditionCalculationType = 'H'
            or ConditionCalculationType = 'I'
            or ConditionCalculationType = 'J'
            or ConditionCalculationType = 'K'
            or ConditionCalculationType = 'W'
           then 'X'
          else ''
        end as boole_d )                                                                               as ConditionBaseValueIsAmount,

      SalesOrderPricingElement.ConditionQuantityUnit                                                   as ConditionQuantitySAPUnit,
      cast(_ConditionQuantityUnit.UnitOfMeasureISOCode as sd_cndn_qty_isounit preserving type)         as ConditionQuantityISOUnit,

      @Semantics.quantity.unitOfMeasure: 'ConditionRateRatioSAPUnit'
      @Semantics.quantity.unitOfMeasureSapCode: 'ConditionRateRatioSAPUnit'
      @Semantics.quantity.unitOfMeasureIsoCode: 'ConditionRateRatioISOUnit'
      SalesOrderPricingElement.ConditionRateRatio,
      @Semantics.nullValueIndicatorFor: 'ConditionRateRatio'
      @Semantics.booleanIndicator: true
      cast(
        case
          when ConditionRateRatioUnit = ''
           then 'X'
          else ''
        end as boole_d )                                                                               as ConditionRateValueIsAmount,

      SalesOrderPricingElement.ConditionRateRatioUnit                                                  as ConditionRateRatioSAPUnit,
      cast(_ConditionRateRatioUnit.UnitOfMeasureISOCode as sd_cndn_rate_ratio_isounit preserving type) as ConditionRateRatioISOUnit,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      SalesOrderPricingElement.ConditionAmount,
      @Semantics.nullValueIndicatorFor: 'ConditionAmount'
      @Semantics.booleanIndicator: true
      cast(
        case
          when ConditionAmount is initial
           then 'X'
          else ''
        end as boole_d )                                                                               as ConditionAmountIsNull,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      @OData.v2.amount.noDecimalShift: true
      SalesOrderPricingElement.ConditionBaseAmount,
      @Semantics.nullValueIndicatorFor: 'ConditionBaseAmount'
      @Semantics.booleanIndicator: true
      cast(
        case
          when ConditionCalculationType = 'A'
            or ConditionCalculationType = 'B'
            or ConditionCalculationType = 'H'
            or ConditionCalculationType = 'I'
            or ConditionCalculationType = 'J'
            or ConditionCalculationType = 'K'
            or ConditionCalculationType = 'W'
           then ''
          else 'X'
        end as boole_d )                                                                               as ConditionBaseValueIsQuantity,

      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      SalesOrderPricingElement.TransactionCurrency,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      SalesOrderPricingElement.CndnRoundingOffDiffAmount,
      @Semantics.nullValueIndicatorFor: 'CndnRoundingOffDiffAmount'
      cast( '' as rap_null_value_indicator )                                                           as CndnRndngOffDiffAmountIsNull,

      @ObjectModel.sapObjectNodeTypeReference: 'PriceConditionInactiveReason'
      SalesOrderPricingElement.ConditionInactiveReason,
      @Consumption.hidden: true
      @Semantics.nullValueIndicatorFor: 'ConditionInactiveReason'
      cast( '' as rap_null_value_indicator )                                                           as ConditionInactiveReasonIsNull,

      @ObjectModel.sapObjectNodeTypeReference: 'PriceConditionClass'
      SalesOrderPricingElement.ConditionClass,
      @Semantics.nullValueIndicatorFor: 'ConditionClass'
      cast( '' as rap_null_value_indicator )                                                           as ConditionClassIsNull,

      @ObjectModel.sapObjectNodeTypeReference: 'PriceConditionControl'
      SalesOrderPricingElement.ConditionControl,
      @Semantics.nullValueIndicatorFor: 'ConditionControl'
      cast( '' as rap_null_value_indicator )                                                           as ConditionControlIsNull,

      @ObjectModel.sapObjectNodeTypeReference: 'PriceConditionOrigin'
      SalesOrderPricingElement.ConditionOrigin,
      @Semantics.nullValueIndicatorFor: 'ConditionOrigin'
      cast( '' as rap_null_value_indicator )                                                           as ConditionOriginIsNull,

      SalesOrderPricingElement.ConditionIsForStatistics,
      @Semantics.nullValueIndicatorFor: 'ConditionIsForStatistics'
      cast( '' as rap_null_value_indicator )                                                           as ConditionIsForStatisticsIsNull,

      SalesOrderPricingElement.ConditionIsManuallyChanged,
      @Semantics.nullValueIndicatorFor: 'ConditionIsManuallyChanged'
      cast( '' as rap_null_value_indicator )                                                           as ConditionIsManuallyChgdIsNull,

      @ObjectModel.sapObjectNodeTypeReference: 'SalesTaxCode'
      SalesOrderPricingElement.TaxCode,
      @Semantics.nullValueIndicatorFor: 'TaxCode'
      cast( '' as rap_null_value_indicator )                                                           as TaxCodeIsNull,

      @ObjectModel.sapObjectNodeTypeReference: 'PricingVariantCondition'
      SalesOrderPricingElement.VariantCondition,
      @Semantics.nullValueIndicatorFor: 'VariantCondition'
      cast( '' as rap_null_value_indicator )                                                           as VariantConditionIsNull,
      
      SalesOrderPricingElement.IsGroupCondition_2                                                      as IsGroupCondition,
      @Semantics.nullValueIndicatorFor: 'IsGroupCondition'
      cast( '' as rap_null_value_indicator )                                                           as IsGroupConditionIsNull,

      // For Access control

      @Consumption.hidden: true
      _SalesOrder.SalesOrderType,
      @Consumption.hidden: true
      _SalesOrder.OrganizationDivision,
      @Consumption.hidden: true
      _SalesOrder.SalesOrganization,
      @Consumption.hidden: true
      _SalesOrder.DistributionChannel,

      //Associations

      @ObjectModel.filter.enabled: false
      @ObjectModel.sort.enabled: false
      _SalesOrder

}