R_PPS_PurContrVersionHistory

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl:{ authorizationCheck:#MANDATORY, personalData.blocking: #BLOCKED_DATA_EXCLUDED }
@EndUserText.label: 'Purchase Contract Version History'
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@VDM.viewType : #COMPOSITE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #MIXED
  }

@ObjectModel.createEnabled: false
@ObjectModel.deleteEnabled: false
@ObjectModel.updateEnabled: false


define view entity R_PPS_PurContrVersionHistory

  as select from I_PPS_PurgDocVersionHistory as VersionHistory
    inner join   R_PurchaseContract          as Document on  VersionHistory.ActivePurchasingDocument  = Document.ActivePurchasingDocument
                                                         and VersionHistory.PurchasingDocumentVersion = Document.PurchasingDocumentVersion
                                                         and (
                                                            Document.PurgDocChangeRequestStatus       = '1'
                                                            or Document.PurgDocChangeRequestStatus    = '2'
                                                            or Document.PurgDocChangeRequestStatus    = '4'
                                                            or Document.PurgDocChangeRequestStatus    = ''
                                                          )


  association [1..1] to I_User                        as _UserDetails                   on  $projection.CreatedByUser = _UserDetails.UserID
  association [1..1] to I_PurContrVersionType         as _VersionType                   on  $projection.PurgDocChangeRequestStatus = _VersionType.PurgDocChangeRequestStatus
  association [0..1] to I_PaymentTermsText            as _PaymentTermsText              on  $projection.PaymentTerms   = _PaymentTermsText.PaymentTerms
                                                                                        and _PaymentTermsText.Language = $session.system_language
  association [0..1] to I_PurchasingGroup             as _PurchasingGroup               on  _PurchasingGroup.PurchasingGroup = $projection.PurchasingGroup
  association [1..1] to I_CurrencyText                as _DocumentCurrencyText          on  _DocumentCurrencyText.Language = $session.system_language
                                                                                        and _DocumentCurrencyText.Currency = $projection.DocumentCurrency
  association [0..1] to I_IncotermsClassificationText as _IncotermsClassificationText   on  _IncotermsClassificationText.IncotermsClassification     = $projection.IncotermsClassification
                                                                                        and _IncotermsClassificationText.IncotermsClassificationName = $session.system_language
  association [0..1] to I_PurchasingOrganization      as _PurchasingOrganization        on  _PurchasingOrganization.PurchasingOrganization = $projection.PurchasingOrganization
  association [0..1] to I_IncotermsClassification     as _IncotermsClassification       on  _IncotermsClassification.IncotermsClassification = $projection.IncotermsClassification
  association [0..1] to I_Supplier                    as _InvoicingParty                on  $projection.InvoicingParty = _InvoicingParty.Supplier
  association [1..*] to R_PPS_PurchaseContractItemTP  as _PurchaseContractItem          on  $projection.PurchaseContract = Document.ActivePurchasingDocument
  association [1..*] to R_PPS_PurContractContactTP    as _PurchaseContractContact       on  $projection.PurchaseContract = Document.ActivePurchasingDocument
  association [1..*] to R_PPS_PurContrHdrCndnValdtyTP as _PurchaseContractHeaderPricing on  $projection.PurchaseContract = Document.ActivePurchasingDocument
  association [0..*] to R_PPS_PurContractPartnerTP    as _PurContrPartner               on  $projection.PurchaseContract = Document.ActivePurchasingDocument
  association [1..1] to R_PPS_PurContractHdrExtension as _PurchaseContractHdrExtension  on  $projection.PurchaseContract = _PurchaseContractHdrExtension.PurchaseContract
  association [0..1] to I_PPS_PurgDocModifTypeText    as _ModificationTypeText          on  $projection.PPSModificationType = _ModificationTypeText.PPSModificationType
                                                                                        and _ModificationTypeText.Language  = $session.system_language

  association [0..1] to I_CompanyCode                 as _CompanyCode                   on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1..1] to I_PPS_PurgDocHdrStatusText    as _PurContrStatusText            on  $projection.ppspurcontrheaderstatus = _PurContrStatusText.PurchasingDocumentStatus
                                                                                        and _PurContrStatusText.Language        = $session.system_language
  association [1..1] to I_PurContrCnsmpnInPercentage  as _PurContrCnsmpnInPercentage    on  Document.ActivePurchasingDocument = _PurContrCnsmpnInPercentage.PurchaseContract
{
  key Document.PurchaseContract,
      Document.PurchaseContractType,
      Document.PurchasingDocumentCategory,
      Document.Supplier,
      Document.CompanyCode,
      Document.PurchasingOrganization,
      Document.PurchasingGroup,

      Document.DocumentCurrency,
      Document.IncotermsClassification,
      Document.IncotermsTransferLocation,
      Document.PaymentTerms,
      Document.CashDiscount1Days,
      Document.CashDiscount2Days,
      Document.NetPaymentDays,
      Document.CashDiscount1Percent,
      Document.CashDiscount2Percent,
      @Semantics.amount.currencyCode:'DocumentCurrency'
      Document.PurchaseContractTargetAmount,
      Document.ValidityStartDate,
      Document.ValidityEndDate,
      Document.ReleaseCode,
      Document.PurchasingDocumentDeletionCode,
      cast( _PurContrCnsmpnInPercentage.ContractConsumptionInPct as abap.dec(18,3) ) as PurContractConsumptionInPct,
      cast( _PurContrCnsmpnInPercentage.ContractConsumptionInPct as abap.dec(18,3))  as ContractConsumptionInPct,
      cast( '%' as abap.unit( 3 ) )                                                  as PurContrConsumptionUnit,
      cast ('' as boolean)                                                           as PurContrHasAdvncdUsrInterface,
      case Document.ManualSupplierAddressID
        when '' then  Document._Supplier.AddressID
        else Document.ManualSupplierAddressID
      end                                                                            as SupplierAddressID,
      Document.SupplyingSupplier,
      Document.InvoicingParty,
      cast( Document.ExchangeRate as fis_exchange_rate preserving type )             as ExchangeRate,
      //Document.ExchangeRate ,

      Document.ExchangeRateIsFixed,
      Document.QuotationSubmissionDate,
      Document.SupplierQuotation,
      Document.ReleaseIsNotCompleted,
      Document.CorrespncExternalReference,
      Document.CorrespncInternalReference,
      Document.SupplierRespSalesPersonName,
      Document.SupplierPhoneNumber,
      Document.IncotermsVersion,
      Document.IncotermsLocation1,
      Document.IncotermsLocation2,
      Document.PurchasingDocumentName,
      Document.LastChangeDateTime,
      Document.PurchasingProcessingStatus,
      @Semantics.booleanIndicator: true
      Document.IsEndOfPurposeBlocked,
      Document.ActivePurchasingDocument,
      Document.PurgDocChangeRequestStatus,
      Document.PurchasingDocumentVersion,
      Document.PurgDocIsChgVers,
      Document.PurgAggrgdProdCmplncSuplrSts,
      //Document.PurgDocClassfctnCode,

      VersionHistory.CreatedByUser                                                   as CreatedByUser,
      VersionHistory.CreationDate                                                    as CreationDate,
      VersionHistory.CreationTime                                                    as CreationTime,
      VersionHistory.PurchasingDocVersionReasonCode                                  as PurchasingDocVersionReasonCode,
      VersionHistory.PurchasingDocVersionStatus                                      as PurchasingDocVersionStatus,

      Document.IncotermsSupChnLoc1AddlUUID,
      Document.IncotermsSupChnLoc2AddlUUID,
      Document.IncotermsSupChnDvtgLocAddlUUID,
      Document.PurchasingDocumentOrigin,
      Document._CreatedByUser.UserDescription                                        as CreatedByUserName,
      Document.PurgHasCatalogRelevantItems,
      _PurchaseContractHdrExtension.PPSSmartNumberHeader                                as PPSSmartNumberHeader ,
      _PurchaseContractHdrExtension.PPSModificationType                              as PPSModificationType,
      _PurchaseContractHdrExtension.PPSPurContrHeaderStatus, //@JIRA_KEY: <S4PPS-14333>

      _PurchaseContractHdrExtension.PPSSmartDocumentNumber,

      case  _PurchaseContractHdrExtension.PPSPurContrHeaderStatus //@JIRA_KEY: <S4PPS-14333>

      when '02' then 3 // Active - Green

      when '03' then 1 // Deleted - Red

      when '04' then 1 // Rejected - Red

      when '05' then 2 // Awaiting Approval - Yellow

      else  null
      end                                                                            as ProcessingStatusCriticality,



      //_PurchasingDocumentTypeText,

      _PaymentTermsText,

      //_PurContrStatusText,

      _UserDetails,
      _VersionType,
      _PurchasingGroup,
      Document._DocumentCurrency,
      _DocumentCurrencyText,
      _IncotermsClassificationText,
      _IncotermsClassification,
      _PurchasingOrganization,
      _InvoicingParty,
      _PurchaseContractHdrExtension,
      _PurchaseContractItem,
      _PurchaseContractHeaderPricing,
      _PurContrPartner,

      _PurchaseContractContact,
      _ModificationTypeText,
      _CompanyCode,
      _PurContrStatusText

}
where
  (
       Document.PurgDocChangeRequestStatus       = '1'
    or Document.PurgDocChangeRequestStatus       = '2'
    or Document.PurgDocChangeRequestStatus       = '4'
    or Document.PurgDocChangeRequestStatus       = ''
  )
  and  VersionHistory.PurchasingDocumentCategory = 'K';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PPS_PURGDOCVERSIONHISTORY",
"I_PURCONTRCNSMPNINPERCENTAGE",
"I_SUPPLIER",
"I_USER",
"R_PPS_PURCONTRACTHDREXTENSION",
"R_PURCHASECONTRACT"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CURRENCY",
"I_CURRENCYTEXT",
"I_INCOTERMSCLASSIFICATION",
"I_INCOTERMSCLASSIFICATIONTEXT",
"I_PAYMENTTERMSTEXT",
"I_PPS_PURGDOCHDRSTATUSTEXT",
"I_PPS_PURGDOCMODIFTYPETEXT",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_PURCONTRVERSIONTYPE",
"I_SUPPLIER",
"I_USER",
"R_PPS_PURCHASECONTRACTITEMTP",
"R_PPS_PURCONTRACTCONTACTTP",
"R_PPS_PURCONTRACTHDREXTENSION",
"R_PPS_PURCONTRACTPARTNERTP",
"R_PPS_PURCONTRHDRCNDNVALDTYTP"
],
"BASE":
[
"R_PURCHASECONTRACT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/