I_UserDescription

@AbapCatalog.sqlViewName: 'IUSERDESCRIPTION'
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@EndUserText.label: 'Beschreibung'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #CLIENT_DEPENDENT
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #M
@AccessControl.personalData.blocking: #REQUIRED
@Metadata.ignorePropagatedAnnotations:true 



// Read the description of a user

// - User with address: Read Fullname

// - Technical User:    Read description of technical User

//

// This view must not be exposed to end users directly, because it exposes person relevant information.

// Only use this view in the definition of context-specific consumption views as a target for the "CreatedByUser"

// and "LastChangedByUser" associations. That's why, the view definition intentionally does not contain the

// "@ObjectModel.representativeKey", "@ObjectModel.text.element" or "@Analytics..." annotations.


define view I_UserDescription
  as select from    usr21
    left outer join adrp on  adrp.persnumber = usr21.persnumber
                         and adrp.nation     = ''
                         and adrp.date_from  = '00010101'

{
  key          cast( usr21.bname    as vdm_userid          preserving type )   as UserID,
      case
        when usr21.idadtype = '01'
          then cast( usr21.techdesc as vdm_userdescription preserving type )
        else   cast( adrp.name_text as vdm_userdescription preserving type )
        end                                                                    as UserDescription,
      case
        when usr21.idadtype = '01'
          then cast( 'X'            as vdm_istechnicaluser preserving type )
        else   cast( ' '            as vdm_istechnicaluser preserving type )         
        end                                                                    as IsTechnicalUser
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"ADRP",
"USR21"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/