I_InternalOrderSettlementRule

@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: ['_LastChangedByUser','_CreatedByUser']
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType:{
  serviceQuality: #B,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
@EndUserText.label: 'Internal Order Settlement Rule'
define view entity I_InternalOrderSettlementRule
  as select from I_CtrlgObjectSettlementRule
    inner join   I_InternalOrder on I_CtrlgObjectSettlementRule.ControllingObject = I_InternalOrder.ControllingObject
  association [0..*] to I_IntOrderSettlementDistrRule as _IntOrderSettlementDistrRule on  $projection.ControllingObject = _IntOrderSettlementDistrRule.ControllingObject
  association [0..*] to I_LdgrSpcfcAllocStruc         as _LdgrSpcfcAllocStruc         on  $projection.AllocationStructure    = _LdgrSpcfcAllocStruc.AllocationStructure
                                                                                      and (
                                                                                         $projection.CompanyCode             = _LdgrSpcfcAllocStruc.CompanyCode
                                                                                         or _LdgrSpcfcAllocStruc.CompanyCode = ''
                                                                                       )
  association [0..1] to I_ControllingArea             as _ControllingArea             on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to I_InternalOrderType           as _InternalOrderType           on  $projection.OrderType = _InternalOrderType.OrderType
  association [0..1] to I_StatusObjectStatusBasic     as _IntOrdIsMarkedForDeletion   on  $projection.ControllingObject         = _IntOrdIsMarkedForDeletion.StatusObject
                                                                                      and _IntOrdIsMarkedForDeletion.StatusCode = 'I0013'
  association [0..1] to I_StatusObjectStatusBasic     as _IntOrdDeletionFlagIsSet     on  I_InternalOrder.ControllingObject   = _IntOrdDeletionFlagIsSet.StatusObject
                                                                                      and _IntOrdDeletionFlagIsSet.StatusCode = 'I0076'
  association [0..1] to I_StatusObjectStatusBasic     as _InternalOrderIsLocked       on  I_InternalOrder.ControllingObject = _InternalOrderIsLocked.StatusObject
                                                                                      and _InternalOrderIsLocked.StatusCode = 'I0043'
{
  key I_CtrlgObjectSettlementRule.ControllingObject,
      I_CtrlgObjectSettlementRule.CreatedByUser,
      I_CtrlgObjectSettlementRule.CreationDate,
      cast(I_CtrlgObjectSettlementRule.LastChangedByUser as fco_sr_io_brgaenam preserving type )        as LastChangedByUser,
      I_CtrlgObjectSettlementRule.LastChangeDate,
      I_CtrlgObjectSettlementRule.CtrlgObjectSettlementRuleName,
      I_CtrlgObjectSettlementRule.AllocationStructure,
      I_CtrlgObjectSettlementRule.SettlementGLAccount,
      I_CtrlgObjectSettlementRule.SettlementSourceStructure,
      I_CtrlgObjectSettlementRule.SettlementIsProportional,
      I_CtrlgObjectSettlementRule.SettlementRuleHasUpdateError,
      I_CtrlgObjectSettlementRule.ControllingSettlementProfile,
      I_CtrlgObjectSettlementRule.SettlementSequentialNumber,
      I_CtrlgObjectSettlementRule.AssetValueDate,
      I_CtrlgObjectSettlementRule.ProfitabilityAcctgTransfStruc,
      I_CtrlgObjectSettlementRule.SettlmtRuleLastUsgeFsclPeriod,
      I_CtrlgObjectSettlementRule.SettlmtRuleLastUsageFiscalYear,
      I_CtrlgObjectSettlementRule.SettlmtRuleProcessingSequence,
      I_CtrlgObjectSettlementRule.SettlementRuleCreationDateTime,
      I_CtrlgObjectSettlementRule.SettlmtRuleAutoGnrtnStrgySqnc,
      I_CtrlgObjectSettlementRule.SettlmtWithFreeDefinedCurrency,


      I_InternalOrder.InternalOrder,
      cast( I_InternalOrder.InternalOrderDescription as fis_io_text preserving type )                   as InternalOrderDescription,
      @ObjectModel.foreignKey.association: '_InternalOrderType'
      @ObjectModel.text.association:null
      I_InternalOrder.OrderType,
      @ObjectModel.foreignKey.association: '_ControllingArea'
      @ObjectModel.text.association:null
      I_InternalOrder.ControllingArea,
      cast(I_InternalOrder.LastChangedByUser  as fco_sr_io_aufaenam preserving type )                   as InternalOrderLastChangedByUser,
      cast(I_InternalOrder.LastChangeDate as  fco_sr_io_aufaedat preserving type )                      as InternalOrderLastChangeDate,
      //      @ObjectModel.foreignKey.association: '_CompanyCode'

      I_InternalOrder.CompanyCode,
      I_InternalOrder.IsStatisticalOrder,
      I_InternalOrder.ControllingObject                                                                 as InternalOrderControllingObject,
      I_InternalOrder._SystemStatus._Text[1: Language = $session.system_language].SystemStatusShortName as IntOrderSystemStatusShortName,
      I_InternalOrder._SystemStatus._Text[1: Language = $session.system_language].StatusName            as InternalOrderSystemStatusName,


      /* Associations */
      I_CtrlgObjectSettlementRule._AllocationStructure,
      I_CtrlgObjectSettlementRule._ControllingObject,
      I_CtrlgObjectSettlementRule._SourceStructure,
      I_CtrlgObjectSettlementRule._CreatedByUser,
      I_CtrlgObjectSettlementRule._CtrlgObjSettlmtDistrRule,
      I_CtrlgObjectSettlementRule._LastChangedByUser,
      I_CtrlgObjectSettlementRule._PrftbltyAcctgTransfStructure,
      I_CtrlgObjectSettlementRule._ControllingSettlementProfile,
      I_CtrlgObjectSettlementRule._SettlmtAutomGnrtnStrgySqnc,
      I_CtrlgObjectSettlementRule._SettlmtWithFreeDfndCurrency,
      I_InternalOrder._InternalOrderTypeText,
      I_InternalOrder._CompanyCode,
      I_InternalOrder._LastChangedByUser                                                                as _IntOrderLastChangedByUser,
      I_InternalOrder._IntOrderActiveSystemStatus,
      I_InternalOrder._IntOrderActiveUserStatus,
      I_InternalOrder._SystemStatus,

      _ControllingArea,
      _InternalOrderType,
      _IntOrderSettlementDistrRule,
      _IntOrdIsMarkedForDeletion,
      _IntOrdDeletionFlagIsSet,
      _InternalOrderIsLocked,
      _LdgrSpcfcAllocStruc
}
where
     I_InternalOrder.OrderCategory = '01'
  or I_InternalOrder.OrderCategory = '02'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CTRLGOBJECTSETTLEMENTRULE",
"I_INTERNALORDER",
"I_INTERNALORDERSYSTEMSTATUS",
"I_INTERNALORDERSYSTEMSTATUST"
],
"ASSOCIATED":
[
"I_ALLOCATIONSTRUCTURE",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_CONTROLLINGOBJECT",
"I_CONTROLLINGSETTLEMENTPROFILE",
"I_CONTROLLINGSTRUCTURE",
"I_CTRLGOBJSETTLMTDISTRRULE",
"I_INTERNALORDERSYSTEMSTATUS",
"I_INTERNALORDERTYPE",
"I_INTERNALORDERTYPETEXT",
"I_INTORDERACTIVESYSTEMSTATUS",
"I_INTORDERACTIVEUSERSTATUS",
"I_INTORDERSETTLEMENTDISTRRULE",
"I_LDGRSPCFCALLOCSTRUC",
"I_PRFTBLTYACCTGTRANSFSTRUCTURE",
"I_SETTLMTAUTOMGNRTNSTRGYSQNC",
"I_SETTLMTWITHFREEDFNDCURRENCY",
"I_STATUSOBJECTSTATUSBASIC",
"I_USERCONTACTCARD"
],
"BASE":
[
"I_CTRLGOBJECTSETTLEMENTRULE",
"I_INTERNALORDER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/