R_REIntegObjectObjRelationTP

//@AbapCatalog.sqlViewName: 'RREINTEGOBJRELTP'

//@AbapCatalog.compiler.compareFilter: true

//@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]

@ObjectModel.representativeKey: 'REIntegObjectRelationUUID'
@ObjectModel.semanticKey: ['InternalRealEstateNumber', 'InternalRealEstateNumberRltn', 'ValidityEndDate'  ]
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@EndUserText.label: 'IntegrationObject Relation TP'
//@ClientHandling.algorithm: #SESSION_VARIABLE

define view entity R_REIntegObjectObjRelationTP
  as select from I_REIntegrationObjectRelation as _REIntegrationObjectRelation
  association        to parent R_REIntegrationObjectTP as _REIntegrationObjectTP        on  $projection.InternalRealEstateNumber = _REIntegrationObjectTP.InternalRealEstateNumber
  //  association [1..1] to I_REIntegObjectRelationAddl    as _REIntegObjectRelationAddl on $projection.REIntegObjectRelationUUID = _REIntegObjectRelationAddl.REIntegObjectRelationUUID

  association [1..1] to I_REEntryValidity              as _REEntryValidity              on  $projection.REEntryValidity = _REEntryValidity.REEntryValidity
  association [0..1] to I_REIntegObjectMeasurement     as _REOccpcyMngObjRelMsmtPartial on  $projection.InternalRealEstateNumberRltn        = _REOccpcyMngObjRelMsmtPartial.InternalRealEstateNumber
                                                                                        and $projection.REMeasurementType                   = _REOccpcyMngObjRelMsmtPartial.REMeasurementType
                                                                                        and $projection.REIsObjectRelationPartial           = 'X'
                                                                                        and _REOccpcyMngObjRelMsmtPartial.ValidityStartDate <= $projection.ValidityStartDate
                                                                                        and _REOccpcyMngObjRelMsmtPartial.ValidityEndDate   >= $projection.ValidityStartDate
{
  key  REIntegObjectRelationUUID,
  key  InternalRealEstateNumber,
       InternalRealEstateNumberRltn,
       _RERelatedIntegrationObject.REIntegrationObjectType,
       _RERelatedIntegrationObject.REIntegrationObjectNumber,
       ValidityEndDate,
       REMeasurementType,
       ValidityStartDate,
       REIsObjectRelationPartial,
       REMeasurementUnit,
       REMeasurementPartialQuantity,
//       REMeasurementTotalQuantity,


       _RERelatedIntegrationObject.REStatusObject,

       @ObjectModel.foreignKey.association: '_REEntryValidity'
       case
       //           when ValidityStartDate is initial then cast ('0' as recavdmentryvalidity)

           when ValidityStartDate is initial and ValidityEndDate is initial then cast ('3' as recavdmentryvalidity)
           when ValidityStartDate > $session.system_date then cast ('2' as recavdmentryvalidity)
           when ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date then cast('3' as recavdmentryvalidity)
           else cast ('1' as recavdmentryvalidity)
       end as REEntryValidity,

       case
       //           when ValidityStartDate is initial then 0

           when ValidityStartDate is initial and ValidityEndDate is initial then 3
           when ValidityStartDate > $session.system_date then 2
           when ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date then 3
       else 1
       end as REEntryValidityCriticality,

       _RERelatedIntegrationObject,
       _REMeasurementType,
       _UnitOfMeasure,

       _REIntegrationObjectTP,
       _REEntryValidity,
       _REOccpcyMngObjRelMsmtPartial,
       //       _REIntegObjectRelationAddl,

       _RERelatedIntegrationObject._StatusObject

}
where //_REIntegrationObjectTP.RealEstateObjectType = 'J5'

  InternalRealEstateNumber like 'J5%'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_REINTEGRATIONOBJECTBASICDATA",
"I_REINTEGRATIONOBJECTRELATION"
],
"ASSOCIATED":
[
"I_REENTRYVALIDITY",
"I_REINTEGOBJECTMEASUREMENT",
"I_REINTEGRATIONOBJECTBASICDATA",
"I_REMEASUREMENTTYPE",
"I_STATUSOBJECT",
"I_UNITOFMEASURE",
"R_REINTEGRATIONOBJECTTP"
],
"BASE":
[
"I_REINTEGRATIONOBJECTBASICDATA",
"I_REINTEGRATIONOBJECTRELATION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/