R_CntrlReqForQtanScheduleLine

@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Restricted View for Central RFQ Item Schedule Line'
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter:true
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@AccessControl.authorizationCheck: #CHECK

@AbapCatalog.sqlViewName: 'RCNTRLRFQSCHL'
@ObjectModel:{ representativeKey: 'ScheduleLine',
               semanticKey: 'CentralRequestForQuotation',
               usageType.dataClass: #TRANSACTIONAL,
               usageType.serviceQuality: #B,
               usageType.sizeCategory: #L }


define view R_CntrlReqForQtanScheduleLine
  as select from I_PurgDocScheduleLineBasic

    inner join   R_CentralRequestForQuotation on I_PurgDocScheduleLineBasic.PurchasingDocument = R_CentralRequestForQuotation.CentralRequestForQuotation

  association [1..1] to R_CentralRequestForQuotation as _CentralRequestForQuotation on  $projection.CentralRequestForQuotation = _CentralRequestForQuotation.CentralRequestForQuotation

  association [1..1] to R_CentralReqForQuotationItem as _CentralReqForQuotationItem on  $projection.CentralRequestForQuotation     = _CentralReqForQuotationItem.CentralRequestForQuotation
                                                                                    and $projection.CentralRequestForQuotationItem = _CentralReqForQuotationItem.CentralRequestForQuotationItem

{
      @ObjectModel: { readOnly: true,
                      foreignKey.association: '_CentralRequestForQuotation' }
  key cast (PurchasingDocument as vdm_requestforquotation preserving type )               as CentralRequestForQuotation,
      @ObjectModel: { readOnly: true,
                      foreignKey.association: '_CentralReqForQuotationItem' }
  key cast (PurchasingDocumentItem as vdm_requestforquotationitem preserving type )       as CentralRequestForQuotationItem,
      @ObjectModel: { readOnly: true }
  key ScheduleLine,

      DelivDateCategory,
      cast (ScheduleLineDeliveryDate as mm_a_delivery_date preserving type)               as ScheduleLineDeliveryDate,
      SchedLineStscDeliveryDate,
      ScheduleLineDeliveryTime,
      ScheduleLineOrderQuantity,
      RoughGoodsReceiptQty,
      cast (PerformancePeriodStartDate as vdm_performanceperiodstartdate preserving type) as PerformancePeriodStartDate,
      cast (PerformancePeriodEndDate as vdm_performanceperiodenddate preserving type)     as PerformancePeriodEndDate,
      I_PurgDocScheduleLineBasic.OrderQuantityUnit                                        as OrderQuantityUnit,

      /* Association */
      _CentralRequestForQuotation,
      _CentralReqForQuotationItem,
      _DeliveryDateCategory

}
where
  ScheduleLine = '0001'