R_QltyNotificationItemCauseTP

@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Quality Notification Item Cause'

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}

@ObjectModel: {
  usageType: {
    serviceQuality: #C,
    sizeCategory: #L,
    dataClass: #TRANSACTIONAL
  },
  representativeKey: 'NotificationCauseID'
}

@Metadata.ignorePropagatedAnnotations: true

define view entity R_QltyNotificationItemCauseTP
  as select from I_QltyNotificationCause

    association [1..1] to  R_QltyNotificationTP        as _QltyNotification        on  $projection.QualityNotification = _QltyNotification.QualityNotification
    association to parent  R_QualityNotificationItemTP as _QualityNotificationItem on  $projection.QualityNotification = _QualityNotificationItem.QualityNotification
                                                                                   and $projection.NotificationItem    = _QualityNotificationItem.NotificationItem

  //Extension

  association [1..1] to E_NotificationCause as _Extension on  $projection.QualityNotification = _Extension.Notification
                                                          and $projection.NotificationItem    = _Extension.NotificationItem
                                                          and $projection.NotificationCauseID = _Extension.NotificationCauseID 

    // Compositions to child nodes

    

{
      @ObjectModel.foreignKey.association: '_QltyNotification'
  key I_QltyNotificationCause.QualityNotification,
      @ObjectModel.foreignKey.association: '_QualityNotificationItem'
  key I_QltyNotificationCause.NotificationItem,
  key I_QltyNotificationCause.NotificationCauseID,
  
      I_QltyNotificationCause.NotificationCauseSortNumber,
      I_QltyNotificationCause.MasterLanguage,

      @Semantics.text: true
      I_QltyNotificationCause.NotificationCauseText,
      
      // Codes

      I_QltyNotificationCause.NotificationCauseCodeCatalog,
      I_QltyNotificationCause.NotificationCauseCodeGroup,
      I_QltyNotificationCause.NotificationCauseCode,
      
      I_QltyNotificationCause.NotificationRootCause,
      
      @Semantics.booleanIndicator: true
      I_QltyNotificationCause.IsDeleted,

      @Semantics.booleanIndicator: true
      I_QltyNotificationCause.IsBusinessPurposeCompleted, // used in the DCL

      
//      I_QltyNotificationCause.ChangedDateTime,

      
      // Admin Data

      @Semantics.user.createdBy: true
      I_QltyNotificationCause.CreatedByUser,
      @Semantics.systemDate.createdAt: true
      I_QltyNotificationCause.CreationDate,
      @Semantics.time: true
      I_QltyNotificationCause.CreationTime,
      @Semantics.user.lastChangedBy: true
      I_QltyNotificationCause.LastChangedByUser,
      @Semantics.systemDate.lastChangedAt: true
      I_QltyNotificationCause.LastChangeDate,
      @Semantics.time: true
      I_QltyNotificationCause.LastChangeTime,
      
      // Associations

      _QltyNotification,
      _QualityNotificationItem,

        // For auth check mapping role

      I_QltyNotificationCause._Notification
// //      I_QltyNotificationCause._NotificationItem


}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_QLTYNOTIFICATIONCAUSE"
],
"ASSOCIATED":
[
"I_QLTYNOTIFICATION",
"R_QLTYNOTIFICATIONTP",
"R_QUALITYNOTIFICATIONITEMTP"
],
"BASE":
[
"I_QLTYNOTIFICATIONCAUSE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/