R_REIntegrationObjectTP

//@AbapCatalog.sqlViewName: 'RREINTEGOBJTP'

//@AbapCatalog.compiler.compareFilter: true

//@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK
//@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'IntegrationObject TP'

@ObjectModel.usageType: {
        serviceQuality: #C,
        dataClass: #TRANSACTIONAL,
        sizeCategory: #XL
    }

@VDM: {
    viewType: #TRANSACTIONAL,
    lifecycle.contract.type: #SAP_INTERNAL_API,
    usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
    }

@ObjectModel.semanticKey: ['REIntegrationObjectNumber' ]
@ObjectModel.representativeKey: 'InternalRealEstateNumber'
@ObjectModel.lifecycle.enqueue.expiryInterval: 'PT15M' //draft expiry 15 min for lock testing

@ObjectModel.sapObjectNodeType.name: 'RealEstateIntegrationObject'

define root view entity R_REIntegrationObjectTP
  as select from I_REIntegrationObject as _REIntegrationObject
  composition [0..*] of R_REIntegObjectAddressTP       as _REIntegObjectAddressTP
  composition [0..*] of R_REIntegObjectObjRelationTP   as _REIntegObjectObjRelationTP
  //  composition [0..*] of R_REIntegObjectObjRltnPrtlTP   as _REIntegObjectObjRltnPrtlTP

  composition [0..*] of R_REIntegObjectObjAssgmtTP     as _REIntegObjectObjAssgmtTP

  composition [0..*] of R_REUseEnableAddlObjAssgmtTP   as _REUseEnableAddlObjAssgmtTP
  composition [0..*] of R_REUseEnableLdngObjAssgmtTP   as _REUseEnableLdngObjAssgmtTP
  composition [0..*] of R_REUseEnableFxdAstObjAssgmtTP as _REUseEnableFxdAstObjAssgmtTP
  composition [0..*] of R_REUseEnableConditionTP       as _REUseEnableConditionTP
  composition [0..*] of R_REIntegObjContractAssgmtTP   as _REIntegObjContractAssgmtTP
  composition [0..*] of R_REOccpcyMngLdngObjAssgmtTP   as _REOccpcyMngLdngObjAssgmtTP

//  composition [0..*] of R_REIntegObjectAcctObjAssgmtTP as _REIntegObjectAcctObjAssgmtTP

  composition [0..*] of R_REIntegObjectPartAssgmtTP    as _REIntegObjectPartAssgmtTP
  composition [0..*] of R_REIntegObjectMeasurementTP   as _REIntegObjectMeasurementTP
  composition [0..*] of R_REIntegObjectReminderRuleTP  as _REIntegObjectReminderRuleTP
  composition [0..*] of R_REIntegObjectReminderDateTP  as _REIntegObjectReminderDateTP
  composition [0..*] of R_REIntegObjectTimelineTP      as _REIntegObjectTimelineTP
  composition [0..*] of R_REIntegObjectStatusObjectTP  as _REIntegObjectStatusObjectTP

  composition [0..*] of R_REOccpcyMngCostObjAssgmtTP   as _REOccpcyMngCostObjAssgmtTP

  //  Extensibility

  association [1..1] to E_REIntegrationObject          as _Extension                on $projection.InternalRealEstateNumber = _Extension.InternalRealEstateNumber

  //  New association

  association [0..1] to I_CompanyCode                  as _CompanyCodeEnableUse     on $projection.CompanyCodeEnableUse     = _CompanyCodeEnableUse.CompanyCode

{
  key       InternalRealEstateNumber,
            RealEstateExternalID,
            REStatusObject,
            REIntegrationObjectNumber,
            @ObjectModel.editableFieldFor: 'REIntegrationObjectNumber'
            REIntegrationObjectNumber as REIntegrationObjNumberForEdit,
            REIntegrationObjectType,
            REIntegObjectCtrlgObjectType,
            REIntegrationObjectName,
            REIntegObjectLongName,
            ValidityStartDate,
            ValidityEndDate,
            REIntegObjSpaceGroupType,
            RESpaceGroupUsageType,
            RESpaceGrpEnableUseType,
            REInternalNumberForUseEnable,
            _REUseEnableIntegrationObject.REIntegrationObjectNumber as REUseEnableObjectNumber,
            REParentIntegObjectType,
            REParentIntegObjectExternalID,
            _REParentIntegrationObject.REIntegrationObjectNumber as REParentIntegObjectNumber,
            REAreaUnit,
            @Semantics.user.createdBy: true
            CreatedByUser,
            CreationDate,
            CreationTime,
            //          Create Timestamp aggregation

            @Semantics.systemDateTime.createdAt: true
            cast (dats_tims_to_tstmp( CreationDate,
                                CreationTime,
                                abap_system_timezone( $session.client,'NULL' ), $session.client, 'NULL' ) as vdm_creationdatetime ) as CreationDateTime,
            RESourceOfCreation,
            @Semantics.user.lastChangedBy: true
            LastChangedByUser,
            LastChangeDate,
            LastChangeTime,
            //          LastChange Timestamp aggregation

            @Semantics.systemDateTime.lastChangedAt: true
            cast (dats_tims_to_tstmp( LastChangeDate,
                                LastChangeTime,
                                abap_system_timezone( $session.client,'NULL' ), $session.client, 'NULL' ) as vdm_lastchangedon ) as LastChangeDateTime,
            RESourceOfChange,
            Responsible,
            REAuthorizationGroup,
           
            CompanyCode,
            cast(coalesce(_REUseEnableIntegrationObject.CompanyCode, CompanyCode ) as bukrs preserving type )              as CompanyCodeEnableUse, 
//            cast(coalesce(_REUseEnableIntegrationObject.CompanyCode, CompanyCode ) as bukrs preserving type )              as PartnerCompanyCode,          

            
            _REIntegObjSpaceGroupType.RESpaceGroupDirection,
            _StatusObject.StatusProfile,

//            RealEstateObjectType,

            cast('J5' as recaobjtype preserving type ) as RealEstateObjectType,
            
            _CreatedByUser,
            _ChangedByUser,
            _ResponsibleUser,
            _UnitOfMeasureArea,
            _REAuthorizationGroup,
            _REIntegObjectType,
            _REIntegObjCtrlgObjType,
            _REParentIntegObjectType,
            _REIntegObjSpaceGroupType,
            _RESpaceGroupUsageType,
            _RESpaceGrpEnableUseType,
            _StatusObjectStatus,
            _REObjectAddress,
            _StatusObject,
            _REKeyAssgmt,
            _REParentIntegrationObject,
            _REUseEnableIntegrationObject,
            _CompanyCode,
            _CompanyCodeEnableUse,
            _REIntegObjectAddressTP,
            _REIntegObjectObjRelationTP,
            _REIntegObjectMeasurementTP,
            _REUseEnableAddlObjAssgmtTP,
            _REUseEnableLdngObjAssgmtTP,
            _REUseEnableFxdAstObjAssgmtTP,
            _REOccpcyMngLdngObjAssgmtTP,
            _REUseEnableConditionTP,
            _REIntegObjContractAssgmtTP,
            _REIntegObjectPartAssgmtTP,
            _REIntegObjectObjAssgmtTP,
            _REIntegObjectReminderRuleTP,
            _REIntegObjectReminderDateTP,
            _REIntegObjectTimelineTP,
            _REIntegObjectStatusObjectTP,
            _REOccpcyMngCostObjAssgmtTP, 
            _REIntegrationObjSubObj
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_REINTEGOBJSPACEGROUPTYPE",
"I_REINTEGRATIONOBJECT",
"I_REINTEGRATIONOBJECTBASICDATA",
"I_STATUSOBJECT"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_REAUTHORIZATIONGROUP",
"I_REINTEGOBJCTRLGOBJTYPE",
"I_REINTEGOBJECTTYPE",
"I_REINTEGOBJSPACEGROUPTYPE",
"I_REINTEGRATIONOBJECT",
"I_REINTEGRATIONOBJECTBASICDATA",
"I_REINTEGRATIONOBJECTSUBOBJ",
"I_REKEYASSGMT",
"I_REOBJECTADDRESS",
"I_RESPACEGROUPUSAGETYPE",
"I_RESPACEGRPENABLEUSETYPE",
"I_STATUSOBJECT",
"I_STATUSOBJECTSTATUS",
"I_UNITOFMEASURE",
"I_USER",
"R_REINTEGOBJCONTRACTASSGMTTP",
"R_REINTEGOBJECTADDRESSTP",
"R_REINTEGOBJECTMEASUREMENTTP",
"R_REINTEGOBJECTOBJASSGMTTP",
"R_REINTEGOBJECTOBJRELATIONTP",
"R_REINTEGOBJECTPARTASSGMTTP",
"R_REINTEGOBJECTREMINDERDATETP",
"R_REINTEGOBJECTREMINDERRULETP",
"R_REINTEGOBJECTSTATUSOBJECTTP",
"R_REINTEGOBJECTTIMELINETP",
"R_REOCCPCYMNGCOSTOBJASSGMTTP",
"R_REOCCPCYMNGLDNGOBJASSGMTTP",
"R_REUSEENABLEADDLOBJASSGMTTP",
"R_REUSEENABLECONDITIONTP",
"R_REUSEENABLEFXDASTOBJASSGMTTP",
"R_REUSEENABLELDNGOBJASSGMTTP"
],
"BASE":
[
"I_REINTEGRATIONOBJECT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/