@AbapCatalog: { sqlViewName: 'ICLLSACCNT',
compiler: { compareFilter: true },
preserveKey: true }
@AccessControl: { authorizationCheck: #CHECK,
privilegedAssociations: [ '_CreatedByContactCard' ],
personalData: { blocking: #BLOCKED_DATA_EXCLUDED } }
@EndUserText: { label: 'Collections Account Note' }
@VDM: { viewType: #COMPOSITE,
lifecycle: { contract: { type: #SAP_INTERNAL_API } } }
@ClientHandling: { algorithm: #SESSION_VARIABLE }
@ObjectModel: { usageType: { serviceQuality: #D,
sizeCategory: #L,
dataClass: #TRANSACTIONAL },
semanticKey: [ 'Customer', 'CollectionSegment' ],
representativeKey: 'Customer' }
define root view I_CollectionsAccountNote
as select from P_CollectionsAccountNote
// VDM Associations
// Created By Contact Card
association [0..1] to I_UserContactCard as _CreatedByContactCard on $projection.CreatedByUser = _CreatedByContactCard.ContactCardID
{
// VDM Fields
@ObjectModel: { foreignKey: { association: '_Customer' } }
key Customer,
@ObjectModel: { foreignKey: { association: '_CollectionSegment' } }
key CollectionSegment,
key _NoteContent[inner].noteid as NoteID,
key cast ( '' as bdm_cct_guid ) as CustomerContactUUID,
key cast ( '' as bdm_rsm_guid ) as ResubmissionUUID,
ObjectKey,
cast( 'Note' as text80 ) as NoteDescription,
_NoteContent[inner].creator as CreatedByUser,
_NoteContent[inner].created as CreationDateTime,
_NoteContent[inner].content as NoteText,
cast( 'sap-icon://notes' as text40 ) as NoteIconURL,
cast( '0' as char1 ) as MigrationStatus,
cast( '' as sysuuid_c32 ) as DraftUUID,
cast( '' as boolean ) as IsHeadOffice,
// Exposed Associations
_CollectionSegment,
_Customer,
_CreatedByContactCard
}
union all select from P_CollsCustomerContactNote
// VDM Associations
// Created By Contact Card
association [0..1] to I_UserContactCard as _CreatedByContactCard on $projection.CreatedByUser = _CreatedByContactCard.ContactCardID
{
// VDM Fields
@ObjectModel: { foreignKey: { association: '_Customer' } }
key Customer,
@ObjectModel: { foreignKey: { association: '_CollectionSegment' } }
key CollectionSegment,
key _NoteContent.noteid,
key CustomerContactUUID,
key cast ( '' as bdm_rsm_guid ) as ResubmissionUUID,
'' as ObjectKey,
NoteDescription,
CreatedByUser,
CreationDateTime,
'' as NoteText,
NoteIconURL,
cast ( '1' as char1 ) as MigrationStatus,
cast( '' as sysuuid_c32 ) as DraftUUID,
cast( '' as boolean ) as IsHeadOffice,
// Exposed Associations
_CollectionSegment,
_Customer,
_CreatedByContactCard
}
union all select from P_CollsResubmissionNote
// VDM Associations
// Created By Contact Card
association [0..1] to I_UserContactCard as _CreatedByContactCard on $projection.CreatedByUser = _CreatedByContactCard.ContactCardID
{
@ObjectModel: { foreignKey: { association: '_Customer' } }
key Customer,
@ObjectModel: { foreignKey: { association: '_CollectionSegment' } }
key CollectionSegment,
key _NoteContent.noteid as NoteID,
key cast ( '' as bdm_cct_guid ) as CustomerContactUUID,
key ResubmissionUUID as ResubmissionUUID,
'' as ObjectKey,
NoteDescription,
CreatedByUser as CreatedByUser,
CreationDateTime as CreationDateTime,
'' as NoteText,
NoteIconURL,
cast( '2' as char1 ) as MigrationStatus,
cast( '' as sysuuid_c32 ) as DraftUUID,
cast( '' as boolean ) as IsHeadOffice,
// Exposed Associations
_CollectionSegment,
_Customer,
_CreatedByContactCard
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_COLLECTIONSACCOUNTNOTE",
"P_COLLSCUSTOMERCONTACTNOTE",
"P_COLLSRESUBMISSIONNOTE",
"SGBT_NTE_CDS_CONT"
],
"ASSOCIATED":
[
"I_COLLECTIONSEGMENT",
"I_CUSTOMER",
"I_USERCONTACTCARD"
],
"BASE":
[
"P_COLLECTIONSACCOUNTNOTE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/