A_OutbDeliveryPartner_1

DDL: A_OUTBDELIVERYPARTNER_1 SQL: AOUTBDELIVERYP1 Type: view BASIC Package: VDM_LE_SHP_OBD_API_V2

CDS view for API exposure

A_OutbDeliveryPartner_1 is a Basic CDS View that provides data about "CDS view for API exposure" in SAP S/4HANA. It reads from 1 data source (I_SDDocumentCompletePartners) and exposes 18 fields with key fields SDDocument, SDDocumentItem, PartnerFunction. It has 5 associations to related views. Part of development package VDM_LE_SHP_OBD_API_V2.

1 data source(s) 18 fields

Data Sources (1)

SourceAliasJoin Type
I_SDDocumentCompletePartners I_SDDocumentCompletePartners from

Associations (5)

CardinalityTargetAliasCondition
[1..1] A_OutbDeliveryHeader_1 _DeliveryDocumentHeader _DeliveryDocumentHeader.DeliveryDocument = $projection.SDDocument
[1..1] A_OutbDeliveryAddress _Address _Address.AddressID = $projection.AddressID
[1..1] A_OutbDeliveryAddress_2 _Address2 _Address2.DeliveryDocument = $projection.SDDocument and _Address2.PartnerFunction = $projection.PartnerFunction
[0..1] A_Supplier _AuthSupplier $projection.Supplier = _AuthSupplier.Supplier
[0..1] A_Customer _AuthCustomer $projection.Customer = _AuthCustomer.Customer

Annotations (12)

NameValueLevelField
AbapCatalog.sqlViewName AOUTBDELIVERYP1 view
AbapCatalog.compiler.compareFilter true view
Metadata.ignorePropagatedAnnotations true view
ClientHandling.algorithm #SESSION_VARIABLE view
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view
VDM.lifecycle.contract.type #PUBLIC_REMOTE_API view
EndUserText.label CDS view for API exposure view
VDM.viewType #BASIC view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #D view
ObjectModel.usageType.sizeCategory #XL view

Fields (18)

KeyFieldSource TableSource FieldDescription
KEY SDDocument SDDocument
KEY SDDocumentItem SDDocumentItem
KEY PartnerFunction PartnerFunction
Customer Customer
Supplier Supplier
Personnel Personnel
AddressID AddressID
BusinessPartnerAddressUUID _BusinessPartnerAddress AddressUUID
RefBusinessPartnerAddressUUID _BPRefAddressForDocSpcfcAddr AddressUUID
ReferenceBusinessPartner ReferenceBusinessPartner
BPRefAddressIDForDocSpcfcAddr BPRefAddressIDForDocSpcfcAddr
SDDocPartnerAddressRefType SDDocPartnerAddressRefType
ContactPerson ContactPerson
_Address _Address
_Address2 _Address2
_DeliveryDocumentHeader _DeliveryDocumentHeader
_AuthSupplier _AuthSupplier
_AuthCustomer _AuthCustomer 
@AbapCatalog.sqlViewName: 'AOUTBDELIVERYP1'
@AbapCatalog.compiler.compareFilter: true
@Metadata.ignorePropagatedAnnotations: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck:#CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@VDM.lifecycle.contract.type:#PUBLIC_REMOTE_API

@EndUserText.label: 'CDS view for API exposure'
@VDM.viewType: #BASIC
@ObjectModel: {
  usageType.dataClass: #TRANSACTIONAL,
  usageType.serviceQuality: #D,
  usageType.sizeCategory: #XL
}

@AccessControl.privilegedAssociations:  [ '_Address' ]

/* !! Direct Exposure to Odata is not allowed with this view !! */

define view A_OutbDeliveryPartner_1 as select from I_SDDocumentCompletePartners 
association [1..1] to A_OutbDeliveryHeader_1 as _DeliveryDocumentHeader on _DeliveryDocumentHeader.DeliveryDocument = $projection.SDDocument
association [1..1] to A_OutbDeliveryAddress as _Address on _Address.AddressID = $projection.AddressID
association [1..1] to A_OutbDeliveryAddress_2 as _Address2 on _Address2.DeliveryDocument = $projection.SDDocument and _Address2.PartnerFunction = $projection.PartnerFunction

association [0..1] to A_Supplier as _AuthSupplier on $projection.Supplier = _AuthSupplier.Supplier
  
association [0..1] to A_Customer as _AuthCustomer on $projection.Customer = _AuthCustomer.Customer

{
    key SDDocument,
    key SDDocumentItem,
    @ObjectModel.sapObjectNodeTypeReference: 'PartnerFunction'
    key PartnerFunction,
    Customer,
    Supplier,
    Personnel,
    AddressID,
   _BusinessPartnerAddress.AddressUUID as BusinessPartnerAddressUUID,
   _BPRefAddressForDocSpcfcAddr.AddressUUID as RefBusinessPartnerAddressUUID,
   @Consumption.hidden: true
   ReferenceBusinessPartner,
   @Consumption.hidden: true
   BPRefAddressIDForDocSpcfcAddr,
   @Consumption.hidden: true
   SDDocPartnerAddressRefType,
    ContactPerson,
    
    /* Associations */
    _Address,
    _Address2,
    @ObjectModel.association.type: [#TO_COMPOSITION_PARENT,#TO_COMPOSITION_ROOT]
    _DeliveryDocumentHeader,
    
    //only for DCL

    @Consumption.hidden: true
    _AuthSupplier,
    @Consumption.hidden: true
    _AuthCustomer
}
where  _DeliveryDocumentHeader.SDDocumentCategory = 'J'

Learn More