R_CollsHeadOfficeAccountTP

@AbapCatalog: { sqlViewName: 'RCOLLSHOBACC',
                compiler:    { compareFilter: true },
                preserveKey: true }
@AccessControl: { authorizationCheck: #CHECK,
                  personalData: { blocking: #BLOCKED_DATA_EXCLUDED },
                  privilegedAssociations: [ '_Resubmission',
                                            '_PromiseToPay',
                                            '_DisputeCase' ] }
@EndUserText: { label: 'Head Office Receivables' }
@VDM: { viewType:  #TRANSACTIONAL,
        lifecycle: { contract: { type: #SAP_INTERNAL_API } } }
@ClientHandling: { algorithm: #SESSION_VARIABLE }
@ObjectModel: { usageType:         { serviceQuality: #X,
                                     sizeCategory:   #L,
                                     dataClass:      #TRANSACTIONAL },
                semanticKey:       [ 'Customer',
                                     'CollectionSegment',
                                     'BusinessPartner' ],
                representativeKey: 'Customer' }

/*+[hideWarning] { "IDS" : [ "KEY_CHECK", "CARDINALITY_CHECK" ]  } */
define root view R_CollsHeadOfficeAccountTP
  as select from P_CollsAccountCollsSegment

  // VDM Associations

  // Customer

  association [0..1] to I_Customer                    as _Customer                    on  $projection.Customer = _Customer.Customer

  // Collection Segment

  association [0..1] to I_CollectionSegment           as _CollectionSegment           on  $projection.CollectionSegment = _CollectionSegment.CollectionSegment

  // Business Partner

  association [0..1] to I_BusinessPartner             as _BusinessPartner             on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner

  // Business Partner Quick View Facet

  association [0..1] to R_BPCollectionsSgmtQuickView  as _CollectionsBPQuickView      on  $projection.BusinessPartner   = _CollectionsBPQuickView.BusinessPartner
                                                                                      and $projection.CollectionSegment = _CollectionsBPQuickView.CollectionSegment

  // Credit Management

  association [0..1] to R_CollsAcctCreditMgmtSummary  as _CollsAcctCreditMgmtSummary  on  $projection.BusinessPartner   = _CollsAcctCreditMgmtSummary.BusinessPartner
                                                                                      and $projection.CollectionSegment = _CollsAcctCreditMgmtSummary.CollectionSegment

  // Main Contact Person

  association [0..1] to I_CollectionsMainContact      as _CollectionsMainContact      on  $projection.BusinessPartner   = _CollectionsMainContact.BusinessPartner
                                                                                      and $projection.CollectionSegment = _CollectionsMainContact.CollectionSegment

  // Sticky Note

  association [0..1] to I_CollsAccountStickyNote      as _CollsAccountStickyNote      on  $projection.Customer          = _CollsAccountStickyNote.Customer
                                                                                      and $projection.CollectionSegment = _CollsAccountStickyNote.CollectionSegment

  // Due Date Grid

  association [0..*] to I_CollectionsDueDateGrid      as _CollectionsDueDateGrid      on  $projection.BusinessPartner   = _CollectionsDueDateGrid.BusinessPartner
                                                                                      and $projection.CollectionSegment = _CollectionsDueDateGrid.CollectionSegment
                                                                                      and $projection.IsHeadOffice      = _CollectionsDueDateGrid.IsHeadOffice

  // Payment Trend

  association [0..*] to I_CollectionsPaymentTrend     as _CollectionsPaymentTrend     on  $projection.Customer          = _CollectionsPaymentTrend.Customer
                                                                                      and $projection.CollectionSegment = _CollectionsPaymentTrend.CollectionSegment
                                                                                      and $projection.IsHeadOffice      = _CollectionsPaymentTrend.IsHeadOffice

  // Invoices

  association [0..*] to R_CollectionsInvoiceTP        as _CollectionsInvoice          on  $projection.CollectionSegment = _CollectionsInvoice.CollectionSegment
                                                                                      and $projection.Customer          = _CollectionsInvoice.Customer

  // Dispute Case

  association [0..*] to R_CollsHeadOfficeDisputeCase  as _DisputeCase                 on  $projection.Customer          = _DisputeCase.HeadOffice
                                                                                      and $projection.CollectionSegment = _DisputeCase.CollectionSegment

  // Promises to Pay

  association [0..*] to R_CollsHeadOfficePromiseToPay as _PromiseToPay                on  $projection.Customer          = _PromiseToPay.Customer
                                                                                      and $projection.CollectionSegment = _PromiseToPay.CollectionSegment

  // Resubmissions

  association [0..*] to R_CollsHeadOfficeResubmission as _Resubmission                on  $projection.Customer          = _Resubmission.Customer
                                                                                      and $projection.CollectionSegment = _Resubmission.CollectionSegment

  // Head-Office/Branch

  association [0..*] to I_CollectionsHeadOfficeBranch as _CollectionsHeadOfficeBranch on  $projection.Customer = _CollectionsHeadOfficeBranch.Customer

  // Collections Account Notes

  association [0..*] to I_CollectionsAccountNote      as _CollectionsAccountNote      on  $projection.Customer          = _CollectionsAccountNote.Customer
                                                                                      and $projection.CollectionSegment = _CollectionsAccountNote.CollectionSegment
                                                                                      and $projection.IsHeadOffice      = _CollectionsAccountNote.IsHeadOffice
{

      // VDM Fields

  key Customer,
  key CollectionSegment,

      @ObjectModel: { foreignKey: { association: '_CollectionsBPQuickView' } }
      BusinessPartner,

      cast( 'X' as boolean preserving type ) as IsHeadOffice,

      // Exposed Associations

      _Customer,
      _CollectionSegment,
      _BusinessPartner,
      _CollectionsBPQuickView,
      _CollsAcctCreditMgmtSummary,
      _CollectionsMainContact,
      _CollsAccountStickyNote,
      _CollectionsDueDateGrid,
      _CollectionsPaymentTrend,
      _CollectionsInvoice,
      _DisputeCase,
      _PromiseToPay,
      _Resubmission,
      _CollectionsHeadOfficeBranch,
      _CollectionsAccountNote

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_COLLSACCOUNTCOLLSSEGMENT"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_COLLECTIONSACCOUNTNOTE",
"I_COLLECTIONSDUEDATEGRID",
"I_COLLECTIONSEGMENT",
"I_COLLECTIONSHEADOFFICEBRANCH",
"I_COLLECTIONSMAINCONTACT",
"I_COLLECTIONSPAYMENTTREND",
"I_COLLSACCOUNTSTICKYNOTE",
"I_CUSTOMER",
"R_BPCOLLECTIONSSGMTQUICKVIEW",
"R_COLLECTIONSINVOICETP",
"R_COLLSACCTCREDITMGMTSUMMARY",
"R_COLLSHEADOFFICEDISPUTECASE",
"R_COLLSHEADOFFICEPROMISETOPAY",
"R_COLLSHEADOFFICERESUBMISSION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/