A_SlsOrdScheduleLineSimln_2

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@EndUserText.label: 'Sales Order Schedule Line Simulation'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: {
  semanticKey: ['SalesOrder','SalesOrderItem', 'ScheduleLine'],
  usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   },
   query.implementedBy: 'ABAP:CL_SD_SO_SIMLN_RAP_V4_QRY'
}

@OData: {
  entityType.name: 'SalesOrderScheduleLine_Type'
}

@VDM: {
  lifecycle.contract.type: #PUBLIC_REMOTE_API,
  viewType: #CONSUMPTION,
  usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
}
define view entity A_SlsOrdScheduleLineSimln_2
  as select from I_SalesOrderScheduleLine as SalesOrderScheduleLine
  association        to parent A_SalesOrderItemSimulation_2   as _Item       on  $projection.SalesOrder             = _Item.SalesOrder
                                                                   and $projection.SalesOrderItem         = _Item.SalesOrderItem
  association [1..1] to A_SalesOrderSimulation_2              as _SalesOrder on  $projection.SalesOrder             = _SalesOrder.SalesOrder

{
    
    key SalesOrderScheduleLine.SalesOrder,

    key SalesOrderScheduleLine.SalesOrderItem,

    key SalesOrderScheduleLine.ScheduleLine,
    
    @ObjectModel.sapObjectNodeTypeReference: 'SalesDocScheduleLineCategory'
    SalesOrderScheduleLine.ScheduleLineCategory,
    
    @Consumption.hidden: true
    @Semantics.nullValueIndicatorFor: 'ScheduleLineOrderQuantity'
    cast( '' as rap_null_value_indicator ) as ScheduleLineOrderQuantity_H,
    
    @Semantics.quantity.unitOfMeasure: 'OrderQuantitySAPUnit'
    @Semantics.quantity.unitOfMeasureSapCode: 'OrderQuantitySAPUnit'
    @Semantics.quantity.unitOfMeasureIsoCode: 'OrderQuantityISOUnit'
    ScheduleLineOrderQuantity,
    
    OrderQuantityUnit                                            as OrderQuantitySAPUnit,
    cast(_OrderQuantityUnit.UnitOfMeasureISOCode as sd_ord_qty_isounit preserving type) as OrderQuantityISOUnit,
    
    RequestedDeliveryDate,

    ConfirmedDeliveryDate,
    
    
    @Consumption.hidden: true
    @Semantics.nullValueIndicatorFor: 'ConfdOrderQtyByMatlAvailCheck'
    cast( '' as rap_null_value_indicator ) as ConfdOrdQtyByMatlAvailCheck_H,
    
    @Semantics.quantity.unitOfMeasure: 'OrderQuantitySAPUnit'
    @Semantics.quantity.unitOfMeasureSapCode: 'OrderQuantitySAPUnit'
    @Semantics.quantity.unitOfMeasureIsoCode: 'OrderQuantityISOUnit'
    ConfdOrderQtyByMatlAvailCheck,
    
    @Semantics.quantity.unitOfMeasure: 'OrderQuantitySAPUnit'
    @Semantics.quantity.unitOfMeasureSapCode: 'OrderQuantitySAPUnit'
    @Semantics.quantity.unitOfMeasureIsoCode: 'OrderQuantityISOUnit'
    DeliveredQtyInOrderQtyUnit,
          
    @Semantics.quantity.unitOfMeasure: 'OrderQuantitySAPUnit'
    @Semantics.quantity.unitOfMeasureSapCode: 'OrderQuantitySAPUnit'
    @Semantics.quantity.unitOfMeasureIsoCode: 'OrderQuantityISOUnit'
    OpenConfdDelivQtyInOrdQtyUnit,

    @Semantics.quantity.unitOfMeasure: 'OrderQuantitySAPUnit'
    @Semantics.quantity.unitOfMeasureSapCode: 'OrderQuantitySAPUnit'
    @Semantics.quantity.unitOfMeasureIsoCode: 'OrderQuantityISOUnit'
    CorrectedQtyInOrderQtyUnit,
    
    @ObjectModel.sapObjectNodeTypeReference: 'DeliveryBlockReason'
    DelivBlockReasonForSchedLine,
    
    PurchaseRequisition,
    
    @Consumption.hidden: true
    @Semantics.nullValueIndicatorFor: 'PurchaseRequisitionItem'
    cast( '' as rap_null_value_indicator ) as PurchaseRequisitionItem_H,    
    
    PurchaseRequisitionItem,
    
    @ObjectModel.sapObjectNodeTypeReference: 'GoodsMovementType'
    SalesOrderScheduleLine.GoodsMovementType,
    
    //Parent

    @ObjectModel.filter.enabled: false
    @ObjectModel.sort.enabled: false
    _Item,
    @ObjectModel.filter.enabled: false
    @ObjectModel.sort.enabled: false
    _SalesOrder,
    
    // For Access control

    @Consumption.hidden: true
    _SalesOrder.SalesOrderType,
    @Consumption.hidden: true
    _SalesOrder.OrganizationDivision,
    @Consumption.hidden: true
    _SalesOrder.SalesOrganization,
    @Consumption.hidden: true
    _SalesOrder.DistributionChannel
}