R_REUsableObjectTP

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Real Estate Usable Object TP'
@ObjectModel.usageType: {
        serviceQuality: #C,
        dataClass: #TRANSACTIONAL,
        sizeCategory: #XL
    }

@VDM: {
    viewType: #TRANSACTIONAL,
    lifecycle.contract.type: #SAP_INTERNAL_API,
    usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
    }
@ObjectModel.sapObjectNodeType.name: 'RealEstateUsableObject'
@ObjectModel.objectIdentifier.oidElement: 'RealEstateUsableObjectOID'
@ObjectModel.alternativeKey: [{ element: [ 'RealEstateUsableObjectOID' ], id: 'OID', uniqueness: #UNIQUE_IF_NOT_INITIAL }]
define root view entity R_REUsableObjectTP
  as select from I_REUsableObject as _REUsableObject
  composition [1..*] of R_REUsblObjLdngAcctAssgmtObjTP as _REUsblObjLdngAcctAssgmtObj
  composition [1..*] of R_REUsblObjAddlAcctAssgmtObjTP as _REUsblObjAddlAcctAssgmtObj
  composition [0..*] of R_REUsableObjectMeasurementTP  as _REUsableObjectMeasurement
  composition [0..*] of R_REUsableObjectStatusObjectTP as _REUsableObjectStatusObject
  composition [0..*] of R_REUsblObjToContractAssgmtTP  as _REUsblObjToContractAssgmt
  composition [0..*] of R_REUsblObjArchtrUsageTP       as _REUsblObjArchitectureUsage
{
  key RealEstateUsableObjectUUID,
      REGenericRentalObjectType,
      InternalRealEstateNumber,
      REStatusObject,
      RealEstateUsableObjectOID,
      RealEstateUsableObjectNumber,
      @ObjectModel.editableFieldFor: 'RealEstateUsableObjectNumber'
      RealEstateUsableObjectNumber as REUsableObjectNumberForEdit,
      REGnrcRntlObjectAlternativeID,
      REUsableObjectName,
      REIdentificationKey,
      CompanyCode,
      ValidityStartDate,
      ValidityEndDate,
      REAuthorizationGroup,
      REGnrcRentalObjUsageCategory,
      REGenericRentalObjectUsageType,
      REGnrcRentalObjPortfolioID,
      REGnrcRentalObjOwnershipID,
      REGenericRentalObjParentUUID,
      cast (_REArchitectureObject.REArchitectureObjectNumber as reobvdmobnrbuildingland preserving type ) as REArchtrObjectNumberBldngLand,
      _StatusObject.StatusProfile,
      CreationDateTime,
      LastChangeDateTime,
      LocalLastChangeDateTime,

      /* Associations */
      _CompanyCode,
      _REAuthorizationGroup,
      _REGnrcRentalObjUsageCategory,
      _REGnrcRentalObjUsageType,
      _REGnrcRentalObjPortfolio,
      _REGnrcRentalObjOwnership,
      _REArchitectureObject,
      _StatusObject,
      _StatusObjectStatus,
      _REGenericRentalObjectType,

      /* Compositions */
      _REUsblObjLdngAcctAssgmtObj,
      _REUsblObjAddlAcctAssgmtObj,
      _REUsableObjectMeasurement,
      _REUsableObjectStatusObject,
      _REUsblObjToContractAssgmt,
      _REUsblObjArchitectureUsage
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_REARCHITECTUREOBJECT",
"I_REUSABLEOBJECT",
"I_STATUSOBJECT"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_REARCHITECTUREOBJECT",
"I_REAUTHORIZATIONGROUP",
"I_REGENERICRENTALOBJECTTYPE",
"I_REGNRCRENTALOBJOWNERSHIP",
"I_REGNRCRENTALOBJPORTFOLIO",
"I_REGNRCRENTALOBJUSAGECATEGORY",
"I_REGNRCRENTALOBJUSAGETYPE",
"I_STATUSOBJECT",
"I_STATUSOBJECTSTATUS",
"R_REUSABLEOBJECTMEASUREMENTTP",
"R_REUSABLEOBJECTSTATUSOBJECTTP",
"R_REUSBLOBJADDLACCTASSGMTOBJTP",
"R_REUSBLOBJARCHTRUSAGETP",
"R_REUSBLOBJLDNGACCTASSGMTOBJTP",
"R_REUSBLOBJTOCONTRACTASSGMTTP"
],
"BASE":
[
"I_REUSABLEOBJECT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/