I_REUSABLEOBJECT

CDS View

Real Estate Usable Object

I_REUSABLEOBJECT is a CDS View in S/4HANA. Real Estate Usable Object. It contains 1 fields. 8 CDS views read from this table.

Used by 8 CDS view(s) 1 fields

CDS Views using this table (8)

ViewTypeJoinVDMDescription
ESH_N_REUSBLOBJ view from
I_REArchtrObjectUsageHNRltn view_entity from COMPOSITE RE Architecture Object Usage Hierarchy Node Relation
I_REUsableObjectVH view_entity from COMPOSITE Real Estate Usable Object
I_REUsblObjectToContractAssgmt view_entity inner COMPOSITE Real Estate Usable Object Contract Assignment
R_REUsableObjectMeasurementTP view_entity inner TRANSACTIONAL RE Usable Object Measurement TP
R_REUsableObjectTP view_entity from TRANSACTIONAL Real Estate Usable Object TP
R_REUsblObjAddlAcctAssgmtObjTP view_entity inner TRANSACTIONAL RE Usable Object Addl Account Assign TP
R_REUsblObjLdngAcctAssgmtObjTP view_entity inner TRANSACTIONAL RE Usable Object Leading Account Assign TP

Fields (1)

KeyField CDS FieldsUsed in Views
KEY RealEstateUsableObjectUUID RealEstateUsableObjectUUID 4 
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Real Estate Usable Object'

//@ObjectModel.representativeKey: 'RealEstateUsableObjectNumber'

@ObjectModel.semanticKey: ['RealEstateUsableObjectNumber']
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@Metadata.allowExtensions: true
@VDM.viewType: #COMPOSITE

@Analytics.internalName:#LOCAL
@Analytics:{
    dataCategory: #DIMENSION,
    dataExtraction: {
        enabled: true,
        delta.changeDataCapture: {
        automatic: true
        }
    }
}

define view entity I_REUsableObject
  as select from I_REGenericRentalObject

  association [0..*] to I_RERntblObjToUsblObjAssgmt as _REUsblObjToRntblObjAssgmt on $projection.RealEstateUsableObjectUUID = _REUsblObjToRntblObjAssgmt.RealEstateUsableObjectUUID

{
  key REGenericRentalObjectUUID                                                           as RealEstateUsableObjectUUID,
      REGenericRentalObjectType,
      InternalRealEstateNumber,
      REStatusObject,
      REGenericRentalObjectOID                                                            as RealEstateUsableObjectOID,
      REGnrcRntlObjectAlternativeID,
      cast( REGenericRentalObjectNumber as regogonrusable preserving type )               as RealEstateUsableObjectNumber,
      cast( REGenericRentalObjectName   as regovdmxusableobject preserving type )         as REUsableObjectName,
      REIdentificationKey,
      CompanyCode,
      ValidityStartDate,
      ValidityEndDate,
      REAuthorizationGroup,
      REGnrcRentalObjUsageCategory,
      cast( REGenericRentalObjectUsageType as regovdmusableobjusagetype preserving type ) as REGenericRentalObjectUsageType,
      REGenericRentalObjParentUUID,
      REGnrcRentalObjPortfolioID,
      REGnrcRentalObjOwnershipID,

      @Semantics.systemDateTime.createdAt: true
      CreationDateTime,
      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime,
      @Semantics.systemDateTime.localInstanceLastChangedAt: true
      LocalLastChangeDateTime,

      /* Associations */
      _REKeyAssgmt,
      _CompanyCode,
      _REAuthorizationGroup,
      _REGnrcRentalObjUsageCategory,
      _REGnrcRentalObjUsageType,
      _REGnrcRentalObjOwnership,
      _REGnrcRentalObjPortfolio,
      _REParentGenericRentalObject,
      _REGenericRentalObjectType,
      _REArchitectureObject,
      _StatusObject,
      _StatusObjectStatus,
      _REUsblObjToRntblObjAssgmt
}
where
     REGenericRentalObjectType = 'U' //Usable Object

  or REGenericRentalObjectType = 'I' //Intercompany

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_REGENERICRENTALOBJECT"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_REARCHITECTUREOBJECT",
"I_REAUTHORIZATIONGROUP",
"I_REGENERICRENTALOBJECT",
"I_REGENERICRENTALOBJECTTYPE",
"I_REGNRCRENTALOBJOWNERSHIP",
"I_REGNRCRENTALOBJPORTFOLIO",
"I_REGNRCRENTALOBJUSAGECATEGORY",
"I_REGNRCRENTALOBJUSAGETYPE",
"I_REKEYASSGMT",
"I_RERNTBLOBJTOUSBLOBJASSGMT",
"I_STATUSOBJECT",
"I_STATUSOBJECTSTATUS"
],
"BASE":
[
"I_REGENERICRENTALOBJECT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More