R_IntOrdSettlementDistrRuleTP

@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
@VDM : {
  viewType: #TRANSACTIONAL ,
  lifecycle.contract.type:#SAP_INTERNAL_API }

@EndUserText.label: 'Internal Order Distribution Rule'
define view entity R_IntOrdSettlementDistrRuleTP
  as select from I_IntOrderSettlementDistrRule

  association to parent R_IntOrderSettlementRuleTP   as _IntOrderSettlementRuleTP on $projection.ControllingObject = _IntOrderSettlementRuleTP.ControllingObject
  composition [0..1] of R_IntOrdSettlmtDistrRuleRETP as _IntOrdSettlmtDistrRuleRETP
{
  key ControllingObject,
  key Ledger,
  key LedgerGroup,
  key SettlementDistributionRuleGrp,
  key SettlmtDistrRuleSequence,
      @ObjectModel:{ editableFieldFor: 'ControllingObject' }
      ControllingObject                                                                                                 as ControllingObjectForEdit,
      @ObjectModel:{ editableFieldFor: 'Ledger' }
      Ledger                                                                                                            as LedgerForEdit,
      @ObjectModel:{ editableFieldFor: 'LedgerGroup' }
      LedgerGroup                                                                                                       as LedgerGroupForEdit,
      @ObjectModel:{ editableFieldFor: 'SettlementDistributionRuleGrp' }
      SettlementDistributionRuleGrp                                                                                     as SettlmtDistributionRuleGrpFoEd,
      @ObjectModel:{ editableFieldFor: 'SettlmtDistrRuleSequence' }
      SettlmtDistrRuleSequence                                                                                          as SettlmtDistrRuleSequenceFoEd,
      SettlementType,
      _SettlmtTypeLanguageDependent.SettlmtTypeLanguageDependent,
      AccountAssignmentType,
      _AccountAssignmentTypeT.AcctAsgtTypeLanguageDependent,
      SettlementReceiver,
      SettlementPercentageRate,
      SettlementEquivalenceFactor,
      SettlementAmount,
      SettlementAmountCurrency,
      ControllingArea,
      CostCenter,
      @VDM.lifecycle: {
        status: #DEPRECATED,
        successor: 'ProfitabilitySegment_2' }
      ProfitabilitySegment,
      ProfitabilitySegment_2,
      @Semantics.booleanIndicator
      cast(
        case AccountAssignmentType
          when 'EO' then 'X'
          else ''
      end as profitabilitysegmentisassigned)                                                                            as ProfitabilitySegmentIsAssigned,
      WBSElementInternalID,
      WBSElementExternalID,
      ProjectNetwork,
      CostObject,
      BusinessProcess,
      BusinessArea,
      AssetTransactionType,
      SalesOrder,
      SalesOrderItem,
      OrderID,
      CompanyCode,
      ProfitCenter,
      MasterFixedAsset,
      FixedAsset,
      GLAccount,
      @Semantics.fiscal.period: true
      ValidityStartFiscalPeriod,
      @Semantics.fiscal.year: true
      ValidityStartFiscalYear,
      @Semantics.fiscal.yearPeriod: true
      //      cast( case ValidityStartFiscalYear  when '0000' then ''

      //                                                     else concat( ValidityStartFiscalYear, ValidityStartFiscalPeriod )

      //                                                     end as fco_stlmt_start_fyearperiod )                               as ValidityStartFiscalYearPeriod,

      //

      cast( case  concat(ValidityStartFiscalYear, ValidityStartFiscalPeriod)
              when '0000000' then ''
              else concat(ValidityStartFiscalYear, ValidityStartFiscalPeriod)
            end as fco_stlmt_start_fyearperiod     )                                                                    as ValidityStartFiscalYearPeriod,
      @Semantics.fiscal.period: true
      ValidityEndFiscalPeriod,
      @Semantics.fiscal.year: true
      ValidityEndFiscalYear,
      @Semantics.fiscal.yearPeriod: true
      //      cast( case ValidityEndFiscalYear   when '0000' then ''

      //                                                     else concat( ValidityEndFiscalYear, ValidityEndFiscalPeriod )

      //                                                     end as fco_stlmt_end_fyearperiod )                                 as ValidityEndFiscalYearPeriod,

      cast( case  concat(ValidityEndFiscalYear, ValidityEndFiscalPeriod)
             when '0000000' then ''
             else concat(ValidityEndFiscalYear, ValidityEndFiscalPeriod)
           end as fco_stlmt_end_fyearperiod     )                                                                       as ValidityEndFiscalYearPeriod,
      @Semantics.fiscal.period: true
      SettlmtRule1stUsgeFiscalPeriod,
      @Semantics.fiscal.year: true
      SettlmtRule1stUsageFiscalYear,
      @Semantics.fiscal.yearPeriod: true
      cast(concat( SettlmtRule1stUsageFiscalYear, SettlmtRule1stUsgeFiscalPeriod )  as fco_stlmt_1stusge_fyearperiod )  as SettlmtRule1stUsgeFsclYrPeriod,
      @Semantics.fiscal.period: true
      SettlmtRuleLastUsgeFsclPeriod,
      @Semantics.fiscal.year: true
      SettlmtRuleLastUsageFiscalYear,
      @Semantics.fiscal.yearPeriod: true
      cast(concat( SettlmtRuleLastUsageFiscalYear, SettlmtRuleLastUsgeFsclPeriod )  as fco_stlmt_lastusge_fyearperiod ) as SettlmtRuleLastUsgeFsclYrPerd,
      SettlmtTracingFctrDetnMethod,
      SettlementDistrAmountRuleType,
      SettlmtDistrRuleSrceAssignment,
      SettlementSourceStructure,
      SettlmtDistributionRuleNumber,
      SettlmtDistrManipulationRule,
      SettlmtRuleAutomStrategyGnrtn,
      SettlementDistrRuleRmngAmount,
      NetworkActivityInternalID,
      ProjectNetworkInternalID,
      NetworkActivity,
      SettlmtWithFreeDefinedCurrency,
      InternalOrder,
      OrderType,
      InternalOrderCompanyCode,
      OperatingConcern,
      SettlmtDistrRuleIsUsedInLedger,
      ServiceDocumentType,
      ServiceDocument,
      ServiceDocumentItem,
      SettlementDistributionRuleUUID,
      SettlementTransaction,
      cast( '' as fco_settlmtdistrrule_is_copied )                                                                      as SettlementDistrRuleIsCopied,
      cast( '' as fis_bukrs )                                                                                           as PrftbltySegmentCompanyCode,

      _IntOrderSettlementRuleTP.ControllingSettlementProfile,

      /* Associations */
      _AccountAssignmentTypeT,
      _CompanyCode,
      _ControllingArea,
      _CostCenter,
      _SourceStructureAssignment,
      _Currency,
      _GLAccount,
      _JntVntrMnpltnRuleRecoveryInd,
      _Ledger,
      _LedgerGroup,
      _OrderID,
      _ProjectNetwork,
      _SettlementAutomGnrtnStrategy,
      _SettlementType,
      _SettlmtTracingFctrDetnMethod,
      _SettlmtDistrAmountRuleType,
      _WBSElementBasicData,
      _IntOrderSettlementRuleTP,
      _SettlmtWithFreeDfndCurrency,
      _InternalOrderCompanyCode,
      _SettlmtTypeLanguageDependent,
      _AssetTransactionType,
      _MasterFixedAsset,
      _FixedAsset,
      _SalesOrderItem,
      _IntOrdSettlmtDistrRuleRETP,
      _NetworkActivityByInternalKey,
      _ProjectNetworkBasicData,
      _BusinessProcess,
      _ProfitCenter,
      _AcctgSrvcDocumentItemBasic,
      _AcctgServiceDocumentType


}
where
  (
        SettlmtWithFreeDefinedCurrency =  'L'
    and Ledger                         =  '00'
  )
  or(
        SettlmtWithFreeDefinedCurrency <> 'L'
  );
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ACCOUNTASSIGNMENTTYPET",
"I_INTORDERSETTLEMENTDISTRRULE",
"I_SETTLMTTYPELANGUAGEDEPENDENT",
"R_INTORDERSETTLEMENTRULETP"
],
"ASSOCIATED":
[
"I_ACCOUNTASSIGNMENTTYPET",
"I_ACCTGSERVICEDOCUMENTTYPE",
"I_ACCTGSRVCDOCUMENTITEMBASIC",
"I_ASSETTRANSACTIONTYPE",
"I_BUSINESSPROCESS",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COSTCENTER",
"I_CTRLGSTRUCTUREASSIGNMENT",
"I_CURRENCY",
"I_FIXEDASSET",
"I_GLACCOUNT",
"I_JNTVNTRMNPLTNRULERECOVERYIND",
"I_LEDGER",
"I_LEDGERGROUP",
"I_MASTERFIXEDASSET",
"I_NETWORKACTIVITYBYINTERNALKEY",
"I_ORDERBASIC",
"I_PROFITCENTER",
"I_PROJECTNETWORKBASICDATA",
"I_SALESORDERITEM",
"I_SETTLEMENTAUTOMGNRTNSTRATEGY",
"I_SETTLEMENTTYPE",
"I_SETTLMTDISTRAMOUNTRULETYPE",
"I_SETTLMTTRACINGFCTRDETNMETHOD",
"I_SETTLMTTYPELANGUAGEDEPENDENT",
"I_SETTLMTWITHFREEDFNDCURRENCY",
"I_WBSELEMENTBASICDATA",
"R_INTORDERSETTLEMENTRULETP",
"R_INTORDSETTLMTDISTRRULERETP"
],
"BASE":
[
"I_INTORDERSETTLEMENTDISTRRULE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/