A_OutbDeliveryAddress

@AbapCatalog.sqlViewName: 'AOUTBDELIVERYAD'
@AbapCatalog.compiler.compareFilter: true
@Metadata.ignorePropagatedAnnotations: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.lifecycle.contract.type:#PUBLIC_REMOTE_API

@EndUserText.label: 'CDS view for API exposure'
@AccessControl.authorizationCheck:#PRIVILEGED_ONLY
@VDM.viewType: #COMPOSITE
@ObjectModel: {
  usageType.dataClass: #MASTER,
  usageType.serviceQuality: #C,
  usageType.sizeCategory: #XL
}

/* !! Direct Exposure to Odata is not allowed with this view !! */
/* !! Direct Access prevented in OData DPC_EXT class !!*/


/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ]  } */
define view A_OutbDeliveryAddress as select from I_Address_2
{
    key I_Address_2.AddressID,
    I_Address_2.StreetPrefixName2                                           as AdditionalStreetPrefixName,
    I_Address_2.StreetSuffixName2                                           as AdditionalStreetSuffixName,
    I_Address_2.AddressTimeZone,
    I_Address_2.Building,
    I_Address_2.OrganizationName1                                           as BusinessPartnerName1,
    I_Address_2.OrganizationName2                                           as BusinessPartnerName2,
    I_Address_2.OrganizationName3                                           as BusinessPartnerName3,
    I_Address_2.OrganizationName4                                           as BusinessPartnerName4,
    I_Address_2.CareOfName,
    I_Address_2.CityNumber                                                  as CityCode,
    I_Address_2.CityName,
    cast('                         ' as char25 preserving type )            as CitySearch,
    I_Address_2.CompanyPostalCode,
    I_Address_2.CorrespondenceLanguage,
    I_Address_2.Country,
    I_Address_2.SecondaryRegionName                                         as County,
    I_Address_2.DeliveryServiceNumber,
    I_Address_2.DeliveryServiceTypeCode,
    I_Address_2.DistrictName                                                as District,
    _CurrentDfltFaxNumber.FaxAreaCodeSubscriberNumber                       as FaxNumber,
    I_Address_2.Floor,
    I_Address_2.FormOfAddress,
    I_Address_2.AddresseeFullName                                           as FullName,
    I_Address_2.VillageName                                                 as HomeCityName,
    I_Address_2.HouseNumber,
    I_Address_2.HouseNumberSupplementText,
    I_Address_2.AddressRepresentationCode                                   as Nation,
    I_Address_2.AddressPersonID                                             as Person,
    _CurrentDfltLandlinePhoneNmbr.PhoneAreaCodeSubscriberNumber             as PhoneNumber,
    I_Address_2.POBox,
    I_Address_2.POBoxDeviatingCityName,
    I_Address_2.POBoxDeviatingCountry,
    I_Address_2.POBoxDeviatingRegion,
    I_Address_2.POBoxIsWithoutNumber,
    I_Address_2.POBoxLobbyName,
    I_Address_2.POBoxPostalCode,
    I_Address_2.PostalCode,
    I_Address_2.PrfrdCommMediumType,
    I_Address_2.Region,
    I_Address_2.RoomNumber,
    I_Address_2.AddressSearchTerm1                                          as SearchTerm1,
    I_Address_2.StreetName,
    I_Address_2.StreetPrefixName1                                           as StreetPrefixName,
    cast('                         ' as char25 preserving type )            as StreetSearch,
    I_Address_2.StreetSuffixName1                                           as StreetSuffixName,
    I_Address_2.TaxJurisdiction,
    I_Address_2.TransportZone
} where I_Address_2.AddressPersonID is initial
    and I_Address_2.AddressRepresentationCode is initial