I_RERentableObject

@AccessControl.authorizationCheck: #MANDATORY
@Metadata.allowExtensions: true

@Analytics: {
              dataCategory: #DIMENSION,
              internalName: #LOCAL,
              dataExtraction.enabled: true
}

@ObjectModel: {
            usageType:{
                        dataClass: #MASTER,
                        serviceQuality: #C,
                        sizeCategory: #L
            },
            representativeKey: 'RealEstateRentableObjectUUID',
            semanticKey: [ 'RealEstateRentableObjectNumber' ],
            sapObjectNodeType.name: 'RealEstateRentableObject',
            supportedCapabilities: [ #ANALYTICAL_DIMENSION,
                                     #CDS_MODELING_DATA_SOURCE,
                                     #CDS_MODELING_ASSOCIATION_TARGET,
                                     #SQL_DATA_SOURCE,
                                     #EXTRACTION_DATA_SOURCE ],
            modelingPattern: #ANALYTICAL_DIMENSION,
            objectIdentifier.oidElement: 'RealEstateRentableObjectOID'
}
@ODM.oid: 'RealEstateRentableObjectOID'

@AccessControl.privilegedAssociations: ['_StatusObject', '_StatusObjectStatus']

@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Real Estate Rentable Object'
define view entity I_RERentableObject
  as select from I_REGenericRentalObject

  association [1..*] to I_RERntblObjToUsblObjAssgmt as _RERntblObjToUsblObjAssgmt on $projection.RealEstateRentableObjectUUID = _RERntblObjToUsblObjAssgmt.RealEstateRentableObjectUUID
  association [1..*] to I_REUsblObjToRntblObjAssgmt as _REUsblObjToRntblObjAssgmt on $projection.RealEstateRentableObjectUUID = _REUsblObjToRntblObjAssgmt.RealEstateRentableObjectUUID
  
  association [1..*] to I_RERntblObjectMeasurement    as _RERntblObjectMeasurement on $projection.RealEstateRentableObjectUUID = _RERntblObjectMeasurement.RealEstateRentableObjectUUID
  association [1..*] to I_RERntblObjToContractAssgmt  as _RERntblObjToContractAssgmt on $projection.RealEstateRentableObjectUUID = _RERntblObjToContractAssgmt.RealEstateRentableObjectUUID
  association [1..*] to I_RERntblObjArchtrUsage       as _RERntblObjArchtrUsage on $projection.RealEstateRentableObjectUUID = _RERntblObjArchtrUsage.RealEstateRentableObjectUUID
  association [1..*] to I_RERntblArchtrObjUsageMsmt as _RERntblArchtrObjUsageMsmt on $projection.RealEstateRentableObjectUUID = _RERntblArchtrObjUsageMsmt.RealEstateRentableObjectUUID
  association [1..*] to I_RERntblObjectStatusObject as _RERntblObjectStatusObject on $projection.RealEstateRentableObjectUUID = _RERntblObjectStatusObject.RealEstateRentableObjectUUID
  
// extensibility

  association [1..1] to E_RERentableObject          as _Extension                 on $projection.RealEstateRentableObjectUUID = _Extension.RealEstateRentableObjectUUID
{
  key REGenericRentalObjectUUID                                                             as RealEstateRentableObjectUUID,
      REGenericRentalObjectType,
      InternalRealEstateNumber,
      @ObjectModel.foreignKey.association: '_StatusObject'
      REStatusObject,
      REGenericRentalObjectOID                                                              as RealEstateRentableObjectOID,
      REGnrcRntlObjectAlternativeID,
      //REGnrcRentalObjPortfolioID,

      _RERntblObjToUsblObjAssgmt._REUsableObject.REGnrcRentalObjPortfolioID,
      cast( REGenericRentalObjectNumber as regogonrrentable preserving type )               as RealEstateRentableObjectNumber,
      cast( REGenericRentalObjectName   as regovdmxrentableobject preserving type )         as RERentableObjectName,
      REIdentificationKey,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      CompanyCode,
      ValidityStartDate,
      ValidityEndDate,
      @ObjectModel.foreignKey.association: '_REAuthorizationGroup'
      REAuthorizationGroup,
      @ObjectModel.foreignKey.association: '_REGnrcRentalObjUsageCategory'
      REGnrcRentalObjUsageCategory,
      @ObjectModel.foreignKey.association: '_REGnrcRentalObjUsageType'
      cast( REGenericRentalObjectUsageType as regovdmrentableobjusagetype preserving type ) as REGenericRentalObjectUsageType,
      @ObjectModel.foreignKey.association: '_REArchitectureObject'
      REGenericRentalObjParentUUID,
      @ObjectModel.foreignKey.association: '_RERentableObjectCategory'
      RERentableObjectCategory,

      @Semantics.systemDateTime.createdAt: true
      CreationDateTime,
      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime,
      @Semantics.systemDateTime.localInstanceLastChangedAt: true
      LocalLastChangeDateTime,

      /* Associations */
      _REKeyAssgmt,
      _CompanyCode,
      _REAuthorizationGroup,
      //_REGnrcRentalObjPortfolio,

      _REGnrcRentalObjUsageCategory,
      _REGnrcRentalObjUsageType,
      _RERentableObjectCategory,
      _REArchitectureObject,
      _StatusObject,
      _StatusObjectStatus,
      _RERntblObjToUsblObjAssgmt,
      _REUsblObjToRntblObjAssgmt,
      _RERntblObjectMeasurement,
      _RERntblObjToContractAssgmt,
      _RERntblObjArchtrUsage,
      _RERntblArchtrObjUsageMsmt,
      _RERntblObjectStatusObject
}
where
     REGenericRentalObjectType = 'R' //Rentable Object