R_MaintTaskListOpBasicTP

@AbapCatalog : { dataMaintenance:#RESTRICTED }
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Tasklist Operations'
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@VDM: { viewType: #TRANSACTIONAL, lifecycle.contract.type: #SAP_INTERNAL_API }
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED}

define view entity R_MaintTaskListOpBasicTP
  as select distinct from I_BillOfOperationsOpBasic     as plpo
    inner join            I_BOOSqncOperationAssgmtChgSt as plas on  plpo.BillOfOperationsType             = plas.BillOfOperationsType
                                                                and plpo.BillOfOperationsGroup            = plas.BillOfOperationsGroup
                                                                and (
                                                                   (   // Operation

                                                                     plpo.BOOOperationInternalID          = plas.BOOOperationInternalID
                                                                     and plpo.SuperiorOperationInternalID = '00000000'
                                                                   )
                                                                   or( // Sub-Operation

                                                                     plpo.SuperiorOperationInternalID     = plas.BOOOperationInternalID
                                                                   )
                                                                 )

  association        to parent R_MaintTaskListOperationTP as _NonHistOp            on  $projection.TaskListType                = _NonHistOp.TaskListType
                                                                                   and $projection.TaskListGroup               = _NonHistOp.TaskListGroup
                                                                                   and $projection.TaskListGroupCounter        = _NonHistOp.TaskListGroupCounter
                                                                                   and $projection.TaskListSequence            = _NonHistOp.TaskListSequence
                                                                                   and $projection.TaskListOperationInternalId = _NonHistOp.TaskListOperationInternalId
  association [1..1] to I_MaintenanceTaskList             as _MaintenanceTaskList  on  _MaintenanceTaskList.TaskListType         = $projection.TaskListType
                                                                                   and _MaintenanceTaskList.TaskListGroup        = $projection.TaskListGroup
                                                                                   and _MaintenanceTaskList.TaskListGroupCounter = $projection.TaskListGroupCounter
  association [0..*] to R_MaintTaskListSubOpTP            as _SubOp                on  $projection.TaskListType                 = _SubOp.TaskListType
                                                                                   and $projection.TaskListGroup                = _SubOp.TaskListGroup
                                                                                   and $projection.TaskListGroupCounter         = _SubOp.TaskListGroupCounter
                                                                                   and $projection.MaintenanceTaskListOperation = _SubOp.MaintenanceTaskListOperation
  association [0..*] to R_MaintTaskListOpMaterialTP       as _OpMaterial           on  $projection.TaskListType                   = _OpMaterial.TaskListType
                                                                                   and $projection.TaskListGroup                  = _OpMaterial.TaskListGroup
                                                                                   and $projection.TaskListGroupCounter           = _OpMaterial.TaskListGroupCounter
                                                                                   and $projection.TaskListSequence               = _OpMaterial.TaskListSequence
                                                                                   and $projection.TaskListOperationInternalId    = _OpMaterial.TaskListOperationInternalId
  association [0..*] to R_MaintTaskListOpRelshpTP         as _OpRelation           on  $projection.TaskListType                = _OpRelation.TaskListType
                                                                                   and $projection.TaskListGroup               = _OpRelation.TaskListGroup
                                                                                   and $projection.TaskListGroupCounter        = _OpRelation.TaskListGroupCounter
                                                                                   and $projection.TaskListOperationInternalId = _OpRelation.SuccssrBOOOpInternalID
//                                                                                     and $projection.TaskListOperationInternalId = _OpRelation.TaskListOperationInternalId

                                                                                   and $projection.TaskListSequence            = _OpRelation.TaskListSequence
//                                                                                   and $projection.TaskListOpBOMItmIntVersCounter = _OpRelation.TaskListOpBOMItmIntVersCounter

  association [0..1] to I_MaintTaskListOpTechObj          as _MaintTaskListTechObj on  $projection.TaskListType                   = _MaintTaskListTechObj.TaskListType
                                                                                   and $projection.TaskListGroup                  = _MaintTaskListTechObj.TaskListGroup
                                                                                   and $projection.TaskListGroupCounter           = _MaintTaskListTechObj.TaskListGroupCounter
                                                                                   and $projection.TaskListSequence               = _MaintTaskListTechObj.TaskListSequence
                                                                                   and $projection.TaskListOperationInternalId    = _MaintTaskListTechObj.TaskListOperationInternalId
                                                                                   and $projection.TaskListOpBOMItmIntVersCounter = _MaintTaskListTechObj.TaskListOpBOMItmIntVersCounter
  association [0..1] to R_MaintTaskListOpLongTextTP       as _OpLongText           on  $projection.TaskListType                   = _OpLongText.TaskListType
                                                                                   and $projection.TaskListGroup                  = _OpLongText.TaskListGroup
                                                                                   and $projection.TaskListGroupCounter           = _OpLongText.TaskListGroupCounter
                                                                                   and $projection.TaskListSequence               = _OpLongText.TaskListSequence
                                                                                   and $projection.TaskListOperationInternalId    = _OpLongText.TaskListOperationInternalId
                                                                                   and $projection.TaskListOpBOMItmIntVersCounter = _OpLongText.TaskListOpBOMItmIntVersCounter
  association        to R_MaintenanceTaskListTP           as _Header               on  $projection.TaskListType         = _Header.TaskListType
                                                                                   and $projection.TaskListGroup        = _Header.TaskListGroup
                                                                                   and $projection.TaskListGroupCounter = _Header.TaskListGroupCounter
{
  key     plas.BillOfOperationsType                                                         as TaskListType,
  key     plas.BillOfOperationsGroup                                                        as TaskListGroup,
  key     plas.BillOfOperationsVariant                                                      as TaskListGroupCounter,
  key     plas.BillOfOperationsSequence                                                     as TaskListSequence,
  key     plpo.BOOOperationInternalID                                                       as TaskListOperationInternalId,
  key     plpo.BOOOpInternalVersionCounter                                                  as TaskListOpBOMItmIntVersCounter,
          cast(plpo.Operation as pph_vornr preserving type)                                 as MaintenanceTaskListOperation,
          case when plpo.SuperiorOperationInternalID <> '00000000'
          then cast(plpo.Operation as pph_uvorn preserving type)
          else ''
          end                                                                               as MaintTaskListSubOperation,

          plpo.MaintOperationExecStageCode,
          plpo.OperationText,
          plpo.OperationControlProfile,
          plpo._WorkCenter.WorkCenter                                                       as WorkCenter,
          plpo.Plant,
          @ObjectModel.foreignKey.association: '_TechnicalObject'
          _MaintTaskListTechObj.TechnicalObject                                             as TechnicalObject,
          @ObjectModel.foreignKey.association: '_TechObjIsEquipOrFuncnlLoc'
          @UI.textArrangement: #TEXT_ONLY
          _MaintTaskListTechObj.TechObjIsEquipOrFuncnlLoc                                   as TechObjIsEquipOrFuncnlLoc,
          plpo.Assembly,
          plpo.OperationCalculationControl,
          @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit'
          plpo.OpPlannedWorkQuantity,
          plpo.OpWorkQuantityUnit,
          plpo.WorkCenterInternalID,
          plpo.WorkCenterTypeCode,
          plpo.NumberOfCapacities,
          @ Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
          plpo.PurchaseOrderQty,
          plpo.PurchaseOrderQuantityUnit,
          @Semantics.quantity.unitOfMeasure: 'OperationStandardDurationUnit'
          plpo.OperationStandardDuration,
          plpo.OperationStandardDurationUnit,
          plpo.CostCtrActivityType,
          plpo.MaterialGroup                                                                as MaterialGroup,
          @Semantics.amount.currencyCode : 'OpExternalProcessingCurrency'
          plpo.OpExternalProcessingPrice,

          plpo.OpExternalProcessingCurrency,
          plpo.CostElement                                                                  as CostElement,
          plpo.PurchasingGroup                                                              as PurchasingGroup,
          plpo.PurchasingOrganization,
          plpo.Supplier,
          plpo.ChangeNumber                                                                 as ChangeNumber,
          plpo.ValidityStartDate,
          plpo.ValidityEndDate,
          plpo.OperationStandardTextCode,
          plpo.PurchasingInfoRecdAddlGrpgName,

          plpo.NumberOfOperationPriceUnits,
          plpo.PurchasingInfoRecord,
          plpo.PurchasingInfoRecordCategory,
          plpo.PurchaseContract,
          plpo.PurchaseContractItem,
          plpo.OperationSystemCondition,
          plpo.Equipment,
          plpo.IsDeleted,
          plpo.MaintOperationalChecklistType,

          /* Associations */
          plpo._Assembly,
          plpo._ChangeMaster,
          plpo._Equipment,
          _MaintenanceTaskList,
          plpo._OperationCalculationControl,
          plpo._OperationControlProfile,
          plpo._OperationStandardText,
          plpo._OperationSystemCondition,
          plpo._Plant,
          plpo._PurchasingInfoRecord,
          plpo._PurchasingOrganization,
          plpo._Supplier,
          @Semantics.booleanIndicator: true
          plpo._Supplier.IsBusinessPurposeCompleted                                         as IsBusinessPurposeCompleted,
          plpo._Supplier.SupplierAccountGroup                                               as SupplierAccountGroup,
          plpo._Supplier.AuthorizationGroup                                                 as AuthorizationGroup,
          _MaintenanceTaskList.TaskListStatus                                               as TaskListStatus,
          _MaintenanceTaskList._TechnicalObject.MaintenancePlanningPlant                    as MaintenancePlanningPlant,
          _MaintenanceTaskList._TechnicalObject.MaintenancePlannerGroup                     as MaintenancePlannerGroup,
          _MaintenanceTaskList._TechnicalObject._LocationAccountAssignment.ControllingArea  as ControllingArea,
          _MaintenanceTaskList._TechnicalObject._LocationAccountAssignment.CostCenter       as CostCenter,
          _MaintenanceTaskList._TechnicalObject._LocationAccountAssignment.MaintenancePlant as MaintenancePlant,
          _MaintenanceTaskList.ResponsiblePlannerGroup                                      as ResponsiblePlannerGroup,
          plpo._WorkCenter,
          plpo._WorkCenterType,
          plpo._MaintOperationExecStageCode,
          /* Associations - locally defined */
          _MaintTaskListTechObj._TechnicalObject                                            as _TechnicalObject,
          _MaintTaskListTechObj._TechObjIsEquipOrFuncnlLoc,
          _NonHistOp,
          _OpMaterial,
          _OpRelation,
          _MaintTaskListTechObj,
          _OpLongText,
          _SubOp,
          _Header
}
where
     plas.BillOfOperationsType = 'A'
  or plas.BillOfOperationsType = 'E'
  or plas.BillOfOperationsType = 'T';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONSOPBASIC",
"I_BOOSQNCOPERATIONASSGMTCHGST",
"I_LOCATIONACCOUNTASSIGNMENT",
"I_MAINTENANCETASKLIST",
"I_MAINTTASKLISTOPTECHOBJ",
"I_SUPPLIER",
"I_TECHNICALOBJECT",
"I_WORKCENTER"
],
"ASSOCIATED":
[
"I_CHANGEMASTER",
"I_EQUIPMENT",
"I_MAINTENANCETASKLIST",
"I_MAINTOPERATIONEXECSTAGECODE",
"I_MAINTOPERATIONSYSTCONDITION",
"I_MAINTTASKLISTOPTECHOBJ",
"I_MATERIAL",
"I_OPERATIONCALCULATIONCONTROL",
"I_OPERATIONCONTROLPROFILE",
"I_OPERATIONSTANDARDTEXT",
"I_PLANT",
"I_PURCHASINGINFORECORDAPI01",
"I_PURCHASINGORGANIZATION",
"I_SUPPLIER",
"I_TECHNICALOBJECT",
"I_TECHOBJISEQUIPORFUNCNLLOC",
"I_WORKCENTER",
"I_WORKCENTERTYPE",
"R_MAINTENANCETASKLISTTP",
"R_MAINTTASKLISTOPERATIONTP",
"R_MAINTTASKLISTOPLONGTEXTTP",
"R_MAINTTASKLISTOPMATERIALTP",
"R_MAINTTASKLISTOPRELSHPTP",
"R_MAINTTASKLISTSUBOPTP"
],
"BASE":
[
"I_BILLOFOPERATIONSOPBASIC",
"I_MAINTTASKLISTOPTECHOBJ"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/