I_EquipmentTimeSeg

@EndUserText.label: 'Equipment Time Segment'
@Analytics: { dataCategory: #DIMENSION }
@AbapCatalog:{ sqlViewName: 'IEQUITIMESEGM', compiler.compareFilter: true, preserveKey }
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck:#CHECK
@AccessControl.privilegedAssociations:['_LocationAccountAssignment']
@ObjectModel.representativeKey: 'EquipUsagePeriodSequenceNumber'

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions: true
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET]

define view I_EquipmentTimeSeg
  as select from equz // EQUZ = Equipment time segment

  association [0..1] to I_LocationAccountAssignment as _LocationAccountAssignment  on  _LocationAccountAssignment.MaintObjectLocAcctAssgmtNmbr = $projection.MaintObjectLocAcctAssgmtNmbr // ILOA = PM Object Location and Account Assignment

  association [0..1] to I_WorkCenterType            as _WorkCenterType             on  $projection.WorkCenterTypeCode = _WorkCenterType.WorkCenterTypeCode
  association [0..1] to I_WorkCenter                as _WorkCenter                 on  _WorkCenter.WorkCenterInternalID = $projection.WorkCenterInternalID
                                                                                   and _WorkCenter.WorkCenterTypeCode   = $projection.WorkCenterTypeCode // CRHD = Work Center Header

  association [0..*] to I_EquipmentText             as _SuperordinateEquipmentText on  _SuperordinateEquipmentText.Equipment = $projection.SuperordinateEquipment
  association [0..1] to I_TechnicalReport           as _EquipmentCodeCatalog       on  $projection.CatalogProfile = _EquipmentCodeCatalog.CatalogProfile

  association [0..1] to I_Equipment                 as _Equipment                  on  $projection.Equipment = _Equipment.Equipment
  association [0..1] to I_Product                   as _ConstructionMaterial       on  $projection.ConstructionMaterial = _ConstructionMaterial.Product
  association [0..1] to I_MaintenancePlanPlant      as _MaintenancePlanningPlant   on  $projection.MaintenancePlanningPlant = _MaintenancePlanningPlant.MaintenancePlanningPlant
{
      @ObjectModel.foreignKey.association: '_Equipment'
  key equz.equnr              as Equipment,

      @Semantics.businessDate.to: true
  key equz.datbi              as ValidityEndDate,

  key equz.eqlfn              as EquipUsagePeriodSequenceNumber,

      equz.timbi              as ValidityEndTime,
      equz.equzn              as NextEquipUsagePeriodSqncNmbr,

      @ObjectModel.foreignKey.association: '_LocationAccountAssignment'
      equz.iloan              as MaintObjectLocAcctAssgmtNmbr,

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_WorkCenterStdVH',
                     element: 'WorkCenterInternalID' },
          additionalBinding: [{ localElement: 'WorkCenterTypeCode',
                                element: 'WorkCenterTypeCode' }]
        }]
      @ObjectModel.foreignKey.association: '_WorkCenter'
      equz.gewrk              as WorkCenterInternalID,

      @ObjectModel.foreignKey.association: '_WorkCenterType'
      equz.pm_objty           as WorkCenterTypeCode,


      equz.ingrp              as MaintenancePlannerGroup,
      equz.rbnr               as CatalogProfile,
      @ObjectModel.foreignKey.association: '_MaintenancePlanningPlant'
      equz.iwerk              as MaintenancePlanningPlant,
      equz.hequi              as SuperordinateEquipment,
      equz.heqnr              as EquipInstallationPositionNmbr,
      equz.tidnr              as TechnicalObjectSortCode,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_ProductStdVH',
                     element: 'Product' }
        }]
      @ObjectModel.foreignKey.association: '_ConstructionMaterial'
      equz.submt              as ConstructionMaterial,


      @Semantics.businessDate.from: true
      equz.datab              as ValidityStartDate,
      @Semantics.systemDate.lastChangedAt: true
      equz.aedat              as LastChangeDate,

      equz.mapar              as ManufacturerPartNmbr,

      @Semantics.systemDateTime.lastChangedAt: true
      equz.segchangeddatetime as LastChangeDateTime,

      //Propagate associations

      _LocationAccountAssignment,
      _WorkCenterType,
      _WorkCenter,
      _SuperordinateEquipmentText,
      _EquipmentCodeCatalog,
      _Equipment,
      _ConstructionMaterial,
      _MaintenancePlanningPlant
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"EQUZ"
],
"ASSOCIATED":
[
"I_EQUIPMENT",
"I_EQUIPMENTTEXT",
"I_LOCATIONACCOUNTASSIGNMENT",
"I_MAINTENANCEPLANPLANT",
"I_PRODUCT",
"I_TECHNICALREPORT",
"I_WORKCENTER",
"I_WORKCENTERTYPE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/