I_PURGDOCSCHEDULELINEBASIC

CDS View

Purchasing Document Schedule Line Basic

I_PURGDOCSCHEDULELINEBASIC is a CDS View in S/4HANA. Purchasing Document Schedule Line Basic. It contains 6 fields. 16 CDS views read from this table.

Used by 16 CDS view(s) 6 fields

CDS Views using this table (16)

ViewTypeJoinVDMDescription
C_RFM_MngPOScheduleLine view from CONSUMPTION Purchase Order Schedule Line Details
I_PurOrdScheduleLineBasic view from BASIC Purchasing Document Schedule Line Basic
I_RFM_MngPOGenNextDelivDate view from COMPOSITE Next Delivery Date for GA
I_RFM_MngPOHdrNextDelivDate view from COMPOSITE Next Delivery Date for Header
I_RFM_MngPOItemDelivDate view from COMPOSITE Item Delivery Date
I_RFM_MngPONextDelivDate view from COMPOSITE Next Delivery Date
I_RFQScheduleLine view from BASIC Request For Quotation Schedule Line
I_StockTransptOrdScheduleLine view from BASIC CDS View for STO Schedule Line
I_SuplrQtnScheduleLine view from BASIC Schedule Line of a Supplier Quotation Item
P_OverDuePurReqnItemForConf view inner COMPOSITE Overdue Purchase Requisition Items for Confirmation
P_PODelivSchedDteCalcDays view from CONSUMPTION PO by Delivery Sch. Date Calc Days
P_POScheduleLine view from CONSUMPTION Purchase Order Schedule Line
P_PurReqnSchedLinesForConf view inner COMPOSITE PO Schedule Lines for confirmation
P_SupDmndOvwSTODate view from COMPOSITE View for Earliest Requested Delivery Date for STO
R_CntrlReqForQtanScheduleLine view from BASIC Restricted View for Central RFQ Item Schedule Line
R_CntrlSuplrQtanScheduleLine view from BASIC Restricted View for Cntrl Suplr Qtan Item Schedule Line

Fields (6)

KeyField CDS FieldsUsed in Views
KEY PurchasingDocument PurchasingDocument 2
KEY PurchasingDocumentItem PurchasingDocumentItem 1
KEY ScheduleLine ScheduleLine 1
_OrderQuantityUnit _OrderQuantityUnit 1
OrderQuantityUnit OrderQuantityUnit 3
RoughGoodsReceiptQty RoughGoodsReceiptQty 1 
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Purchasing Document Schedule Line Basic'
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IMMPRGDOCSLBASIC'
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

define view I_PurgDocScheduleLineBasic
  as select from eket as eket 

  association [1..1] to I_PurchasingDocument      as _PurchasingDocument        on  $projection.PurchasingDocument        = _PurchasingDocument.PurchasingDocument
  association [1..1] to I_PurchasingDocumentItem  as _PurchasingDocumentItem    on  $projection.PurchasingDocument        = _PurchasingDocumentItem.PurchasingDocument
                                                                                and $projection.PurchasingDocumentItem    = _PurchasingDocumentItem.PurchasingDocumentItem
  association [0..1] to I_UnitOfMeasure           as _OrderQuantityUnit         on  $projection.OrderQuantityUnit         = _OrderQuantityUnit.UnitOfMeasure
  association [0..1] to I_Purchaserequisition     as _PurchaseRequisition       on  $projection.PurchaseRequisition       = _PurchaseRequisition.PurchaseRequisition
  association [0..1] to I_Purchaserequisitionitem as _PurchaseRequisitionItem   on  $projection.PurchaseRequisition       = _PurchaseRequisitionItem.PurchaseRequisition
                                                                                and $projection.PurchaseRequisitionItem   = _PurchaseRequisitionItem.PurchaseRequisitionItem
  association [1..1] to I_Deliverydatecategory    as _DeliveryDateCategory      on  $projection.DelivDateCategory         = _DeliveryDateCategory.DelivDateCategory
  
  // new asociations for CustomUI

  association [0..*] to I_UnitOfMeasureText       as _OrderQuantityUnitText     on  $projection.OrderQuantityUnit         = _OrderQuantityUnitText.UnitOfMeasure
  
 {
  key eket.ebeln as PurchasingDocument,
  key eket.ebelp as PurchasingDocumentItem,
  key etenr      as ScheduleLine,

      //@ObjectModel: { foreignKey.association: '_DeliveryDateCategory'} I_DeliveryDateCategory wrong implemented

      lpein      as DelivDateCategory,
      eindt      as ScheduleLineDeliveryDate,
      slfdt      as SchedLineStscDeliveryDate,
      startdate  as PerformancePeriodStartDate,
      enddate    as PerformancePeriodEndDate,
      uzeit      as ScheduleLineDeliveryTime,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'      
      eket.menge as ScheduleLineOrderQuantity,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      wemng      as RoughGoodsReceiptQty,

      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_OrderQuantityUnit'
      _PurchasingDocumentItem.OrderQuantityUnit       as OrderQuantityUnit,

      @ObjectModel.foreignKey.association: '_PurchaseRequisition'
      eket.banfn as PurchaseRequisition,

      @ObjectModel.foreignKey.association: '_PurchaseRequisitionItem'
      eket.bnfpo as PurchaseRequisitionItem,

      estkz      as SourceOfCreation,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'      
      ameng      as PrevDelivQtyOfScheduleLine,
      eket.mahnz as NoOfRemindersOfScheduleLine,
      fixkz      as ScheduleLineIsFixed,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'      
      mng02      as ScheduleLineCommittedQuantity,
      rsnum      as Reservation,
      mbdat      as ProductAvailabilityDate, 
      mbuhr      as MaterialStagingTime,
      tddat      as TransportationPlanningDate,
      tduhr      as TransportationPlanningTime, 
      lddat      as LoadingDate,
      lduhr      as LoadingTime,
      wadat      as GoodsIssueDate,
      wauhr      as GoodsIssueTime,
      eldat      as STOLatestPossibleGRDate,
      eluhr      as STOLatestPossibleGRTime,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'       
      glmng      as StockTransferDeliveredQuantity,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'      
      wamng      as ScheduleLineIssuedQuantity,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'      
      dabmg      as MRPRelevantQuantity,
      charg      as Batch,
      licha      as BatchBySupplier,
      
      _PurchaseRequisition,
      _PurchaseRequisitionItem,
      _DeliveryDateCategory,
      _PurchasingDocument,
      _PurchasingDocumentItem,
      _OrderQuantityUnit,
      
      // Text associations for CustomUI

      _OrderQuantityUnitText

}

Learn More