R_REIntegObjContractAssgmtTP

//@AbapCatalog.sqlViewName: 'RREINTEGCNASSTP'

//@AbapCatalog.compiler.compareFilter: true

//@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]

@ObjectModel.representativeKey: 'InternalRealEstateNumber'
@ObjectModel.semanticKey: [  'CompanyCode', 'RealEstateContract', 'ValidityStartDate'  ]
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@EndUserText.label: 'IntegrationObject Contract Assignment TP'
//@ClientHandling.algorithm: #SESSION_VARIABLE

define view entity R_REIntegObjContractAssgmtTP
  as select from I_REIntegObjToContractAssgmt as _REObjectAssgmt
  association        to parent R_REIntegrationObjectTP as _REIntegrationObjectTP  on  $projection.InternalRealEstateNumber  = _REIntegrationObjectTP.InternalRealEstateNumber
  association [1..1] to I_REContract                   as _REContract             on  $projection.CompanyCodeForEdit        = _REContract.CompanyCode
                                                                                  and $projection.RealEstateContractForEdit = _REContract.RealEstateContract
  association [1..1] to I_REEntryValidity              as _REEntryValidity           on $projection.REEntryValidity           = _REEntryValidity.REEntryValidity  
{
  key InternalRealEstateNumber,
  key REObjectAssignmentType,
  key CompanyCode,
  key RealEstateContract,
  key ValidityStartEndDateValue,
      REStatusObjectSource,
      CompanyCode                                                         as CompanyCodeForEdit,
      RealEstateContract                                                  as RealEstateContractForEdit,
      REStatusObjectTarget,
      @Semantics.businessDate.from: true
      cast( coalesce(ValidityStartDate, '00000000') as rebdvdmvalidfrom ) as ValidityStartDate,
      @Semantics.businessDate.to: true
      cast( coalesce(ValidityEndDate, '99991231') as rebdvdmvalidto )     as ValidityEndDate,
      REOnlyInfoAssgmt,
      REStatusObjectSourceIsArchived,
      REObjectPossessionStartDate,
      REObjectPossessionEndDate,

       @ObjectModel.foreignKey.association: '_REEntryValidity'
       case
       //           when ValidityStartDate is initial then cast ('0' as recavdmentryvalidity)

           when ValidityStartDate is initial and ValidityEndDate is initial then cast ('3' as recavdmentryvalidity)
           when ValidityStartDate > $session.system_date then cast ('2' as recavdmentryvalidity)
           when ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date then cast('3' as recavdmentryvalidity)
           else cast ('1' as recavdmentryvalidity)
       end                                                                 as REEntryValidity,

       case
       //           when ValidityStartDate is initial then 0

           when ValidityStartDate is initial and ValidityEndDate is initial then 3
           when ValidityStartDate > $session.system_date then 2
           when ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date then 3
       else 1
       end                                                                 as REEntryValidityCriticality,

      _REObjectAssignmentType,
      _REEntryValidity,

      _REIntegrationObjectTP,

      _REContract,
      _CompanyCode

}

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_REINTEGOBJTOCONTRACTASSGMT"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_RECONTRACT",
"I_REENTRYVALIDITY",
"I_REOBJECTASSIGNMENTTYPE",
"R_REINTEGRATIONOBJECTTP"
],
"BASE":
[
"I_REINTEGOBJTOCONTRACTASSGMT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/