I_QLTYNOTIFICATIONCAUSE

CDS View

Quality Notification Item Cause

I_QLTYNOTIFICATIONCAUSE is a CDS View in S/4HANA. Quality Notification Item Cause. It contains 19 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 19 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
R_QltyNotificationItemCauseTP view_entity from TRANSACTIONAL Quality Notification Item Cause

Fields (19)

KeyField CDS FieldsUsed in Views
KEY NotificationCauseID NotificationCauseID 1
KEY NotificationItem NotificationItem 1
KEY QualityNotification QualityNotification 1
_Notification _Notification 1
CreatedByUser CreatedByUser 1
CreationDate CreationDate 1
CreationTime CreationTime 1
IsBusinessPurposeCompleted IsBusinessPurposeCompleted 1
IsDeleted IsDeleted 1
LastChangeDate LastChangeDate 1
LastChangedByUser LastChangedByUser 1
LastChangeTime LastChangeTime 1
MasterLanguage MasterLanguage 1
NotificationCauseCode NotificationCauseCode 1
NotificationCauseCodeCatalog NotificationCauseCodeCatalog 1
NotificationCauseCodeGroup NotificationCauseCodeGroup 1
NotificationCauseSortNumber NotificationCauseSortNumber 1
NotificationCauseText NotificationCauseText 1
NotificationRootCause NotificationRootCause 1 
@AbapCatalog.sqlViewName: 'IQLTYNTFCAU'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Quality Notification Item Cause'

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations:  [ '_CreatedByUserContactCard','_LastChangedByUserContactCard' ]

@VDM: {
    viewType: #COMPOSITE,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel.supportedCapabilities: 
    [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
@ObjectModel.modelingPattern: #NONE
@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #L,
        serviceQuality: #C },
    representativeKey: 'NotificationCauseID'
}
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true

define view I_QltyNotificationCause as select from I_NotificationCause 

  inner join   I_QltyNotification // inner join ensures that only items of quality notifications are selected

    on I_QltyNotification.QualityNotification = I_NotificationCause.Notification 
    
  // Define own association for parent and root in the QM layer

  association [1] to I_QltyNotification          as _QltyNotification         on  $projection.QualityNotification = _QltyNotification.QualityNotification
  association [1] to I_QualityNotificationItem   as _QualityNotificationItem  on  $projection.QualityNotification = _QualityNotificationItem.QualityNotification
                                                                              and $projection.NotificationItem    = _QualityNotificationItem.NotificationItem
                         
  association [1..1] to I_QltyNotification as _Notification on $projection.QualityNotification = _Notification.QualityNotification
  association [1..1] to I_QualityNotificationItem as _NotificationItem on $projection.QualityNotification = _NotificationItem.QualityNotification and 
                                                                          $projection.NotificationItem = _NotificationItem.NotificationItem     

  //Extension

  association [1..1] to E_NotificationCause as _Extension on  $projection.QualityNotification = _Extension.Notification
                                                          and $projection.NotificationItem    = _Extension.NotificationItem
                                                          and $projection.NotificationCauseID = _Extension.NotificationCauseID 

{

  @ObjectModel.foreignKey.association: '_Notification'
  key I_NotificationCause.Notification as QualityNotification,
  @ObjectModel.foreignKey.association: '_NotificationItem'
  key I_NotificationCause.NotificationItem,
  key I_NotificationCause.NotificationCauseID,
  I_NotificationCause.NotificationCauseSortNumber,
  I_NotificationCause.CreatedByUser,
  I_NotificationCause.CreationDate,
  I_NotificationCause.CreationTime,
  I_NotificationCause.LastChangedByUser,
  I_NotificationCause.LastChangeDate,
  I_NotificationCause.LastChangeTime,
  I_NotificationCause.NotificationCauseText,
  cast( I_NotificationCause.NotificationCauseCodeCatalog as vdm_qurkat preserving type ) as NotificationCauseCodeCatalog,
  cast( I_NotificationCause.NotificationCauseCodeGroup as vdm_qurgrp preserving type ) as NotificationCauseCodeGroup,
  I_NotificationCause.NotificationCauseCode,
  I_NotificationCause.ChangedDateTime,
  I_NotificationCause.MasterLanguage,
  I_NotificationCause.NotificationRootCause,
  
  @Semantics.booleanIndicator 
  cast( I_NotificationCause.IsDeleted as vdm_qisdeleted preserving type ) as IsDeleted,
  @Semantics.booleanIndicator 
  I_NotificationCause.IsBusinessPurposeCompleted,
  
  /* Associations */
  _QltyNotification,
  @VDM.lifecycle: { status: #DEPRECATED, successor: '_QltyNotification' }
  _Notification,
  _QualityNotificationItem,
  @VDM.lifecycle: { status: #DEPRECATED, successor: '_QualityNotificationItem' }
  _NotificationItem,
  I_NotificationCause._CreatedByUserContactCard,
  I_NotificationCause._LastChangedByUserContactCard,
  I_NotificationCause._NotifCauseCodeCatalog,
  I_NotificationCause._NotifCauseCodeGroup,
  I_NotificationCause._NotifCauseCode,
  I_NotificationCause._NotificationRootCause
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_NOTIFICATIONCAUSE",
"I_QLTYNOTIFICATION"
],
"ASSOCIATED":
[
"E_NOTIFICATIONCAUSE",
"I_NOTIFCAUSECODE",
"I_NOTIFCAUSECODECATALOG",
"I_NOTIFCAUSECODEGROUP",
"I_NOTIFICATIONROOTCAUSE",
"I_QLTYNOTIFICATION",
"I_QUALITYNOTIFICATIONITEM",
"I_USERCONTACTCARD"
],
"BASE":
[
"I_NOTIFICATIONCAUSE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More