A_SalesOrderItemPartnerSimln_2

@VDM: {
  lifecycle.contract.type: #PUBLIC_REMOTE_API,
  usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE],
  viewType: #CONSUMPTION
}

@AccessControl: {
    authorizationCheck: #MANDATORY,
    personalData.blocking: #('TRANSACTIONAL_DATA')
}

@EndUserText.label: 'Item Partner Simulation'

@Metadata.ignorePropagatedAnnotations: true

@OData: {
  entityType.name: 'SalesOrderItemPartner_Type'
}

@ObjectModel: {
   semanticKey: ['SalesOrder','SalesOrderItem','PartnerFunction'],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   },
   query.implementedBy: 'ABAP:CL_SD_SO_SIMLN_RAP_V4_QRY'
}
define view entity A_SalesOrderItemPartnerSimln_2
    as select from R_SalesOrderItemPartnerTP as SalesOrderItemPartner

    association        to parent A_SalesOrderItemSimulation_2 as _Item                   on  $projection.SalesOrder     = _Item.SalesOrder
                                                                             and $projection.SalesOrderItem = _Item.SalesOrderItem
    association [1..1] to A_SalesOrderSimulation_2            as _SalesOrder             on  $projection.SalesOrder = _SalesOrder.SalesOrder
{  
  key SalesOrderItemPartner.SalesOrder,
  
  key SalesOrderItemPartner.SalesOrderItem,
  
      @ObjectModel.sapObjectNodeTypeReference: 'PartnerFunction'
  key SalesOrderItemPartner.PartnerFunction,
  
  SalesOrderItemPartner.Customer,
  
  @Consumption.hidden: true
  @Semantics.nullValueIndicatorFor: 'Customer'
  cast( '' as rap_null_value_indicator ) as Customer_H,
  
  SalesOrderItemPartner.Supplier,
  
  @Consumption.hidden: true
  @Semantics.nullValueIndicatorFor: 'Supplier'
  cast( '' as rap_null_value_indicator ) as Supplier_H,
  
  SalesOrderItemPartner.Personnel,

  @Consumption.hidden: true
  @Semantics.nullValueIndicatorFor: 'Personnel'
  cast( '' as rap_null_value_indicator ) as Personnel_H,
  
  SalesOrderItemPartner.ContactPerson,
    
  @Consumption.hidden: true
  @Semantics.nullValueIndicatorFor: 'ContactPerson'
  cast( '' as rap_null_value_indicator ) as ContactPerson_H,
  
  SalesOrderItemPartner.ReferenceBusinessPartner,
  
  SalesOrderItemPartner.PartnerIsSpecificForSDDocItem,

  cast('' as ad_name1)                   as BusinessPartnerName1,

  cast('' as ad_name2)                   as BusinessPartnerName2,

  cast('' as ad_name3)                   as BusinessPartnerName3,

  cast('' as ad_name4)                   as BusinessPartnerName4,  
    
  SalesOrderItemPartner.StreetName,

  SalesOrderItemPartner.StreetPrefixName1,

  SalesOrderItemPartner.StreetPrefixName2,

  SalesOrderItemPartner.StreetSuffixName1,

  SalesOrderItemPartner.StreetSuffixName2,

  SalesOrderItemPartner.HouseNumber,

  SalesOrderItemPartner.PostalCode,

  SalesOrderItemPartner.CityName,

  SalesOrderItemPartner.DistrictName,
    
  SalesOrderItemPartner.Region,
  
  @ObjectModel.sapObjectNodeTypeReference: 'Country'  
  SalesOrderItemPartner.Country,
  
  @ObjectModel.sapObjectNodeTypeReference: 'Country'
  SalesOrderItemPartner.PhoneNumberCountry,
          
  SalesOrderItemPartner.PhoneNumber,
  
  SalesOrderItemPartner.PhoneNumberExtension,
  
  @ObjectModel.sapObjectNodeTypeReference: 'Country'
  SalesOrderItemPartner.MobilePhoneCountry,
  
  SalesOrderItemPartner.MobilePhoneNumber,
  
  @ObjectModel.sapObjectNodeTypeReference: 'Country'
  SalesOrderItemPartner.FaxNumberCountry,
  
  SalesOrderItemPartner.FaxNumber,
  
  SalesOrderItemPartner.FaxNumberExtension,

  SalesOrderItemPartner.InternationalPhoneNumber,

  SalesOrderItemPartner.InternationalMobilePhoneNumber,
  
  SalesOrderItemPartner.InternationalFaxNumber,  
    
  SalesOrderItemPartner.POBox,

  SalesOrderItemPartner.POBoxPostalCode,

  SalesOrderItemPartner.FormOfAddress,
  
  @EndUserText.label: 'Correspondence Language'  
  cast(SalesOrderItemPartner.CorrespondenceLanguage as bu_langu_corr preserving type) as CorrespondenceLanguage,
  
  @Semantics.eMail.address: true 
  SalesOrderItemPartner.EmailAddress,

  SalesOrderItemPartner.TaxJurisdiction,

  SalesOrderItemPartner.TransportZone,

  @Consumption.hidden: true
  @Semantics.nullValueIndicatorFor: 'UnloadingPointName'
  cast( '' as rap_null_value_indicator ) as UnloadingPointNameIsNull,
    
  SalesOrderItemPartner.UnloadingPointName,

  @Consumption.hidden: true
  @Semantics.nullValueIndicatorFor: 'VATRegistration'
  cast( '' as rap_null_value_indicator ) as VATRegistrationIsNull,
    
  SalesOrderItemPartner.VATRegistration,

  SalesOrderItemPartner.SDDocPartnerAddrIsDocSpecific,
  
  //used for ETAG

  @Consumption.hidden: true
  _SalesOrder.LastChangeDateTime,
  
  //    Associations

  @ObjectModel.filter.enabled: false
  @ObjectModel.sort.enabled: false
  _Item,
  @ObjectModel.filter.enabled: false
  @ObjectModel.sort.enabled: false
  _SalesOrder,
  
  // For Access control

    @Consumption.hidden: true
    _SalesOrder.SalesOrderType,
    @Consumption.hidden: true
    _SalesOrder.OrganizationDivision,
    @Consumption.hidden: true
    _SalesOrder.SalesOrganization,
    @Consumption.hidden: true
    _SalesOrder.DistributionChannel
  
}