I_RFQScheduleLine

@ClientHandling.algorithm: #SESSION_VARIABLE //Inserted by VDM CDS Suite Plugin


@ObjectModel:{ representativeKey: 'ScheduleLine',
               semanticKey: 'RequestForQuotation',
               usageType.dataClass: #TRANSACTIONAL,
               usageType.serviceQuality: #B,
               usageType.sizeCategory: #L }

@EndUserText.label: 'Request For Quotation Schedule Line'

@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.sqlViewName: 'IMMRFQSCHEDULELN'

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

define view I_RFQScheduleLine 
  as select from I_PurgDocScheduleLineBasic
  
//    inner join   I_RequestForQuotation on I_PurgDocScheduleLineBasic.PurchasingDocument = I_RequestForQuotation.RequestForQuotation


  association [1..1] to I_RequestForQuotation     as _RequestForQuotation     on  $projection.RequestForQuotation = _RequestForQuotation.RequestForQuotation

  association [1..1] to I_RequestForQuotationItem as _RequestForQuotationItem on  $projection.RequestForQuotation     = _RequestForQuotationItem.RequestForQuotation
                                                                              and $projection.RequestForQuotationItem = _RequestForQuotationItem.RequestForQuotationItem

{

      @ObjectModel: { readOnly: true,
                      foreignKey.association: '_RequestForQuotation' }
  key cast (PurchasingDocument as vdm_requestforquotation preserving type )               as RequestForQuotation,
      @ObjectModel: { readOnly: true,
                      foreignKey.association: '_RequestForQuotationItem' }
  key cast (PurchasingDocumentItem as vdm_requestforquotationitem preserving type )       as RequestForQuotationItem,
      @ObjectModel: { readOnly: true }
  key ScheduleLine,

      DelivDateCategory,
      cast (ScheduleLineDeliveryDate as mm_a_delivery_date preserving type)               as ScheduleLineDeliveryDate,
      SchedLineStscDeliveryDate,
      ScheduleLineDeliveryTime,
      ScheduleLineOrderQuantity,
      RoughGoodsReceiptQty,
      cast (PerformancePeriodStartDate as vdm_performanceperiodstartdate preserving type) as PerformancePeriodStartDate,
      cast (PerformancePeriodEndDate as vdm_performanceperiodenddate preserving type)     as PerformancePeriodEndDate,
      OrderQuantityUnit,
      _RequestForQuotation,
      _RequestForQuotationItem,
      _DeliveryDateCategory

}
where
  ScheduleLine = '0001'