R_REUsableObjectMeasurementTP

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'RE Usable Object Measurement TP'
@ObjectModel.usageType: {
        serviceQuality: #C,
        dataClass: #TRANSACTIONAL,
        sizeCategory: #L
    }

@VDM: {
    viewType: #TRANSACTIONAL,
    lifecycle.contract.type: #SAP_INTERNAL_API,
    usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
    }
define view entity R_REUsableObjectMeasurementTP
  as select from I_REMeasurement  as _REMeasurement
    inner join   I_REUsableObject as _REUsableObjectData on _REUsableObjectData.InternalRealEstateNumber = _REMeasurement.InternalRealEstateNumber
  association        to parent R_REUsableObjectTP as _REUsableObject  on $projection.RealEstateUsableObjectUUID = _REUsableObject.RealEstateUsableObjectUUID
  association [1..1] to I_REEntryValidity         as _REEntryValidity on $projection.REEntryValidity = _REEntryValidity.REEntryValidity
{
  key _REUsableObjectData.RealEstateUsableObjectUUID,
  key _REMeasurement.InternalRealEstateNumber,
  key _REMeasurement.REMeasurementType,
  key cast( _REMeasurement.ValidityEndDate as abap.char(8) ) as ValidityEndDate,
      @ObjectModel.editableFieldFor: 'ValidityEndDate'
      _REMeasurement.ValidityEndDate                         as ValidityEndDateForEdit,
      _REMeasurement.ValidityStartDate,

      @ObjectModel.editableFieldFor: 'REMeasurementType'
      _REMeasurement.REMeasurementType                       as REMeasurementTypeForEdit,
      _REMeasurement._REMeasurementType.REMeasurementIsTotal,
      _REMeasurement.REMeasurementUnit,
      _REMeasurement.REMeasurementQuantity,
      _REMeasurement.REMaximumMeasurementQuantity,

      @ObjectModel.foreignKey.association: '_REEntryValidity'
      case
          when _REMeasurement.ValidityStartDate is initial and _REMeasurement.ValidityEndDate is initial then cast (left('3',1) as recavdmentryvalidity preserving type )
          when _REMeasurement.ValidityStartDate > $session.system_date then cast (left('2',1) as recavdmentryvalidity preserving type )
          when _REMeasurement.ValidityStartDate <= $session.system_date and _REMeasurement.ValidityEndDate >= $session.system_date then cast(left('3',1) as recavdmentryvalidity preserving type )
          else cast (left('1',1) as recavdmentryvalidity preserving type )
      end                                                    as REEntryValidity,

      case
          when _REMeasurement.ValidityStartDate is initial and _REMeasurement.ValidityEndDate is initial then 3
          when _REMeasurement.ValidityStartDate > $session.system_date then 2
          when _REMeasurement.ValidityStartDate <= $session.system_date and _REMeasurement.ValidityEndDate >= $session.system_date then 3
      else 1
      end                                                    as REEntryValidityCriticality,

      /* Associations */
      _REUsableObject,
      _REMeasurement._REMeasurementType                      as _REMeasurementType,
      _REMeasurement._UnitOfMeasure                          as _UnitOfMeasure,
      _REEntryValidity
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_REMEASUREMENT",
"I_REMEASUREMENTTYPE",
"I_REUSABLEOBJECT"
],
"ASSOCIATED":
[
"I_REENTRYVALIDITY",
"I_REMEASUREMENTTYPE",
"I_UNITOFMEASURE",
"R_REUSABLEOBJECTTP"
],
"BASE":
[
"I_REMEASUREMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/