R_CreditMemoRequestPartnerTP

DDL: R_CREDITMEMOREQUESTPARTNERTP Type: view_entity TRANSACTIONAL

Credit Memo Request Partner - TP

R_CreditMemoRequestPartnerTP is a Transactional CDS View that provides data about "Credit Memo Request Partner - TP" in SAP S/4HANA. It reads from 1 data source (I_CreditMemoReqPartner) and exposes 56 fields with key fields CreditMemoRequest, PartnerFunction. It has 4 associations to related views.

1 data source(s) 56 fields

Data Sources (1)

SourceAliasJoin Type
I_CreditMemoReqPartner CreditMemoRequestPartner from

Associations (4)

CardinalityTargetAliasCondition
[0..1] I_PartnerFunction _PartnerFunction $projection.PartnerFunctionForEdit = _PartnerFunction.PartnerFunction
[0..1] I_Language _CorrespondenceLanguage $projection.CorrespondenceLanguage = _CorrespondenceLanguage.Language
[0..1] I_FormOfAddress _FormOfAddress $projection.FormOfAddress = _FormOfAddress.FormOfAddress
[0..1] I_TransportationZone _TransportationZone $projection.transportzone = _TransportationZone.TransportZone and $projection.country = _TransportationZone.CountryCode

Annotations (8)

NameValueLevelField
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
VDM.viewType #TRANSACTIONAL view
AccessControl.authorizationCheck #CHECK view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
Metadata.ignorePropagatedAnnotations true view
EndUserText.label Credit Memo Request Partner - TP view

Fields (56)

KeyFieldSource TableSource FieldDescription
KEY CreditMemoRequest CreditMemoRequest
KEY PartnerFunction
PartnerFunctionForEdit
Customer I_CreditMemoReqPartner Customer
Supplier I_CreditMemoReqPartner Supplier
Personnel I_CreditMemoReqPartner Personnel
ContactPerson I_CreditMemoReqPartner ContactPerson
ReferenceBusinessPartner I_CreditMemoReqPartner ReferenceBusinessPartner
Partner I_CreditMemoReqPartner Partner
FullName I_CreditMemoReqPartner FullName
SDDocumentPartnerType _PartnerFunction SDDocumentPartnerType
FormOfAddress I_CreditMemoReqPartner FormOfAddress
PostalCode
CityName
DistrictName
Country
Region
StreetName
StreetPrefixName1
StreetPrefixName2
StreetSuffixName1
StreetSuffixName2
HouseNumber
InternationalPhoneNumber I_CreditMemoReqPartner InternationalPhoneNumber
InternationalMobilePhoneNumber I_CreditMemoReqPartner InternationalMobilePhoneNumber
EmailAddress I_CreditMemoReqPartner EmailAddress
InternationalFaxNumber I_CreditMemoReqPartner InternationalFaxNumber
POBox
POBoxPostalCode
CorrespondenceLanguage I_CreditMemoReqPartner CorrespondenceLanguage
TaxJurisdiction
TransportZone
UnloadingPointName I_CreditMemoReqPartner UnloadingPointName
VATRegistration I_CreditMemoReqPartner VATRegistration
SDDocPartnerAddrIsDocSpecific I_CreditMemoReqPartner SDDocPartnerAddrIsDocSpecific
AddressID I_CreditMemoReqPartner AddressID
AddressPersonID I_CreditMemoReqPartner AddressPersonID
AddressObjectType I_CreditMemoReqPartner AddressObjectType
SDDocPartnerAddressRefType I_CreditMemoReqPartner SDDocPartnerAddressRefType
BPAddrDeterminationTransaction I_CreditMemoReqPartner BPAddrDeterminationTransaction
BPRefAddressIDForDocSpcfcAddr I_CreditMemoReqPartner BPRefAddressIDForDocSpcfcAddr
CreditMemoRequestType _CreditMemoRequest CreditMemoRequestType
SalesOrganization _CreditMemoRequest SalesOrganization
DistributionChannel _CreditMemoRequest DistributionChannel
OrganizationDivision _CreditMemoRequest OrganizationDivision
_CreditMemoRequest _CreditMemoRequest
_PartnerFunction _PartnerFunction
_CorrespondenceLanguage _CorrespondenceLanguage
_FormOfAddress _FormOfAddress
_TransportationZone _TransportationZone
_DfltAddrRprstn I_CreditMemoReqPartner _DfltAddrRprstn
_OrgNamePostalAddress I_CreditMemoReqPartner _OrgNamePostalAddress
_BusinessPartnerAddress I_CreditMemoReqPartner _BusinessPartnerAddress
_BPRefAddressForDocSpcfcAddr I_CreditMemoReqPartner _BPRefAddressForDocSpcfcAddr
_Country
_Region 
@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations: [ '_DfltAddrRprstn' ]
}

@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory: #L
    }
}

@ObjectModel.semanticKey: ['CreditMemoRequest', 'PartnerFunction']

@Metadata.ignorePropagatedAnnotations: true

@EndUserText.label: 'Credit Memo Request Partner - TP'
define view entity R_CreditMemoRequestPartnerTP
  as select from I_CreditMemoReqPartner as CreditMemoRequestPartner
  
  association        to parent R_CreditMemoRequestTP as _CreditMemoRequest      on $projection.CreditMemoRequest = _CreditMemoRequest.CreditMemoRequest

  association [0..1] to I_PartnerFunction            as _PartnerFunction        on $projection.PartnerFunctionForEdit = _PartnerFunction.PartnerFunction

  association [0..1] to I_Language                   as _CorrespondenceLanguage on $projection.CorrespondenceLanguage = _CorrespondenceLanguage.Language
   
  association [0..1] to I_FormOfAddress              as _FormOfAddress          on  $projection.FormOfAddress = _FormOfAddress.FormOfAddress

  association [0..1] to I_TransportationZone         as _TransportationZone     on  $projection.transportzone = _TransportationZone.TransportZone
                                                                                and $projection.country       = _TransportationZone.CountryCode
{
  key CreditMemoRequest,      

  key cast(CreditMemoRequestPartner.PartnerFunction as parvw_unv preserving type )        as PartnerFunction,
      
      @ObjectModel.editableFieldFor: 'PartnerFunction'
      @ObjectModel.foreignKey.association: '_PartnerFunction'
      cast(CreditMemoRequestPartner.PartnerFunction as parvw_unv preserving type )        as PartnerFunctionForEdit,

      @Consumption.hidden: true
      CreditMemoRequestPartner.Customer,

      @Consumption.hidden: true
      CreditMemoRequestPartner.Supplier,

      @Consumption.hidden: true
      CreditMemoRequestPartner.Personnel,

      @Consumption.hidden: true
      CreditMemoRequestPartner.ContactPerson,

      CreditMemoRequestPartner.ReferenceBusinessPartner,
      
      @ObjectModel.text.element: ['FullName']
      CreditMemoRequestPartner.Partner,
      
      @Semantics.name.fullName: true
      @Semantics.text: true
      CreditMemoRequestPartner.FullName,
      
      _PartnerFunction.SDDocumentPartnerType,

      @ObjectModel.foreignKey.association: '_FormOfAddress'
      @Semantics.name.jobTitle: true
      CreditMemoRequestPartner.FormOfAddress,

      @Semantics.address.zipCode:true
      CreditMemoRequestPartner._OrgNamePostalAddress.PostalCode,

      @Semantics.address.city:true
      CreditMemoRequestPartner._OrgNamePostalAddress.CityName,

      CreditMemoRequestPartner._OrgNamePostalAddress.DistrictName,

      @Semantics.address.country:true
      @ObjectModel.foreignKey.association: '_Country'
      CreditMemoRequestPartner._OrgNamePostalAddress.Country,

      @ObjectModel.foreignKey.association: '_Region'
      @Semantics.address.region: true
      CreditMemoRequestPartner._OrgNamePostalAddress.Region,

      @Semantics.address.street: true
      CreditMemoRequestPartner._OrgNamePostalAddress.StreetName,

      @Semantics.address.street: true
      CreditMemoRequestPartner._OrgNamePostalAddress.StreetPrefixName1,

      @Semantics.address.street: true
      CreditMemoRequestPartner._OrgNamePostalAddress.StreetPrefixName2,

      @Semantics.address.street: true
      CreditMemoRequestPartner._OrgNamePostalAddress.StreetSuffixName1,

      @Semantics.address.street: true
      CreditMemoRequestPartner._OrgNamePostalAddress.StreetSuffixName2,

      @Semantics.address.streetNoNumber: true
      CreditMemoRequestPartner._OrgNamePostalAddress.HouseNumber,

      @Semantics.telephone.type: [#WORK]
      CreditMemoRequestPartner.InternationalPhoneNumber,

      @Semantics.telephone.type:  [#CELL]
      CreditMemoRequestPartner.InternationalMobilePhoneNumber,

      @Semantics.eMail.address: true
      @Semantics.eMail.type:  [#WORK]
      CreditMemoRequestPartner.EmailAddress,

      @Semantics.telephone.type: [#FAX]
      CreditMemoRequestPartner.InternationalFaxNumber,

      @Semantics.address.postBox: true
      CreditMemoRequestPartner._OrgNamePostalAddress.POBox,

      @Semantics.address.zipCode:true
      CreditMemoRequestPartner._OrgNamePostalAddress.POBoxPostalCode,

      @ObjectModel.foreignKey.association: '_CorrespondenceLanguage'
      CreditMemoRequestPartner.CorrespondenceLanguage,

      CreditMemoRequestPartner._OrgNamePostalAddress.TaxJurisdiction,

      @ObjectModel.foreignKey.association: '_TransportationZone'
      CreditMemoRequestPartner._OrgNamePostalAddress.TransportZone,

      @Semantics.text: true
      CreditMemoRequestPartner.UnloadingPointName,

      CreditMemoRequestPartner.VATRegistration,
      
      CreditMemoRequestPartner.SDDocPartnerAddrIsDocSpecific,

      //    On Conditions For Associations

      @Consumption.hidden: true
      CreditMemoRequestPartner.AddressID,
      @Consumption.hidden: true
      CreditMemoRequestPartner.AddressPersonID,
      @Consumption.hidden: true
      CreditMemoRequestPartner.AddressObjectType,
      @Consumption.hidden: true
      CreditMemoRequestPartner.SDDocPartnerAddressRefType,
      @Consumption.hidden: true
      CreditMemoRequestPartner.BPAddrDeterminationTransaction,
      @Consumption.hidden: true
      CreditMemoRequestPartner.BPRefAddressIDForDocSpcfcAddr,

      //DCL

      @Consumption.hidden: true
      _CreditMemoRequest.CreditMemoRequestType,
      @Consumption.hidden: true
      _CreditMemoRequest.SalesOrganization,
      @Consumption.hidden: true
      _CreditMemoRequest.DistributionChannel,
      @Consumption.hidden: true
      _CreditMemoRequest.OrganizationDivision,

      //    Associations

      _CreditMemoRequest,
      _PartnerFunction,
      _CorrespondenceLanguage,
      _FormOfAddress,
      _TransportationZone,
      
      CreditMemoRequestPartner._DfltAddrRprstn,      
      CreditMemoRequestPartner._OrgNamePostalAddress,
      CreditMemoRequestPartner._BusinessPartnerAddress,
      CreditMemoRequestPartner._BPRefAddressForDocSpcfcAddr,
      CreditMemoRequestPartner._OrgNamePostalAddress._Country,
      CreditMemoRequestPartner._OrgNamePostalAddress._Region
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRORGNAMEPOSTALADDRESS",
"I_CREDITMEMOREQPARTNER",
"I_PARTNERFUNCTION",
"R_CREDITMEMOREQUESTTP"
],
"ASSOCIATED":
[
"I_ADDRESS_2",
"I_ADDRORGNAMEPOSTALADDRESS",
"I_BUSPARTADDRESS",
"I_COUNTRY",
"I_FORMOFADDRESS",
"I_LANGUAGE",
"I_PARTNERFUNCTION",
"I_REGION",
"I_TRANSPORTATIONZONE",
"R_CREDITMEMOREQUESTTP"
],
"BASE":
[
"I_ADDRORGNAMEPOSTALADDRESS",
"I_CREDITMEMOREQPARTNER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More