R_MaintenanceTaskListBasicTP

//@AbapCatalog.sqlViewName: 'RMAINTTLBASICTP'

//@AbapCatalog.compiler.compareFilter: true

//@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK
@Metadata.ignorePropagatedAnnotations: true
//@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM: { viewType: #TRANSACTIONAL, lifecycle.contract.type: #SAP_INTERNAL_API }
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED}
@EndUserText.label: 'TP View for Tasklist Header Details'

define view entity R_MaintenanceTaskListBasicTP
  as select from I_MaintenanceTaskList
  association [0..1] to R_TaskListLongTextTP           as _LongText     on  $projection.TaskListType           = _LongText.TaskListType
                                                                        and $projection.TaskListGroup          = _LongText.TaskListGroup
                                                                        and $projection.TaskListGroupCounter   = _LongText.TaskListGroupCounter
                                                                        and $projection.TaskListVersionCounter = _LongText.TaskListVersionCounter
  association [0..*] to R_MaintTskListStrgyPackageTP   as _MaintPackage on  $projection.TaskListType         = _MaintPackage.TaskListType
                                                                        and $projection.TaskListGroup        = _MaintPackage.TaskListGroup
                                                                        and $projection.TaskListGroupCounter = _MaintPackage.TaskListGroupCounter
  association [0..*] to R_MaintTaskListOpBasicTP       as _Operation    on  $projection.TaskListType         =  _Operation.TaskListType
                                                                        and $projection.TaskListGroup        =  _Operation.TaskListGroup
                                                                        and $projection.TaskListGroupCounter =  _Operation.TaskListGroupCounter
                                                                        and $projection.ValidityEndDate      >= _Operation.ValidityStartDate
                                                                        and $projection.ValidityStartDate    <= _Operation.ValidityEndDate
  association        to parent R_MaintenanceTaskListTP as _Header       on  $projection.TaskListGroup        = _Header.TaskListGroup
                                                                        and $projection.TaskListType         = _Header.TaskListType
                                                                        and $projection.TaskListGroupCounter = _Header.TaskListGroupCounter
                                                                        
  association [0..1] to I_Equipment            as _Equipment            on  $projection.Equipment            = _Equipment.Equipment 
  association [0..1] to I_FunctionalLocation   as _FunctionalLocation   on  $projection.FunctionalLocation   = _FunctionalLocation.FunctionalLocation 
  association [0..1] to I_EquipmentTimeSeg     as _Equipmentts          on  $projection.Equipment            = _Equipmentts.Equipment  
                                                                        and _Equipmentts.ValidityEndDate     = '99991231'
                                                                        and _Equipmentts.EquipUsagePeriodSequenceNumber = '001' -- HasEquipmentData = 'X'
{
  key TaskListType,
  key TaskListGroup,
  key TaskListGroupCounter,
  key TaskListVersionCounter,

      MaintenancePlanningPlant,
      TaskListStatus,
      TechnicalObject,
      TaskListObjectKey,
      TechObjIsEquipOrFuncnlLoc,
      TaskListUsage,
      TaskListDesc,
      _WorkCenter.WorkCenter                                                                  as WorkCenter,
      WorkCenterTypeCode,
      WorkCenterInternalID,
      MaintenanceStrategy,
      OperationSystemCondition,
      Assembly,
      ChangeNumber,
      SafetyRelevantObject,
      ValidityStartDate,
      ValidityEndDate,
      IsMarkedForDeletion,
      LastChangeDate,
      LastChangedByUser,
      CreatedByUser,
      CreationDate,

      Plant,
      ResponsiblePlannerGroup,
      ReferenceElement,
      InspSubsetFieldCombination,
      InspExternalNumberingOfValues,
      IsDeleted,
      Equipment,
      FunctionalLocation,
      FunctionalLocationLabelName,

      BillOfOperationsUsage,
      TaskListIsHierarchical,
      _TaskListStatus._Text[1:Language = $session.system_language].BillOfOperationsStatusDesc as TaskListStatusDesc,
      
      case TechObjIsEquipOrFuncnlLoc
        when 'EAMS_EQUI' then _Equipment.AuthorizationGroup
        else _FunctionalLocation.AuthorizationGroup
      end as AuthorizationGroup,
      
      case TechObjIsEquipOrFuncnlLoc
        when 'EAMS_EQUI' then _Equipmentts._LocationAccountAssignment.ControllingArea  
        else _FunctionalLocation._LocationAccountAssignment.ControllingArea  
      end as ControllingArea,
      
      case TechObjIsEquipOrFuncnlLoc
        when 'EAMS_EQUI' then _Equipmentts.MaintenancePlannerGroup 
        else _FunctionalLocation.MaintenancePlannerGroup 
      end as MaintenancePlannerGroup,
      
       case TechObjIsEquipOrFuncnlLoc
        when 'EAMS_EQUI' then _Equipmentts._LocationAccountAssignment.CostCenter
        else _FunctionalLocation._LocationAccountAssignment.CostCenter  
      end as CostCenter,
      
       case TechObjIsEquipOrFuncnlLoc
        when 'EAMS_EQUI' then _Equipmentts._LocationAccountAssignment.MaintenancePlant  
        else _FunctionalLocation._LocationAccountAssignment.MaintenancePlant  
      end as MaintenancePlant,
      
      /* Associations */
      _TechnicalObject,
      _Header,
      _Operation,
      _LongText,
      _MaintPackage

}
where
  IsDeleted <> 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONSSTATUS",
"I_BILLOFOPERATIONSSTATUSTEXT",
"I_EQUIPMENT",
"I_EQUIPMENTTIMESEG",
"I_FUNCTIONALLOCATION",
"I_LOCATIONACCOUNTASSIGNMENT",
"I_MAINTENANCETASKLIST",
"I_WORKCENTER"
],
"ASSOCIATED":
[
"I_TECHNICALOBJECT",
"R_MAINTENANCETASKLISTTP",
"R_MAINTTASKLISTOPBASICTP",
"R_MAINTTSKLISTSTRGYPACKAGETP",
"R_TASKLISTLONGTEXTTP"
],
"BASE":
[
"I_MAINTENANCETASKLIST"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/