R_CreditMemoRequestTextTP

DDL: R_CREDITMEMOREQUESTTEXTTP Type: view_entity TRANSACTIONAL

Credit Memo Request - Text TP

R_CreditMemoRequestTextTP is a Transactional CDS View that provides data about "Credit Memo Request - Text TP" in SAP S/4HANA. It reads from 3 data sources (P_SalesDocumentText, I_SalesDocumentBasic, I_SalesDocumentType) and exposes 15 fields with key fields CreditMemoRequest, Language, LongTextID. It has 3 associations to related views.

3 data source(s) 15 fields

Data Sources (3)

SourceAliasJoin Type
P_SalesDocumentText P_SalesDocumentText from
I_SalesDocumentBasic SalesDocumentBasic inner
I_SalesDocumentType SalesDocumentType inner

Associations (3)

CardinalityTargetAliasCondition
[0..*] I_TextDeterminationProcedItem _TextDeterminationProcedItem $projection.TextDeterminationProcedure = _TextDeterminationProcedItem.TextDeterminationProcedure and $projection.LongTextID = _TextDeterminationProcedItem.LongTextID and _TextDeterminationProcedItem.TextObjectCategory = 'VBBK'
[0..1] I_Language _Language $projection.LanguageForEdit = _Language.Language
[0..1] I_SDDocumentLongTextID _LongTextID $projection.LongTextIDForEdit = _LongTextID.LongTextID

Annotations (8)

NameValueLevelField
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
VDM.viewType #TRANSACTIONAL view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
Metadata.ignorePropagatedAnnotations true view
AccessControl.authorizationCheck #CHECK view
EndUserText.label Credit Memo Request - Text TP view

Fields (15)

KeyFieldSource TableSource FieldDescription
KEY CreditMemoRequest
KEY Language CreditMemoRequestText Language
KEY LongTextID CreditMemoRequestText LongTextID
LongTextIDForEdit CreditMemoRequestText LongTextID
LanguageForEdit CreditMemoRequestText Language
LongText CreditMemoRequestText LongText
TextDeterminationProcedure I_SalesDocumentType TextDeterminationProcedure
TextDeterminationProcedureItem _TextDeterminationProcedItem TextDeterminationProcedureItem
CreditMemoRequestType _CreditMemoRequest CreditMemoRequestType
SalesOrganization _CreditMemoRequest SalesOrganization
DistributionChannel _CreditMemoRequest DistributionChannel
OrganizationDivision _CreditMemoRequest OrganizationDivision
_CreditMemoRequest _CreditMemoRequest
_Language _Language
_LongTextID _LongTextID 

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}

@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory: #L
    }
}

@ObjectModel.semanticKey: ['CreditMemoRequest', 'Language', 'LongTextID']

@Metadata.ignorePropagatedAnnotations: true

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@EndUserText.label: 'Credit Memo Request - Text TP'
define view entity R_CreditMemoRequestTextTP
  as select from P_SalesDocumentText( P_SAPClient : $session.client ) as CreditMemoRequestText

    inner join   I_SalesDocumentBasic                                 as SalesDocumentBasic on  SalesDocumentBasic.SalesDocument      = CreditMemoRequestText.SalesDocument
                                                                                            and SalesDocumentBasic.SDDocumentCategory = 'K'

    inner join   I_SalesDocumentType                                  as SalesDocumentType  on SalesDocumentBasic.SalesDocumentType = SalesDocumentType.SalesDocumentType


  association        to parent R_CreditMemoRequestTP  as _CreditMemoRequest           on  $projection.CreditMemoRequest = _CreditMemoRequest.CreditMemoRequest

  association [0..*] to I_TextDeterminationProcedItem as _TextDeterminationProcedItem on  $projection.TextDeterminationProcedure          = _TextDeterminationProcedItem.TextDeterminationProcedure
                                                                                      and $projection.LongTextID                          = _TextDeterminationProcedItem.LongTextID
                                                                                      and _TextDeterminationProcedItem.TextObjectCategory = 'VBBK'

  association [0..1] to I_Language                    as _Language                    on  $projection.LanguageForEdit = _Language.Language
  association [0..1] to I_SDDocumentLongTextID        as _LongTextID                  on  $projection.LongTextIDForEdit = _LongTextID.LongTextID

{
  key cast(CreditMemoRequestText.SalesDocument as credit_memo_request preserving type) as CreditMemoRequest,

  key CreditMemoRequestText.Language,

  key CreditMemoRequestText.LongTextID,

      @ObjectModel.foreignKey.association: '_LongTextID'
      CreditMemoRequestText.LongTextID                                                 as LongTextIDForEdit,

      @ObjectModel.foreignKey.association: '_Language'
      CreditMemoRequestText.Language                                                   as LanguageForEdit,

      CreditMemoRequestText.LongText,

      @Consumption.hidden: true
      SalesDocumentType.TextDeterminationProcedure,

      _TextDeterminationProcedItem.TextDeterminationProcedureItem                      as TextDeterminationProcedureItem,

      // For Access control

      @Consumption.hidden: true
      _CreditMemoRequest.CreditMemoRequestType,
      @Consumption.hidden: true
      _CreditMemoRequest.SalesOrganization,
      @Consumption.hidden: true
      _CreditMemoRequest.DistributionChannel,
      @Consumption.hidden: true
      _CreditMemoRequest.OrganizationDivision,


      // Exposed associations

      _CreditMemoRequest,
      _Language,
      _LongTextID
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESDOCUMENTBASIC",
"I_SALESDOCUMENTTYPE",
"I_TEXTDETERMINATIONPROCEDITEM",
"R_CREDITMEMOREQUESTTP"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_SDDOCUMENTLONGTEXTID",
"R_CREDITMEMOREQUESTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More