R_CreditMemoRequestTP

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@ObjectModel: {
  sapObjectNodeType:{
        name: 'CreditMemoRequest'
   },
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory: #L
    }
}

@ObjectModel.semanticKey: ['CreditMemoRequest']

@Metadata.ignorePropagatedAnnotations: true

@EndUserText.label: 'Credit Memo Request - TP'
define root view entity R_CreditMemoRequestTP
  as select from I_CreditMemoRequest as CreditMemoRequest

  composition [0..*] of R_CreditMemoRequestItemTP      as _Item
  composition [0..*] of R_CreditMemoRequestPartnerTP   as _Partner
  composition [0..*] of R_CreditMemoReqPricingElmntTP  as _PricingElement
  composition [0..*] of R_CreditMemoRequestTextTP      as _Text
  composition [0..1] of R_CreditMemoReqShipToPartyTP   as _ShipToParty
  association [0..1] to I_SlsOrganizationDistrChnl     as _SlsOrganizationDistrChnl on  $projection.SalesOrganization   = _SlsOrganizationDistrChnl.SalesOrganization
                                                                                    and $projection.DistributionChannel = _SlsOrganizationDistrChnl.DistributionChannel
  association [0..1] to I_CreditMemoReqPartner         as _SoldToParty              on  $projection.CreditMemoRequest = _SoldToParty.CreditMemoRequest
                                                                                    and _SoldToParty.PartnerFunction  = 'AG'    
  association [0..1] to I_CreditMemoReqPartner         as _Payer                     on  $projection.CreditMemoRequest = _Payer.CreditMemoRequest
                                                                                    and _Payer.PartnerFunction  = 'RG'                                                
  //Extension Association

  association [1]    to E_SalesDocumentBasic           as _Extension                on  $projection.CreditMemoRequest   = _Extension.SalesDocument         
{
  key CreditMemoRequest,

      @ObjectModel.foreignKey.association: '_CreditMemoRequestType'
      CreditMemoRequestType,

      CreditMemoRequestDate,

      @ObjectModel.foreignKey.association: '_ControllingArea'
      ControllingArea,

      @ObjectModel.text.element: ['CustomerName']
      SoldToParty,

      @Semantics.text:true
      _SoldToParty._DfltAddrRprstn.AddresseeFullName                               as CustomerName,
      
      _Payer.Customer as PayerParty,
      
      @ObjectModel.foreignKey.association: '_SalesOrganization'
      SalesOrganization,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      DistributionChannel,
      @ObjectModel.foreignKey.association: '_OrganizationDivision'
      OrganizationDivision,

      _SlsOrganizationDistrChnl.ReferenceDistributionChannel,

      @ObjectModel.foreignKey.association: '_SalesOffice'
      SalesOffice,

      @ObjectModel.foreignKey.association: '_SalesGroup'
      SalesGroup,

      @ObjectModel.foreignKey.association: '_SalesDistrict'
      SalesDistrict,

      PurchaseOrderByCustomer,

      @ObjectModel.foreignKey.association: '_CustomerPurchaseOrderType'
      CustomerPurchaseOrderType,

      CustomerPurchaseOrderDate,

      @ObjectModel.foreignKey.association: '_CustomerGroup'
      CustomerGroup,

      @ObjectModel.foreignKey.association: '_SDDocumentReason'
      SDDocumentReason,

      PricingDate,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      TotalNetAmount,

      TransactionCurrency,

      @ObjectModel.foreignKey.association: '_HeaderBillingBlockReason'
      HeaderBillingBlockReason,
      
      SDPricingProcedure,

      @ObjectModel.foreignKey.association: '_IncotermsClassification'
      IncotermsClassification,

      @ObjectModel.foreignKey.association: '_IncotermsVersion'
      IncotermsVersion,

      IncotermsLocation1,

      IncotermsLocation2,

      @ObjectModel.foreignKey.association: '_CustomerPaymentTerms'
      CustomerPaymentTerms,

      @ObjectModel.foreignKey.association: '_BillingCompanyCode'
      BillingCompanyCode,

      PaymentMethod,

      BillingDocumentDate,

      ServicesRenderedDate,

      ReferenceSDDocument,

      @ObjectModel.foreignKey.association: '_ReferenceSDDocumentCategory'
      ReferenceSDDocumentCategory,

      CreatedByUser,

      @Consumption.hidden: true
      CreationDate,

      @Consumption.hidden: true
      CreationTime,

      cast( dats_tims_to_tstmp( CreationDate, CreationTime, abap_system_timezone( $session.client, 'NULL' ),
        $session.client, 'NULL' ) as creation_date_time ) as SalesDocumentCreationDateTime,

      LastChangedByUser,
      @Consumption.hidden: true
      LastChangeDate,
      case tstmp_is_valid(cast(LastChangeDateTime as abap.dec(15,0)))
        when 0 then cast( dats_tims_to_tstmp( CreationDate, CreationTime, 'UTC', $session.client, 'NULL' ) as timestampl )
        else LastChangeDateTime
      end                                                 as LastChangeDateTime,

      @ObjectModel.foreignKey.association: '_CreditMemoReqApprovalReason'
      CreditMemoReqApprovalReason,

      @ObjectModel.foreignKey.association: '_SalesDocApprovalStatus'
      SalesDocApprovalStatus,

      @ObjectModel.foreignKey.association: '_OverallBillingBlockStatus'
      OverallBillingBlockStatus,

      @ObjectModel.foreignKey.association: '_OverallSDProcessStatus'
      OverallSDProcessStatus,

      @ObjectModel.foreignKey.association: '_OverallSDDocumentRejectionSts'
      OverallSDDocumentRejectionSts,

      @ObjectModel.foreignKey.association: '_OverallOrdReltdBillgStatus'
      OverallOrdReltdBillgStatus,

      @ObjectModel.foreignKey.association: '_TotalBlockStatus'
      TotalBlockStatus,

      @ObjectModel.foreignKey.association: '_HdrGeneralIncompletionStatus'
      HdrGeneralIncompletionStatus,

      @ObjectModel.foreignKey.association: '_OvrlItmGeneralIncompletionSts'
      OvrlItmGeneralIncompletionSts,

      @ObjectModel.foreignKey.association: '_OverallSDDocReferenceStatus'
      OverallSDDocReferenceStatus,

      //Compositions

      _Item,
      _Partner,
      _PricingElement,
      _Text,
      _ShipToParty,

      //Exposed Associations

      _CreditMemoRequestType,
      _SalesOrganization,
      _DistributionChannel,
      _OrganizationDivision,
      _SalesOffice,
      _SalesGroup,
      _SalesDistrict,
      _CustomerPurchaseOrderType,
      _CustomerGroup,
      _SDDocumentReason,
      _TransactionCurrency,
      _IncotermsClassification,
      _IncotermsVersion,
      _CustomerPaymentTerms,
      _BillingCompanyCode,
      _HeaderBillingBlockReason,
      _ReferenceSDDocumentCategory,
      _CreditMemoReqApprovalReason,
      _OverallSDProcessStatus,
      _OverallBillingBlockStatus,
      _SalesDocApprovalStatus,
      _OverallSDDocumentRejectionSts,
      _OverallOrdReltdBillgStatus,
      _TotalBlockStatus,
      _OverallSDDocReferenceStatus,
      _HdrGeneralIncompletionStatus,
      _OvrlItmGeneralIncompletionSts,
      _ControllingArea,
      _LastChangedByUser,
      _CreatedByUser
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESS_2",
"I_CREDITMEMOREQPARTNER",
"I_CREDITMEMOREQUEST",
"I_SLSORGANIZATIONDISTRCHNL"
],
"ASSOCIATED":
[
"I_BILLINGBLOCKREASON",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_CREDITMEMOREQAPPROVALREASON",
"I_CREDITMEMOREQUESTTYPE",
"I_CURRENCY",
"I_CUSTOMERGROUP",
"I_CUSTOMERPAYMENTTERMS",
"I_CUSTOMERPURCHASEORDERTYPE",
"I_DISTRIBUTIONCHANNEL",
"I_DIVISION",
"I_HDRGENINCOMPLETIONSTATUS",
"I_INCOTERMSCLASSIFICATION",
"I_INCOTERMSVERSION",
"I_OVERALLBILLINGBLOCKSTATUS",
"I_OVERALLORDRELTDBILLGSTATUS",
"I_OVERALLSDDOCREFERENCESTATUS",
"I_OVERALLSDDOCUMENTRJCNSTATUS",
"I_OVERALLSDPROCESSSTATUS",
"I_OVRLITMGENINCOMPLETIONSTS",
"I_SALESDISTRICT",
"I_SALESDOCAPPROVALSTATUS",
"I_SALESGROUP",
"I_SALESOFFICE",
"I_SALESORGANIZATION",
"I_SDDOCUMENTCATEGORY",
"I_SDDOCUMENTREASON",
"I_TOTALBLOCKSTATUS",
"I_USER",
"R_CREDITMEMOREQPRICINGELMNTTP",
"R_CREDITMEMOREQSHIPTOPARTYTP",
"R_CREDITMEMOREQUESTITEMTP",
"R_CREDITMEMOREQUESTPARTNERTP",
"R_CREDITMEMOREQUESTTEXTTP"
],
"BASE":
[
"I_CREDITMEMOREQUEST"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/