R_IntOrderSettlementRuleTP

@AccessControl.authorizationCheck: #CHECK
@ObjectModel:{
  usageType:{
    serviceQuality: #C,
    sizeCategory: #L,
    dataClass: #TRANSACTIONAL
     } ,
  sapObjectNodeType.name: 'InternalOrderSettlementRule'
   }

@VDM : {
  viewType: #TRANSACTIONAL ,
  lifecycle.contract.type:#SAP_INTERNAL_API }

@EndUserText.label: 'Internal Order Settlement Rule'
define root view entity R_IntOrderSettlementRuleTP
  as select from I_InternalOrderSettlementRule
  composition [0..*] of R_IntOrdSettlementDistrRuleTP  as _IntOrdSettlementDistrRuleTP
  composition [0..*] of R_IntOrdSettlmtHistPerLedgerTP as _IntOrdSettlmtHistPerLedgerTP
  association [0..1] to I_StatusObjectStatusBasic      as _IntOrdSettlementRuleIsCreated on  I_InternalOrderSettlementRule.ControllingObject = _IntOrdSettlementRuleIsCreated.StatusObject
                                                                                         and (
                                                                                            _IntOrdSettlementRuleIsCreated.StatusCode        = 'I0028'
                                                                                            or _IntOrdSettlementRuleIsCreated.StatusCode     = 'I0027'
                                                                                          )
                                                                                         and _IntOrdSettlementRuleIsCreated.StatusIsInactive = ''

{
  key ControllingObject,
      CreatedByUser,
      CreationDate,
      LastChangedByUser,
      LastChangeDate,
      CtrlgObjectSettlementRuleName,
      AllocationStructure,
      SettlementSourceStructure,
      ControllingSettlementProfile,
      AssetValueDate,
      SettlementSequentialNumber,
      ProfitabilityAcctgTransfStruc,
      SettlmtRuleProcessingSequence,
      SettlmtRuleAutoGnrtnStrgySqnc,
      SettlmtWithFreeDefinedCurrency,
      InternalOrder,
      InternalOrderDescription,
      OrderType,
      ControllingArea,
      InternalOrderLastChangedByUser,
      InternalOrderLastChangeDate,
      CompanyCode,
      InternalOrderControllingObject,
      IntOrderSystemStatusShortName,
      InternalOrderSystemStatusName,
      IsStatisticalOrder,
      @ObjectModel.text.association:null
      _SystemStatus.ControllingObjectStatus,

      case _IntOrdSettlementRuleIsCreated.StatusIsInactive
      when 'X' then cast ('' as fco_io_distr_rule_created preserving type )
      when '' then cast ('X' as fco_io_distr_rule_created preserving type )
      else cast ('' as fco_io_distr_rule_created preserving type )
      end   as IntOrdSettlementRuleIsCreated,

      case _IntOrdIsMarkedForDeletion.StatusIsInactive
        when 'X' then cast ('' as fco_io_markedfordeletion preserving type )
        when '' then cast ('X' as fco_io_markedfordeletion preserving type )
        else cast ('' as fco_io_markedfordeletion preserving type )
      end   as InternalOrderIsDeleted,

      case _IntOrdDeletionFlagIsSet.StatusIsInactive
        when 'X' then cast ('' as fco_io_deletionflag preserving type )
        when '' then cast ('X' as fco_io_deletionflag preserving type )
        else cast ('' as fco_io_deletionflag preserving type )
      end   as InternalOrderDeletionFlagIsSet,

      case _InternalOrderIsLocked.StatusIsInactive
        when 'X' then cast ('' as fco_io_lock preserving type )
        when '' then cast ('X' as fco_io_lock preserving type )
        else cast ('' as fco_io_lock preserving type )
        end as InternalOrderIsLocked,

      case  SettlmtWithFreeDefinedCurrency
      when 'L' then  cast (  '' as fco_sr_io_parlledgersisinactv preserving type )
      else           cast ( 'X' as fco_sr_io_parlledgersisinactv preserving type)
      end   as SettlmtParlLedgersIsInactive,

      @Semantics.systemDateTime.lastChangedAt: true
      cast(
        dats_tims_to_tstmp(
          LastChangeDate,
          cast('000000' as co_chg_time  )  ,
          abap_system_timezone( $session.client,'NULL' ),
          $session.client,
          'NULL'
        ) as timestamp
      )     as LastChangeDateTime,
      /* Associations */
      _AllocationStructure,
      _ControllingArea,
      _SourceStructure,
      _CreatedByUser,
      _LastChangedByUser,
      _CtrlgObjSettlmtDistrRule,
      _PrftbltyAcctgTransfStructure,
      _ControllingSettlementProfile,
      _SettlmtAutomGnrtnStrgySqnc,
      _SettlmtWithFreeDfndCurrency,
      _IntOrdSettlementDistrRuleTP,
      _IntOrdSettlmtHistPerLedgerTP,
      _IntOrderLastChangedByUser,
      _InternalOrderTypeText,
      _CompanyCode,
      _IntOrderActiveSystemStatus,
      _IntOrderActiveUserStatus,
      _LdgrSpcfcAllocStruc


}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INTERNALORDERSETTLEMENTRULE",
"I_INTERNALORDERSYSTEMSTATUS",
"I_STATUSOBJECTSTATUSBASIC"
],
"ASSOCIATED":
[
"I_ALLOCATIONSTRUCTURE",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_CONTROLLINGSETTLEMENTPROFILE",
"I_CONTROLLINGSTRUCTURE",
"I_CTRLGOBJSETTLMTDISTRRULE",
"I_INTERNALORDERTYPETEXT",
"I_INTORDERACTIVESYSTEMSTATUS",
"I_INTORDERACTIVEUSERSTATUS",
"I_LDGRSPCFCALLOCSTRUC",
"I_PRFTBLTYACCTGTRANSFSTRUCTURE",
"I_SETTLMTAUTOMGNRTNSTRGYSQNC",
"I_SETTLMTWITHFREEDFNDCURRENCY",
"I_USERCONTACTCARD",
"R_INTORDSETTLEMENTDISTRRULETP",
"R_INTORDSETTLMTHISTPERLEDGERTP"
],
"BASE":
[
"I_INTERNALORDERSETTLEMENTRULE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/